Video  - AS3

Art işlemenin bir parçası olarak kodu çözülen videoya uygulanan filtre türünü belirtir. Varsayılan değer 0 olup, gerektiğinde video sıkıştırıcının bir blok çözme filtresi uygulamasını sağlar.

Video sıkıştırması istenmeyen yapılara yol açabilir. Bloklamayı ve On2 codec bileşeni kullanılarak sıkıştırılmış videolara yönelik halka oluşturmayı azaltan filtreler ayarlamak için deblocking özelliğini kullanabilirsiniz.

Blocking, her bir video karesini oluşturan blokların sınırları arasındaki görünebilir kusurları ifade eder. Ringing, bir video görüntüsü içindeki öğelerin bozuk kenarlarını ifade eder.

İki blok çözme filtresi kullanılabilir: biri Sorenson codec bileşeninde ve biri On2 VP6 codec bileşenindedir. Ayrıca, On2 VP6 codec bileşenini kullandığınızda bir halka azaltma filtresi kullanılabilir. Bir filtre ayarlamak için şu değerlerden birini kullanın:

• 0—Video sıkıştırıcısının gerektiğinde blok çözme filtresi uygulamasını sağlar.
• 1—Blok çözme filtresi kullanmaz.
• 2—Sorenson blok çözme filtresini kullanır.
• 3—Yalnızca On2 videosu için On2 blok çözme filtresini kullanır ancak halka azaltma filtresini kullanmaz.
• 4—Yalnızca On2 videosu için On2 blok çözme ve halka azaltma filtresini kullanır.
• 5—Yalnızca On2 videosu için On2 blok çözme ve daha yüksek performanslı On2 halka azaltma filtresini kullanır.

Sorenson codec bileşenini kullandığınızda video için 2'den yüksek bir değer seçilirse, Sorenson kod çözücüsü varsayılan olarak 2 değerini kullanır.

Blok çözme filtresinin kullanılması, genel oynatma performansı üzerinde etkilidir ve genellikle yüksek bant genişliğine sahip video için gerekli değildir. Bir kullanıcının sistemi yeterince güçlü değilse, kullanıcı blok çözme filtresi etkin şekilde video oynatırken zorluklarla karşılaşabilir.

Videonun ölçeklendiğinde düzgünleştirilmesi (enterpolasyonlu yapılması) gerekip gerekmediğini belirtir. Düzgünleştirmenin çalışması için çalışma zamanının yüksek kalite modunda (varsayılan) olması gerekir. Varsayılan değer false (düzgünleştirme yok) olur.

Flash Player 9.0.115.0 ve sonraki sürümleri kullanarak video oynatmak için, bu özelliği true değerine ayarlayarak görüntü doku eşleme en iyileştirmesi özelliğinden yararlanın.

Video akışının yüksekliğini piksel cinsinden belirten bir tam sayı. Canlı akışlar için bu değer, video akışını çeken Camera nesnesinin Camera.height özelliğiyle aynıdır. Kayıtlı video dosyaları için bu değer videonun yüksekliğidir. NetStream.Video.DimensionChange olayı, bu değer değiştiğinde kayıtlı videolar için gönderilir.

Örneğin, Sahne Alanı üzerindeki Video nesnesinin gerçek boyutu dikkate alınmaksızın kullanıcının videoyu yakalandığı boyutta gördüğünden emin olmak için bu özelliği kullanmak isteyebilirsiniz.

İlgili API Öğeleri

Video akışının genişliğini piksel cinsinden belirten bir tam sayı. Canlı akışlar için bu değer, video akışını çeken Camera nesnesinin Camera.width özelliğiyle aynıdır. Kayıtlı video dosyaları için bu değer videonun genişliğidir. NetStream.Video.DimensionChange olayı, bu değer değiştiğinde kayıtlı videolar için gönderilir.

