StyleManager

Paket	fl.managers
Sınıf	public class StyleManager
Miras Alma	StyleManager Object

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

StyleManager sınıfı, bir Flash belgesindeki bileşen örneği, bir bileşen türünün tamamı veya tüm arabirim bileşenleri için stilleri almakta ve ayarlamakta kullanılabilecek statik yöntemler sağlar. Stiller, bir bileşenin dolgu, metin biçimleri ve kaplamalar gibi görüntülenme şekillerini etkileyen değerler şeklinde tanımlanır.

Örnekleri görüntüle

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		StyleManager() Yeni StyleManager nesnesi oluşturur.	StyleManager
		clearComponentStyle(component:Object, name:String):void [statik] Belirtilen bileşenden bir stil kaldırır.	StyleManager
		clearStyle(name:String):void [statik] Bir belgedeki tüm kullanıcı arabirimi bileşenlerinden global bir stili kaldırır.	StyleManager
		getComponentStyle(component:Object, name:String):Object [statik] Belirli bir bileşende varolan olan bir stili alır.	StyleManager
		getStyle(name:String):Object [statik] Ada göre genel bir stil alır.	StyleManager
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		registerInstance(instance:UIComponent):void [statik] Bir bileşen örneğini stil yöneticisi ile kaydeder.	StyleManager
		setComponentStyle(component:Object, name:String, style:Object):void [statik] Bir bileşen türünün tüm örneklerine, örneğin bir Button bileşeninin tüm örneklerine veya bir ComboBox bileşeninin tüm örneklerine, bir stil ayarlar.	StyleManager
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		setStyle(name:String, style:Object):void [statik] Bir belgedeki tüm kullanıcı arabirimi bileşenleri için genel bir stil ayarlar.	StyleManager
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String Belirtilen nesnenin dize olarak temsil edilen halini döndürür.	Object
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object

Yapıcı Ayrıntı

()

Yapıcı

public function StyleManager()

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Yeni StyleManager nesnesi oluşturur.

Yöntem Ayrıntısı

clearComponentStyle

()

yöntem

public static function clearComponentStyle(component:Object, name:String):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Belirtilen bileşenden bir stil kaldırır.

Parametreler

	`component:Object` — Stilin kaldırılacağı bileşenin adı.

	`name:String` — Kaldırılacak stilin adı.

İlgili API Öğeleri

clearStyle()
getComponentStyle()
setComponentStyle()

clearStyle

()

yöntem

public static function clearStyle(name:String):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir belgedeki tüm kullanıcı arabirimi bileşenlerinden global bir stili kaldırır.

Parametreler

name:String — Kaldırılacak global stilin adı.

İlgili API Öğeleri

clearComponentStyle()
getStyle()
setStyle()

getComponentStyle

()

yöntem

public static function getComponentStyle(component:Object, name:String):Object

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Belirli bir bileşende varolan olan bir stili alır.

Parametreler

	`component:Object` — İstenen stili bulmaya yönelik bileşen örneğinin adı.

	`name:String` — Alınacak stilin adı.

Döndürür

Object — Belirtilen bileşenden istenen stil. Belirtilen değer bulunmazsa bu işlev null değerini döndürür.

İlgili API Öğeleri

clearComponentStyle()
getStyle()
setComponentStyle()

getStyle

()

yöntem

public static function getStyle(name:String):Object

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Ada göre global bir stil alır.

Parametreler

name:String — Alınacak stilin adı.

Döndürür

Object — Alınan global stilin değeri.

İlgili API Öğeleri

clearStyle()
getComponentStyle()
setStyle()

registerInstance

()

yöntem

public static function registerInstance(instance:UIComponent):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir bileşen örneğini stil yöneticisi ile kaydeder. Bir bileşen örneği başlatıldıktan sonra, stildeki değişiklikler hakkında bilgi alacak şekilde stil yöneticisi ile kaydedilebilir. Bileşen örnekleri, bileşen temelli veya aslen global olan değişiklikler hakkında bilgi alacak şekilde kaydedilebilir.

Parametreler

instance:UIComponent — Stil yönetimi için kaydedilecek bileşen örneği.

setComponentStyle

