Camera  - AS3

Kameranın algıladığı hareket miktarı. Değerler 0 (hareket algılanmaz) ile 100 (büyük miktarda hareket algılanır) arasıdır. Bu özelliğin değeri, setMotionLevel() yöntemine bir ayar iletmeniz gerekip gerekmediğini belirlemenize yardımcı olabilir.

Kamera mevcutsa ancak Video.attachCamera() yöntemi çağrılmadığından henüz kullanılmıyorsa, bu özellik -1 değerine ayarlanır.

Yalnızca sıkıştırılmamış yerel videoyu akışa alıyorsanız, ancak olay işleyicisine bir işlev atamış olmanız kaydıyla bu özellik ayarlanır. Yoksa, bu özellik tanımlanmaz.

İlgili API Öğeleri

Gitmekte olan video akışının kullanabileceği bayt cinsinden maksimum bant genişliği miktarı. 0 değeri, akışın istenen kare kalitesini korumak için gerektiği kadar çok bant genişliği kullanabileceği anlamına gelir.

Bu özelliği ayarlamak için setQuality() yöntemini kullanın.

İlgili API Öğeleri

Kameranın saniyede kare sayısı olarak veri yakalama hızı. Bu özellik ayarlanamaz; ancak kameranın veri yakalamasını istediğiniz maksimum kare hızını belirten ilgili bir özelliği (fps) ayarlamak için setMode() yöntemini kullanabilirsiniz.

İlgili API Öğeleri

Kameranın saniye başına kare sayısı olarak veri yakalamasını istediğiniz maksimum hız. Olabilecek maksimum hız, kameranın yeteneklerine bağlıdır; bu kare hızı gerçekleştirilemez.

• Bu özellik için istediğiniz bir değeri ayarlamak üzere setMode() yöntemini kullanın.
• Kameranın geçerli veri yakalama hızını belirlemek için currentFPS özelliğini kullanın.

İlgili API Öğeleri

Piksel olarak geçerli yakalama yüksekliği. Bu özellik için bir değeri ayarlamak üzere setMode() yöntemini kullanın.

İlgili API Öğeleri

Tüm kullanılabilir kameraları listeleyen Camera.names dizisinde kameranın konumunu belirten, sıfır tabanlı bir dizin.

İlgili API Öğeleri

isSupported özelliği, Camera sınıfı geçerli platformda destekleniyorsa true olarak, aksi halde false olarak ayarlanır.

Video sıkıştırma algoritması tarafından enterpolasyonlu yapılmak yerine tam (keyframes) olarak iletilen video kareleri sayısı. Varsayılan değer 15 olup bu, her 15. karenin bir anahtar kare olduğu anlamına gelir. 1 değeri, her karenin bir anahtar kare olduğu anlamına gelir. İzin verilen değerler 1 ile 300 arasıdır.

İlgili API Öğeleri

Kameranın yakaladıklarına ait yerel görünümün Flash Media Server kullanılarak canlı iletim yapıldığında olduğu gibi sıkıştırılıp sıkıştırmasının açıldığını mı (true) yoksa sıkıştırılmadığını mı (false) belirtir. Varsayılan değer false şeklindedir.

Sıkıştırılmış bir akış, video kalitesi ayarlarını önizleme gibi test işlemleri için yararlı olsa da, önemli miktarda işleme maliyetine yol açar. Yerel görünüm sıkıştırılır, canlı bağlantıda olduğu gibi iletim için düzenlenir ve sonra yerel görüntüleme için sıkıştırılması açılır.

Bu değeri ayarlamak için Camera.setLoopback() öğesini kullanın. Bu özellik true olduğunda kullanılan sıkıştırma miktarını ayarlamak için, Camera.setQuality() öğesini kullanın.

İlgili API Öğeleri

activity olayını çağırmak için gerekli hareket miktarı. Kabul edilebilir değerler 0 - 100 aralığındadır. Varsayılan değer 50'dir.

motionLevel özelliğinin değerine bakılmaksızın video görüntülenebilir. Daha fazla bilgi için bkz. setMotionLevel().

İlgili API Öğeleri

Kameranın hareket algılamayı durdurmasıyla activity olayının çağrılması arasında geçen milisaniye sayısı. Varsayılan değer 2000'dir (2 saniye).

Bu değeri ayarlamak için, setMotionLevel() öğesini kullanın.

İlgili API Öğeleri