Örneğin, Sahne Alanı üzerindeki Video nesnesinin gerçek boyutu dikkate alınmaksızın kullanıcının videoyu yakalandığı boyutta gördüğünden emin olmak için bu özelliği kullanmak isteyebilirsiniz.

İlgili API Öğeleri

Yeni bir Video örneği oluşturur. width ve height parametreleri için bir değer sağlanmazsa, varsayılan değerler kullanılır. Başlangıç yapısından sonra, Video.width ve Video.height öğelerini kullanarak Video nesnesinin width ve height özelliklerini ayarlayabilirsiniz. Yeni bir Video nesnesi oluşturulduğunda, genişlik ve yükseklik için sıfır değerine izin verilmez; sıfır değerini iletirseniz, varsayılan değerler uygulanır.

Video oluşturduktan sonra, Video nesnesini üst DisplayObjectContainer nesnesine eklemek için DisplayObjectContainer.addChild() veya DisplayObjectContainer.addChildAt() yöntemini çağırın.

var MyVideo:Video = new Video();
addChild(MyVideo);
 
var MyNC:NetConnection = new NetConnection();
MyNC.connect(null);
 
var MyNS:NetStream = new NetStream(MyNC);
MyNS.play("http://www.helpexamples.com/flash/video/clouds.flv");

MyVideo.attachNetStream(MyNS);

//the clouds.flv video has metadata we're not using, so create
//an error handler to ignore the message generated by the runtime
//about the metadata
MyNS.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 

function asyncErrorHandler(event:AsyncErrorEvent):void 
{ 
   //ignore metadata error message
} 

Uygulamada Video nesnesinin sınırları içinde görüntülenecek bir kameradaki video akışını belirtir.

Kullanıcı tarafından yakalanan canlı videoyu Video nesnesine eklemek için bu yöntemi kullanın. Canlı videoyu, yakalanmakta olduğu aynı bilgisayarda veya aygıtta yerel olarak oynatabilir ya da Flash Media Server'a gönderip başka kullanıcılar için akışa almak üzere sunucuyu kullanabilirsiniz.

Not: Bir iOS AIR uygulamasında, uygulama, GPU oluşturma modunu kullandığında kamera videosu görüntülenemez.

Parametreler

İlgili API Öğeleri

Uygulamada Video nesnesinin sınırları içinde görüntülenecek video akışını belirtir. Video akışı, NetStream.play() ile oynatılan bir video dosyası, bir Camera nesnesi veya null şeklinde olur. Bir video dosyası kullanırsanız, video yerel dosya sisteminde veya Flash Media Server üzerinde saklanabilir. netStream argümanının değeri null olursa, video artık Video nesnesinde oynatılmaz.

Bir video dosyası yalnızca ses içeriyorsa bu yöntemi kullanmanız gerekmez; NetStream.play() öğesini çağırdığınızda video dosyalarının ses bölümü otomatik olarak oynatılır. Bir video dosyasıyla ilişkili sesi denetlemek için, video dosyasını oynatan NetStream nesnesinin soundTransform özelliğini kullanın.

Parametreler

İlgili API Öğeleri

Video nesnesinde görüntülenen görüntüyü siler (video akışında değil). Bu yöntem, geçerli görüntünün işlenmesi için kullanışlıdır. Örneğin, Video nesnesini saklamadan son görüntüyü veya görüntüleme standby bilgilerini silebilirsiniz.

İlgili API Öğeleri

Bu örnekte, Video ve NetStream nesnelerini oluşturan ve Video.attachNetStream() ve NetStream.play() öğelerini çağıran kod bir işleyici işlevine yerleştirilir. İşleyici yalnızca, NetConnection nesnesine bağlanmak için yapılan denemenin başarılı olması durumunda; yani netStatus olayı, başarılı olunduğunu gösteren bir code özelliğine sahip bir info nesnesi döndürdüğünde çağrılır. NetStream.play() öğesini çağırmadan önce başarılı bir bağlantı yapılmasını beklemeniz önerilir.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }