Bitmap  - AS3

Başvurulan BitmapData nesnesi.

Bitmap nesnesinin en yakın piksele bitiştirilip bitiştirilmediğini denetler. PixelSnapping sınıfı, şu olası değerleri içerir:

• PixelSnapping.NEVER—Piksel bitiştirme oluşmaz.
• PixelSnapping.ALWAYS—Dönüştürmeden bağımsız olarak görüntü her zaman en yakın piksele bitiştirilir.
• PixelSnapping.AUTO—Görüntü, döndürme veya eğim olmadan çizilirse ve %99,9 ile %100,1 ölçek faktöründe çizilirse, en yakın piksele bitiştirilir. Bu koşullar karşılanırsa, bitmap görüntüsü en yakın piksele bitiştirilerek %100 ölçekte çizilir. Dahili olarak bu değer, vektör oluşturucu kullanılarak olabilecek en hızlı şekilde görüntünün çizilmesini sağlar.

Bitmap ölçeklendirildiğinde düzgünleştiriliyor mu, kontrol eder. true olursa, ölçeklendiğinde bitmap düzgünleştirilir. false olursa, ölçeklendiğinde bitmap düzgünleştirilmez.

Bir Bitmap nesnesini, belirtilen BitmapData nesnesine başvurması için başlatır.

	bitmapData:BitmapData (default = null) — Başvurulan BitmapData nesnesi.
	pixelSnapping:String (default = "auto") — Bitmap nesnesinin en yakın piksele bitiştirilip bitiştirilmediği.
	smoothing:Boolean (default = false) — Bitmap öğesinin ölçeklendiğinde düzgünleştirilip düzgünleştirilmediği. Örneğin, şu örnekler, smoothing öğesi false (sol) değerine ve true (sağ) değerine ayarlanmış şekilde 3 faktörüyle ölçeklenmiş aynı bitmap'i gösterir:

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. Bir url özelliği oluşturulur; bu, görüntü dosyasının konumu ve adıdır.
2. Sınıf yapıcısı, configureAssets() yöntemini çağırır; bu çağrı sonucunda da completeHandler() yöntemi çağrılır.
3. configureAssets() öğesi, bir Loader nesnesi oluşturur; bu nesne de, completeHandler() görüntü işlemeyi tamamladığında gönderilen bir olay dinleyicisini başlatır.
4. Daha sonra, buildChild() yöntemi, dosya adı ve konumunun bilinmesi için url iletilmiş şekilde yeni bir URLRequest nesnesi (request) oluşturur.
5. request nesnesi, bir görüntüleme nesnesi kullanarak görüntüyü belleğe yükleyen loader.load() yöntemine iletilir.
6. Daha sonra görüntü, ekranda x = 0, y = 0 koordinatlarında hemen görüntüyü gösteren görüntüleme listesine yerleştirilir.
7. completeHandler() yöntemi daha sonra şu görevleri gerçekleştirir:
   1. Loader nesnesiyle başlatılan bir Bitmap nesnesiyle birlikte ikinci bir Loader nesnesi oluşturur.
   2. Orijinal görüntünün kopyasını oluşturan duplicateImage() yöntemini çağıran ikinci bir Bitmap nesnesi (duplicate) oluşturur.
   3. duplicate nesnesinin BitmapData nesnesine atanan bir BitmapData nesnesi oluşturur.
   4. Orijinal görüntüyle aynı koordinatlar, genişlik ve yükseklikle başlatılan yeni bir Rectangle nesnesi oluşturur.
   5. x = 0, y = 0 varsayılan ayarlı yeni bir Point nesnesi oluşturur.
   6. Şu değişkenleri oluşturur:
      • operation: eşik değeri >= orijinal olduğunda yeni rengi uygular.
      • threshold: her pikselin karşılaştırıldığı değer, 0xCC alfasıyla açık griye ayarlanır.
      • color: piksellerin eşik testini geçmek için ayarlandığı renk, bu durumda düz sarıdır.
      • mask: rengin tam karşıtına ayarlanır, (saydam mavi).
      • copySource: false değerine ayarlanır ve eşik değerinin geçmemesi durumunda piksel değerlerinin kopyalanmadığını belirtir. Görüntü çoğaltıldığı ve yalnızca eşik testini geçen pikseller değiştirildiği için bu değerin bir anlamı yoktur.
   7. Önceki değişkenleri kullanarak threshold() yöntemini çağırır. Sonuçta elde edilen eşik denklemi şu şekildedir: (geçerli piksel Değeri & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) olursa, piksel 0xFFFFFF00 olarak ayarlanır.

Notlar:

• SWF dosyasını “Yerel oynatma güvenliği“ ayarı “Yalnızca yerel dosyalara erişim“ şeklinde ayarlanmış biçimde derlemeniz gerekir.
• Bu örnek, Image.gif adlı bir dosyanın SWF dosyanızla aynı dizine yerleştirilmesini gerektirir.
• En fazla 80 piksel genişlikte bir görüntü kullanmanız önerilir.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}