Kullanıcının Flash Player Gizlilik iletişim kutusunda kameraya erişimi engelleyip (true) engellemediğini (false) gösteren bir Boolean değeri. Bu değer değiştiğinde, status olayı gönderilir.

İlgili API Öğeleri

Kamera donanımının döndürdüğü haliyle geçerli kameranın adı.

İlgili API Öğeleri

Tüm kullanılabilir kameraların adlarını içeren dizeler dizisi. Bu diziye erişmek, Flash Player Gizlilik iletişim kutusunu göstermez. Bu dizi, sistemdeki her kameranın ve kamera sayısının sıfır tabanlı bir dizinini sağlar(names.length yoluyla).

names özelliğinin çağrılması, donanımın yoğun şekilde incelenmesini gerektirir. Çoğu durumda yalnızca varsayılan kamerayı kullanabilirsiniz.

İlgili API Öğeleri

Uygulamaya kamera kullanımı izninin verilip verilmediğini belirler.

İlgili API Öğeleri

Aygıtta kameranın yer aldığı tarafı belirtir.

Mobil bir aygıtta kameranın aygıtın ön yüzünde mi yoksa arka yüzünde mi olduğunu belirlemek için position özelliğini kullanın. Aşağıdaki işlev, kullanılabilir her kamerayı istenen konuma sahip bir kamera buluncaya kadar kontrol eder. Hiçbir kamera istenen konumda değilse varsayılan kamera döndürülür.

     function getCamera( position:String ):Camera
     {
       var camera:Camera;
       var cameraCount:uint = Camera.names.length;
      for ( var i:uint = 0; i < cameraCount; ++i )
      {
        camera = Camera.getCamera( String(i) );
        if ( camera.position == position ) return camera;
      }
      return Camera.getCamera();
     
     

Mobil aygıtlarda kamera konumu normalde CameraPosition.FRONT ya da CameraPosition.BACK şeklindedir. Camera öğesinin konumu belirlenemiyorsa, konum CameraPosition.UNKNOWN olarak bildirilir.Masaüstü platformlarda konum her zaman için CameraPosition.UNKNOWN şeklindedir.

Bu özelliğin geçerli değerlerinin sabitleri CameraPosition sınıfında tanımlanır

İlgili API Öğeleri

Her video karesine uygulanmakta olan sıkıştırma miktarının belirlediği gerekli resim kalitesi düzeyi. Kabul edilebilir kalite değerleri 1 (en düşük kalite, maksimum sıkıştırma) ile 100 (en yüksek kalite, sıkıştırma yok) arasıdır. Varsayılan değer 0 olup bu, mevcut bant genişliğinin aşılmasını önlemek için gerektiğinde resim kalitesinin değişebileceği anlamına gelir.

Bu özelliği ayarlamak için setQuality() yöntemini kullanın.

İlgili API Öğeleri

Piksel olarak geçerli yakalama genişliği. Bu özellik için istediğiniz bir değeri ayarlamak üzere setMode() yöntemini kullanın.

İlgili API Öğeleri

Piksel verisinin dikdörtgen bölgesinden bir bayt dizisini doldurur

Bayt dizisine her piksel için işaretsiz bir tam sayı (32 bit çarpılmamış bir piksel değeri) yazar. Dizi, tüm piksellerin tutulması için gerekli bayt sayısına yeniden boyutlandırılır.

Parametreler

İlgili API Öğeleri

Piksel verisinin dikdörtgen bölgesinden bir vektörü doldurur.

Vektöre her piksel için işaretsiz bir tam sayı (32 bit çarpılmamış bir piksel değeri) yazar. Vektör, tüm piksellerin tutulması için gerekli giriş sayısına yeniden boyutlandırılır.

Parametreler

İlgili API Öğeleri

Son kareyi bir bitmap'e kopyalar.

Bu yöntem, son karenin içeriğini BitmapData örneğine kopyalar.

Parametreler

İlgili API Öğeleri

Video yakalamak için bir Camera nesnesine başvuru döndürür. Video yakalamaya başlamak için, Camera nesnesini bir Video nesnesine eklemeniz gerekir (bkz. Video.attachCamera() ). Videoyu Flash Media Server'a iletmek için, NetStream.attachCamera() öğesini çağırarak Camera nesnesini bir NetStream nesnesine ekleyin.

getCamera() yöntemine yapılan birden çok çağrı, aynı kamera sürücüsüne başvurur. Böylece, kodunuz firstCam:Camera = getCamera() ve secondCam:Camera = getCamera() gibi kodlar içerirse, hem firstCam hem de secondCam, aynı kameraya başvurur, bu, kullanıcının varsayılan kamerasıdır.

Hem ön hem de arka kamerası olan mobil aygıtlarda aynı anda yalnızca bir kameradan video yakalayabilirsiniz.

Genelde, varsayılan kameraya bir başvuru döndürmek üzere name parametresi için bir değer iletmemeniz yalnızca getCamera() öğesini kullanmanız gerekir. Kamera ayarları panelinden (bu bölümün ilerleyen kısımlarında ele alınmıştır), kullanıcı, kullanılacak varsayılan kamerayı belirtebilir.

Kameraya erişilmesine yönelik bir kullanıcının Allow veya Deny izni ayarını belirlemek için ActionScript'i kullanamazsınız ancak kullanıcının kamera iznini ayarlayabildiği Adobe Flash Player Ayarları kamera ayarı iletişim kutusunu görüntüleyebilirsiniz. attachCamera() yöntemini kullanan bir SWF dosyası, getCamera() yönteminin döndürdüğü kamerayı bir Video veya NetStream nesnesine eklemeyi denediğinde, Flash Player, kullanıcının kameraya erişilmesine izin verip vermemeyi seçmesini sağlayan bir iletişim kutusunu görüntüler. (Uygulama pencerenizin boyutunun en az 215 x 138 piksel olduğundan emin olun; bu değer, Flash Player'ın iletişim kutusunu görüntülemek için gerektirdiği minimum boyuttur.) Kullanıcı, kamera ayarı iletişim kutusuna yanıt verdiğinde, Flash Player kullanıcının yanıtını gösteren status olayında bir bilgi nesnesi döndürür: Camera.muted, kullanıcının kameraya erişimi reddettiğini gösterir; Camera.Unmuted ise kullanıcının kameraya erişilmesine izin verdiğini belirtir. status olayını işlemeden kullanıcının bir kameraya erişilmesine izin verip vermediğini belirlemek için muted özelliğini kullanın.