()

yöntem

public static function setComponentStyle(component:Object, name:String, style:Object):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir bileşen türünün tüm örneklerine, örneğin bir Button bileşeninin tüm örneklerine veya bir ComboBox bileşeninin tüm örneklerine, bir stil ayarlar.

Parametreler

	`component:Object` — Bileşenin türü, örneğin Button veya ComboBox. Bu parametre de, bir bileşen türünün tüm örneklerini tanımlamak için kullanılabilen bir bileşen örneğini veya sınıfını kabul eder.

	`name:String` — Ayarlanacak stilin adı.

	`style:Object` — Ayarlanacak stili tanımlayan stil nesnesi.

İlgili API Öğeleri

clearComponentStyle()
getComponentStyle()
setStyle()

setStyle

()

yöntem

public static function setStyle(name:String, style:Object):void

Dil Sürümü:

ActionScript 3.0

Ürün Sürümü:

Flash CS3

Çalışma Zamanı Sürümleri:

Flash Player 9.0.28.0, AIR 1.0

Bir belgedeki tüm kullanıcı arabirimi bileşenleri için genel bir stil ayarlar.

Parametreler

	`name:String` — Ayarlanacak stile ad veren bir String değeri.

	`style:Object` — Ayarlanacak stil nesnesi. Bu özelliğin değeri, kullanıcının ayarladığı stile bağlıdır. Örneğin, stil "textFormat" öğesine ayarlanmışsa, stil özelliği bir TextFormat nesnesine ayarlanmalıdır. Stil adı ve stil özelliği değeri arasındaki bir uyuşmazlık, bileşenin hatalı bir davranış göstermesine neden olabilir.

İlgili API Öğeleri

clearStyle()
getStyle()
setComponentStyle()

Örnekler Bu örnek nasıl kullanılır?

StyleManagerExample.as

Bu örnek, nasıl dinamik olarak bir DataGrid öğesinin oluşturulacağını ve olaylarının dinleneceğini gösterir.

Örneği çalıştırmak için şu adımları izleyin:

Kütüphaneye DataGrid, Button, Label ve TextArea bileşenlerini ekleyin.
Bu kodu FLA dosyanızla aynı dizine StyleManagerExample.as olarak kaydedin.
FLA dosyasındaki Document sınıfını StyleManagerExample olarak ayarlayın.

