| Paket | flash.text.engine |
| Sınıf | public final class TextElement |
| Miras Alma | TextElement  ContentElement Object |
| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
content özelliğine bir TextElement nesnesi atayın. Bunu diğer metin ve grafik öğeleriyle bir birim olarak birleştirmek için bir GroupElement nesnesine atayın. Metni biçimlendirmek için ElementFormat sınıfını kullanın.
İlgili API Öğeleri
Genel Özellikler
Miras Alınan Genel Özellikleri Gizle
Miras Alınan Genel Özellikleri Göster| Özellik | Tanımlayan: | ||
|---|---|---|---|
 | constructor : Object
Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru. | Object | |
| elementFormat : ElementFormat
Öğe için kullanılan ElementFormat nesnesi. | ContentElement | |
| eventMirror : EventDispatcher
Bu içerik öğesi esas alınarak geçerli metin satırlarına gönderilen her olayın kopyalarını alan EventDispatcher nesnesi. | ContentElement | |
| groupElement : GroupElement [salt okunur]
Bu öğeyi içeren GroupElement nesnesi veya grupta yer almıyorsa null değeri. | ContentElement | |
| rawText : String [salt okunur]
U+FDEF karakterleri de dahil olmak üzere, öğedeki metnin bir kopyası. | ContentElement | |
| text : String
Öğenin içeriği olan metni alır. | TextElement | ||
| textBlock : flash.text.engine:TextBlock [salt okunur]
Bu öğenin ait olduğu TextBlock. | ContentElement | |
| textBlockBeginIndex : int [salt okunur]
Bu öğenin birinci karakterinin metin bloğundaki dizin. | ContentElement | |
| textRotation : String
Bir birim olarak öğeye uygulanacak döndürme değeri. | ContentElement | |
| userData : *
Uygulamaya, rastgele verileri öğeyle ilişkilendirme yolu sağlar. | ContentElement | |
Genel Yöntemler
| Yöntem | Tanımlayan: | ||
|---|---|---|---|
TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")
Yeni bir TextElement örneği oluşturur. | TextElement | ||
|
Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir. | Object | |
|
Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir. | Object | |
|
Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir. | Object | |
beginIndex ve endIndex parametrelerinin newText parametresinin içeriğini belirttiği karakter aralığını değiştirir. | TextElement | ||
|
Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar. | Object | |
|
Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür. | Object | |
|
Belirtilen nesnenin dize olarak temsil edilen halini döndürür. | Object | |
|
Belirtilen nesnenin temel değerini döndürür. | Object | |
Özellik Ayrıntısı
text | özellik |
Yapıcı Ayrıntı
TextElement | () | Yapıcı |
public function TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Yeni bir TextElement örneği oluşturur.
Parametrelertext:String (default = null)null şeklindedir.
| |
elementFormat:ElementFormat (default = null)null şeklindedir.
| |
eventMirror:EventDispatcher (default = null)EventDispatcher nesnesi. Varsayılan değer null şeklindedir.
| |
textRotation:String (default = "rotate0")TextRotation sabitlerini kullanın. Varsayılan değer TextRotation.ROTATE_0 olur.
|
Örnek ( Bu örnek nasıl kullanılır? )
Şu örnek, metin dizesinden bir TextElement nesnesi oluşturur, 12 font boyutunu ve kırmızı rengini (0xCC0000) kullanarak bu nesneyi biçimler ve bir TextBlock öğesinin
content özelliğine atar. Metin bloğunu her biri 150 pikselden oluşan satırlara kesmek için createLines() işlevini çağırır.
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.ElementFormat;
public class TextElementExample extends Sprite {
public function TextElementExample():void {
var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " +
"sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut " +
"enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut " +
"aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit " +
"in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur " +
"sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt " +
"mollit anim id est laborum.";
var format:ElementFormat = new ElementFormat(null, 12, 0xCC0000);
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
createLines(textBlock);
}
private function createLines(textBlock:TextBlock):void {
var yPos = 20;
var textLine:TextLine = textBlock.createTextLine (null, 150);
while (textLine)
{
addChild(textLine);
textLine.x = 15;
yPos += textLine.textHeight+2;
textLine.y = yPos;
textLine = textBlock.createTextLine(textLine, 150);
}
}
}
}
Yöntem Ayrıntısı
replaceText | () | yöntem |
public function replaceText(beginIndex:int, endIndex:int, newText:String):void| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5, Flash Lite 4 |
beginIndex ve endIndex parametrelerinin newText parametresinin içeriğini belirttiği karakter aralığını değiştirir. beginIndex ve endIndex değerleri, text öğesinin geçerli içeriklerini ifade eder.
Metni silmek için, newText için null değerini iletin.
Metin eklemek için, beginIndex ve endIndex için aynı değeri iletin. Yeni metin, belirtilen dizinden önce eklenir.
Metin eklemek üzere, beginIndex veendIndex öğeleri için text.length öğesini iletin.
Metnin tamamını ayarlamak üzere, beginIndex için 0 ve endIndex için de text.length öğesini iletin.
Parametreler
beginIndex:int — Değiştirme aralığının başlangıcı için sıfır temelli dizin değeri.
| |
endIndex:int — Değiştirme aralığının bitişini izleyen sıfır temelli dizin değeri.
| |
newText:String — Belirtilen karakter aralığını değiştirmek için kullanılan metin.
|
Atar
RangeError — Belirtilen beginIndex veya endIndex aralık dışındadır.
|
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, şunu yapmak için birçok defa
replaceText() öğesini çağırır:
- metnin başına dize ekleme
- metnin sonuna dize ekleme
- metnin ortasına dize ekleme
- metnin tamamını yeni bir metinle değiştirme
package {
import flash.display.Sprite;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.TextElement;
import flash.text.engine.TextBlock;
import flash.text.engine.TextLine;
public class TextElement_replaceTextExample extends Sprite {
public function TextElement_replaceTextExample():void {
var str:String = "0123456";
var fontDescription:FontDescription = new FontDescription("Arial");
var format:ElementFormat = new ElementFormat(fontDescription);
format.fontSize = 14;
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
textElement.replaceText(0, 0, "abc");
createLine(textBlock, 20); //"abc0123456"
textElement.replaceText(10, 10, "abc");
createLine(textBlock, 40); // "abc0123456abc"
textElement.replaceText(5, 8, "abc");
createLine(textBlock, 60); // "abc01abc56abc"
textElement.replaceText(0, 13, "abc");
createLine(textBlock, 80); // "abc"
textElement.replaceText(0, 3, "That's all she wrote!");
createLine(textBlock, 100); // "That's all she wrote" */
}
private function createLine(textBlock:TextBlock, y:Number):void {
var textLine:TextLine = textBlock.createTextLine(null, 150);
textLine.x = 10;
textLine.y = y;
addChild(textLine);
}
}
}
Tue Jun 12 2018, 01:09 PM Z