Flash Player'da kullanıcı, SWF dosyası oynatılırken sağ tıklatıp (Windows ve Linux) veya Control tuşuna basarak tıklatıp (Macintosh) Ayarlar'ı seçip daha sonra Gizlilik iletişim kutusunu açıp Hatırla seçeneğini belirleyerek kalıcı gizlilik ayarlarını belirtebilir. Kullanıcı, Hatırla seçeneğini belirlerse, Flash Player artık bu etki alanındaki SWF dosyalarının kameranıza erişmesine izin verip vermeyeceğini kullanıcıya sormaz.

Not: Kullanıcı, Flash Player Ayarları iletişim kutusunda Hatırla seçeneğini belirleyerek erişimi engellediyse, attachCamera() yöntemi, kameraya erişime yönelik İzin Ver veya Engelle iletişim kutusunu çağırmaz. Bu durumda, Security.showSettings(SecurityPanel.PRIVACY) kullanarak kullanıcı için Flash Player Gizlilik panelini görüntüleyip kullanıcıdan İzin Ver veya Engelle ayarını değiştirmesini isteyebilirsiniz.

getCamera() öğesi null değerini döndürürse, ya kamera başka bir uygulama tarafından kullanılıyordur ya da sistemde yüklü kamera yoktur. Herhangi bir kameranın yüklenip yüklenmediğini belirlemek için names.length özelliğini kullanın. Kullanıcının getCamera() tarafından başvurulacak kamerayı seçmesini sağlayan Flash Player Kamera Ayarları panelini görüntülemek için Security.showSettings(SecurityPanel.CAMERA) öğesini kullanın.

Donanımda kamera taraması yapılması zaman alır. Çalışma zamanı en az bir kamera bulduğunda, donanımda player örneğinin ömrü için tekrar tarama yapılmaz. Ancak çalışma zamanı bir kamera bulmazsa, getCamera her çağrıldığında tarama yapar. Kamera varsa ancak devre dışı bırakılmışsa bu yararlıdır; SWF dosyanız, getCamera öğesini çağıran bir Tekrar Dene düğmesi sağlarsa, Flash Player, kullanıcının SWF dosyasını yeniden başlatması gerekmeden kamerayı bulabilir.

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);
        
        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            if (Camera.isSupported)
            {
                cam = Camera.getCamera();
                
                 if (!cam) {
                    myTextField.text = "No camera is installed.";
                    
                } else if (cam.muted) {
                    myTextField.text = "To enable the use of the camera,\n"
                                     + "please click on this text field.\n" 
                                     + "When the Flash Player Settings dialog appears,\n"
                                     + "make sure to select the Allow radio button\n" 
                                     + "to grant access to your camera.";
    
                    myTextField.addEventListener(MouseEvent.CLICK, clickHandler);
    
                }else {
                    myTextField.text = "Connecting";
                    connectCamera(); 
                }
       
                addChild(myTextField);
    
                t.addEventListener(TimerEvent.TIMER, timerHandler);
            }else {
                myTextField.text = "The Camera class is not supported on this device.";
            }
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