package
{
    import fl.controls.Button;
    import fl.controls.DataGrid;
    import fl.controls.Label;
    import fl.controls.TextArea;
    import fl.core.UIComponent;
    import fl.managers.FocusManager;
    import fl.managers.StyleManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class StyleManagerExample extends Sprite 
    {
        private var btn:Button;
        private var ta1:TextArea;
        private var ta2:TextArea;
        private var ta3:TextArea;
        private var ta4:TextArea;
        private var description:Label;
        private var dg:DataGrid;
        private var formatForInstance:TextFormat;
        private var formatForGlobal:TextFormat;
        
        private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
        private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
        
        public function StyleManagerExample() {
            setupComponents();
            setupUI();
            setupStyles();
        }
        private function setupUI():void {
            var setInstanceStyleBtn:Button = new Button();
            var clearInstanceStyleBtn:Button = new Button();
            var setClassStyleBtn:Button = new Button();
            var clearClassStyleBtn:Button = new Button();
            var setGlobalStyleBtn:Button = new Button();
            var clearGlobalStyleBtn:Button = new Button();
            
            setInstanceStyleBtn.label = "Set Instance Style";
            clearInstanceStyleBtn.label = "Clear Instance Style";
            setClassStyleBtn.label = "Set Class Style";
            clearClassStyleBtn.label = "Clear Class Style";
            setGlobalStyleBtn.label = "Set Global Style";
            clearGlobalStyleBtn.label = "Clear Global Style";
            setInstanceStyleBtn.focusEnabled = false;
            clearInstanceStyleBtn.focusEnabled = false;
            setClassStyleBtn.focusEnabled = false;
            clearClassStyleBtn.focusEnabled = false;
            setGlobalStyleBtn.focusEnabled = false;
            clearGlobalStyleBtn.focusEnabled = false;
            
            setInstanceStyleBtn.move(10,310);
            clearInstanceStyleBtn.move(10,340);
            setClassStyleBtn.move(140,310);
            clearClassStyleBtn.move(140,340);
            setGlobalStyleBtn.move(270,310);
            clearGlobalStyleBtn.move(270,340);
            setInstanceStyleBtn.setSize(120,24);
            clearInstanceStyleBtn.setSize(120,24);
            setClassStyleBtn.setSize(120,24);
            clearClassStyleBtn.setSize(120,24);
            setGlobalStyleBtn.setSize(120,24);
            clearGlobalStyleBtn.setSize(120,24);
            
            setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
            clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
            setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
            clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
            setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
            clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);

            description = new Label();
            description.move(10, 370);
            description.autoSize = TextFieldAutoSize.LEFT;
            description.text = "";

            addChild(setInstanceStyleBtn);
            addChild(clearInstanceStyleBtn);
            addChild(setClassStyleBtn);
            addChild(clearClassStyleBtn);
            addChild(setGlobalStyleBtn);
            addChild(clearGlobalStyleBtn);
            addChild(description);
        }
        private function setupComponents():void {
            dg = new DataGrid();
            dg.addItem( { Name:"John Alpha",     Number:"555-123-0101" } );
            dg.addItem( { Name:"Mary Bravo",     Number:"555-372-3322" } );
            dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
            dg.addItem( { Name:"Susan Delta",     Number:"555-987-3434" } );        
            dg.move(10,10);
            dg.setSize(200,290);
            dg.columns = ["Name","Number"];
            addChild(dg);
            
            ta1 = new TextArea();
            ta1.move(220,10);
            ta1.setSize(150,140);
            ta1.text = testString;
            ta1.tabEnabled = true;
            addChild(ta1);
            
            ta2 = new TextArea();
            ta2.move(380,10);
            ta2.setSize(150,140);
            ta2.text = testString;
            ta2.tabEnabled = true;
            addChild(ta2);
            
            ta3 = new TextArea();
            ta3.move(220,160);
            ta3.setSize(150,140);
            ta3.text = testString;
            ta3.tabEnabled = true;
            addChild(ta3);
            
            ta4 = new TextArea();
            ta4.move(380,160);
            ta4.setSize(150,140);
            ta4.text = testString;
            ta4.tabEnabled = true;
            addChild(ta4);
        }
        private function setupStyles():void {
            formatForGlobal = new TextFormat();
            formatForGlobal.font = "Georgia";
            formatForGlobal.size = 10;
            formatForInstance = new TextFormat();
            formatForInstance.underline = true;            
        }
        private function setInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.setStyle("textFormat",formatForInstance);    
                description.text = "The TextArea object with focus is now underlined.";            
            }
        }
        private function clearInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.clearStyle("textFormat");
                description.text = "The TextArea object with focus is no longer underlined.";
            }
        }
        private function setClassStyle(e:MouseEvent):void {
            var c:Class = TextArea;
            var styleName:String = "textPadding";
            var value:Number = 10;
            StyleManager.setComponentStyle(c,styleName,value);    
            description.text = "Padding for all TextArea instances is now 10.";
        }
        private function clearClassStyle(e:MouseEvent):void {
            var styleName:String = "textPadding";
            var c:Class = TextArea;
            StyleManager.clearComponentStyle(c,styleName);                    
            description.text = "TextArea padding has been reset to the default.";
        }
        private function setGlobalStyle(e:MouseEvent):void {            
            var styleName:String = "textFormat";
            var value:Object = formatForGlobal;
            StyleManager.setStyle(styleName,value);
            description.text = "All components now use font Georgia size 10.";
        }
        private function clearGlobalStyle(e:MouseEvent):void {
            var styleName:String = "textFormat";
            StyleManager.clearStyle(styleName);    
            description.text = "Font style for all components has been cleared.";
        }
    }
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

StyleManager - AS3 Flash

Paketlerx

Dil Öğeleri

Ekler

Paket fl.managers

StyleManager

clearComponentStyle

clearStyle

getComponentStyle

getStyle

registerInstance

setComponentStyle

setStyle