Uygulama için kamera izni ister.

Hangi video karelerinin video sıkıştırma algoritması tarafından enterpolasyonlu yapılmak yerine tam (keyframes) olarak iletileceğini belirtir. Bu yöntem yalnızca Flash Media Server kullanarak video iletiyorsanız kullanılabilir.

Flash Video sıkıştırma algoritması, videonun son karesinden bu yana değişenleri ileterek videoyu sıkıştırır; bu bölümler enterpolasyonlu kareler olarak değerlendirilir. Bir videonun kareleri, önceki karenin içeriklerine göre enterpolasyonlu yapılabilir. Ancak bir anahtar kare, tam olan bir video karesidir; önceki karelerden enterpolasyonlu yapılmaz.

keyFrameInterval parametresi için bir değerin nasıl ayarlanacağını belirlemek üzere hem bant genişliği kullanımını hem de video oynatma erişilebilirliğini göz önünde bulundurun. Örneğin, keyFrameInterval için daha yüksek bir değerin belirtilmesi (anahtar kareleri daha az sıklıkla göndererek), bant genişliği kullanımını azaltır. Ancak bu, oynatma kafasını videoda belirli bir konuma yerleştirmek için gerekli süreyi artırabilir; videonun devam etmesi için daha önceki video karelerinin enterpolasyonlu yapılması gerekebilir.

Tam tersine, keyFrameInterval için daha düşük bir değerin belirtilmesi (anahtar kareleri daha fazla sıklıkla göndererek), tüm video kareleri daha fazla sıklıkla iletildiği için bant genişliği kullanımını artırır ancak kayıtlı bir videodaki belirli bir video karesini bulmak için gerekli süreyi de azaltabilir.

Parametreler

İlgili API Öğeleri

Kameranın yerel bir görünümü için sıkıştırılmış bir video akışı kullanılıp kullanılmayacağını belirtir. Bu yöntem yalnızca Flash Media Server kullanarak video iletiyorsanız kullanılabilir; compress öğesinin true değerine ayarlanması, kullanıcıların videoyu gerçek zamanlı görüntülerken videonun nasıl görüntülendiğini daha doğru şekilde görmenizi sağlar.

Sıkıştırılmış bir akış, video kalitesi ayarlarını önizleme gibi test amaçları için yararlı olsa da, büyük ölçüde işleme maliyetine yol açar; bunun nedeni, yerel görünümün yalnızca sıkıştırılmakla kalmayıp canlı bağlantıda olduğu gibi iletim için düzenlenmesi ve sonra yerel görüntüleme için sıkıştırılmasının açılmasıdır.

compress öğesini true değerine ayarladığınızda kullanılan sıkıştırma miktarını ayarlamak için Camera.setQuality() öğesini kullanın.

Parametreler

İlgili API Öğeleri

Kamera yakalama modunu belirtilen gereksinimleri en iyi şekilde karşılayan yerli moda ayarlar. Kameranın ilettiğiniz tüm parametrelerle eşleşen yerel bir modu yoksa, çalışma zamanı, istenen modu en yakın şekilde sentezleyen bir yakalama modunu seçer. Bu işleme kapsamında görüntüyü kırpma ve kareleri bırakma yer alabilir.

Varsayılan olarak, çalışma zamanı, görüntü boyutunu korumak için gerektiğinde kareleri bırakır. Bu, görüntünün boyutunu azaltma anlamına gelse de, bırakılan karelerin sayısını en aza indirgemek üzere favorArea parametresi için false değerini iletin.

Bir yerel mod seçilirken, çalışma zamanı, istenen en boy oranını olabildiğince korumaya çalışır. Örneğin, myCam.setMode(400, 400, 30) komutunu verirseniz ve kamerada kullanılabilir maksimum genişlik ve yükseklik değerleri 320 ve 288 ise, çalışma zamanı, genişliği ve yüksekliği 288'e ayarlar; bu özelliklerin aynı değere ayarlanmasıyla çalışma zamanı, istediğiniz 1:1 en boy oranını korur.

Çalışma zamanı istediğiniz değerlere en yakın eşleşen modu seçtikten sonra bu özelliklere atanan değerleri belirlemek için width, height ve fps özelliklerini kullanın.

Flash Media Server kullanıyorsanız, tekli çerçeveler yakalayabilir veya zaman aşımı fotoğrafı (TLP) oluşturabilirsiniz. Daha fazla bilgi için bkz. NetStream.attachCamera().

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.events.MouseEvent;
    import flash.display.StageScaleMode;

    public class Camera_setModeExample extends Sprite {
        private var cam:Camera;
        private var vid:Video;

        public function Camera_setModeExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;

            cam = Camera.getCamera();
            
            if (!cam) {
                trace("No camera is installed.");
            }else {
                connectCamera();
            }
        }

        private function connectCamera():void {
            vid = new Video();
            vid.width = cam.width;
            vid.height = cam.height; 
            vid.attachCamera(cam);
            addChild(vid);    

            stage.addEventListener(MouseEvent.CLICK, clickHandler);
        }
    
        private function clickHandler(e:MouseEvent):void {

            switch (cam.width) {
                case 160:
                cam.setMode(320, 240, 10); 
                break;
                case 320:
                cam.setMode(640, 480, 5); 
                break;
                default:
                cam.setMode(160, 120, 15); 
                break;
            } 

            removeChild(vid);           
            connectCamera();
        }
    }
}

activity olayını göndermek için ne kadar hareketin gerekli olduğunu belirtir. İsteğe bağlı olarak, çalışma zamanının hareketi durmuş olarak değerlendirip olay göndermeden önce geçmesi gereken milisaniye cinsinden etkinsizlik süresini ayarlar.

Not: motionLevel parametresinin değerine bakılmaksızın video görüntülenebilir. Bu parametre, videonun gerçekten yakalanıp yakalanmadığını veya görüntülenip görüntülenmediğini değil, yalnızca ne zaman ve hangi koşullarda olayın gönderileceğini belirler.

Kameranın hareketi algılamasını önlemek için, motionLevel parametresi için 100 değerini iletin; böylece hiçbir zaman activity olayı gönderilmez. (Büyük olasılıkla bu değeri, örneğin, olay gönderildiğinde normalde tetiklenecek olan işleyicileri geçici olarak devre dışı bırakmak gibi yalnızca test amaçlarıyla kullanırsınız.)

Kameranın geçerli olarak algıladığı hareket miktarını belirlemek için activityLevel özelliğini kullanın. Hareket duyarlılığı değerleri, doğrudan etkinlik değerlerine karşılık gelir. Hiç hareket olmaması, 0 etkinlik değerine karşılık gelir. Sabit hareket, 100 etkinlik değerine karşılık gelir. Hareket etmediğinizde etkinlik değeriniz, hareket duyarlılığı değerinizden daha düşüktür; hareket ettiğinizde, etkinlik değerleri genellikle hareket duyarlılığı değerinizi aşar.

Bu yöntem, Microphone.setSilenceLevel() yönteminin amacına benzer; her iki yöntem de activity olayının ne zaman gönderilmesi gerektiğini belirtmek için kullanılır. Ancak bu yöntemlerin yayın akışları üzerinde çok farklı etkileri vardır:

• Microphone.setSilenceLevel(), bant genişliğini en iyileştirmek için tasarlanmıştır. Bir ses akışı sessiz olarak değerlendirildiğinde, herhangi bir ses verisi gönderilmez. Bunun yerine, sessizliğin başladığını belirten tek bir mesaj gönderilir.
• Camera.setMotionLevel(), hareketi algılamak için tasarlanmış olup bant genişliği kullanımını etkilemez. Bir video akışı hareketi algılamasa da video yine de gönderilir.

Parametreler

İlgili API Öğeleri

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.ActivityEvent;

    public class Camera_setMotionLevelExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_setMotionLevelExample() {
            myTextField = new TextField();
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    
        
            cam = Camera.getCamera();
            
            if (!cam) {
                myTextField.text = "No camera is installed.";

            }else {
                myTextField.text = "Waiting to connect.";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                cam.setMotionLevel(5, 1000);
                cam.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
        }

        private function activityHandler(e:ActivityEvent):void {
            if (e.activating == true) {
                t.start();    
            } else {
                myTextField.text = "Everything is quiet.";
                t.stop();
            }    
        }

        private function timerHandler(event:TimerEvent):void {
             myTextField.x = 10;
             myTextField.y = cam.height + 20;
             myTextField.text = "There is some activity. Level: " + cam.activityLevel;
        }
    }
}

Saniyede maksimum bant genişliği miktarını veya giden video akışının gerekli resim kalitesini ayarlar. Genellikle bu yöntem yalnızca Flash Media Server kullanarak video iletiyorsanız kullanılabilir.

Gitmekte olan video akışının hangi öğesinin (bant genişliği kullanımı veya resim kalitesi) uygulamanız için daha önemli olduğunu belirtmek üzere bu yöntemi kullanın.

• Bant genişliği kullanımının öncelikli olduğunu belirtmek üzere bandwidth için bir değer iletin ve quality için 0 değerini iletin. Çalışma zamanı, belirtilen bant genişliği içinde olabilecek en yüksek kalitede video iletir. Gerekirse, çalışma zamanı, belirtilen bant genişliğinin aşılmasını önlemek için resim kalitesini düşürür. Genellikle, hareket arttıkça kalite düşer.
• Kalitenin öncelikli olduğunu belirtmek üzere bandwidth için 0 değerini iletin ve quality için sayısal bir değer iletin. Çalışma zamanı, belirtilen kaliteyi korumak için gerektiği kadar çok bant genişliği kullanır. Gerekirse, çalışma zamanı, resim kalitesini korumak için kare hızını düşürür. Genellikle hareket arttıkça bant genişliği kullanımı da artar.
• Bant genişliği ve kalitenin eşit düzeyde önemli olduğunu belirtmek üzere her iki parametre için de sayısal değerler iletin. Çalışma zamanı, belirtilen kaliteye sahip olan ve belirtilen bant genişliğini aşmayan videoları iletir. Gerekirse, çalışma zamanı, belirtilen bant genişliğini aşmadan resim kalitesini korumak için kare hızını düşürür.

Parametreler

İlgili API Öğeleri

Bir kamera oturum başlattığında veya sona erdirdiğinde gönderilir. activating değeri true olan bir activity olayını tetiklemek için gerekli hareket miktarını veya activating değeri false olan bir activity olayını tetiklemeden önce geçmesi gereken etkinsizlik süresini belirtmek için Camera.setMotionLevel() öğesini çağırın.

Bu olay şu özelliklere sahiptir:

Uygulama, aygıt üzerindeki kamerayı kullanmak için izin istediğinde gönderilir. İznin verildiğini veya reddedildiğini belirlemek için status özelliğinin değerini kontrol edin

İlgili API Öğeleri

Bir kamera durumunu bildirdiğinde gönderilir. Bir kameraya erişilmeden önce, çalışma zamanı, kullanıcılarına kameralarına erişime izin vermesi veya erişimi reddetmesini sağlamak için bir Gizlilik iletişim kutusunu görüntüler. code özelliğinin değeri "Camera.Muted"olursa, kullanıcı, SWF dosyasının kullanıcı kamerasına erişmesine izin vermeyi reddetmiştir. code özelliğinin değeri "Camera.Unmuted" olursa, kullanıcı, SWF dosyasının kullanıcı kamerasına erişmesine izin vermiştir.

Not: Bu olay AIR platformunda gönderilmez. Yalnızca Flash Player üzerinde kullanılır.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Çalışma zamanı tarafından yeni bir kamera karesinin işlenmesinin ardından gönderilir ve kopyalanabilir.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Not: Bu örneğin doğru şekilde çalışması için bir kameranın bilgisayarınıza takılı olması gerekir.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.media.Camera;
    import flash.media.Video;

    public class CameraExample extends Sprite {
        private var video:Video;
        
        public function CameraExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            
            var camera:Camera = Camera.getCamera();
            
            if (camera != null) {
                camera.addEventListener(ActivityEvent.ACTIVITY, activityHandler);
                video = new Video(camera.width * 2, camera.height * 2);
                video.attachCamera(camera);
                addChild(video);
            } else {
                trace("You need a camera.");
            }
        }
        
        private function activityHandler(event:ActivityEvent):void {
            trace("activityHandler: " + event);
        }
    }
}