TextLineMetrics  - AS3

Metnin çıkış değeri satır taban çizgisiyle satır yüksekliğinin en üst noktası arasındaki mesafenin piksel olarak uzunluğudur. Bu sınıfa yönelik genel bakış şemasındaki “Çıkış“ ölçümüne bakın.

İlgili API Öğeleri

Metnin iniş değeri satır taban çizgisiyle çizginin alt derinliği arasındaki mesafenin piksel olarak uzunluğudur. Bu sınıfa yönelik genel bakış şemasındaki “İniş“ ölçümüne bakın.

İlgili API Öğeleri

Seçilen satırlardaki metnin (metnin tamamının olması gerekmez) yükseklik değeri. Metnin yüksekliği cilt payı yüksekliğini içermez. Bu sınıfa yönelik genel bakış şemasındaki “Satır yüksekliği“ ölçümüne bakın.

İlgili API Öğeleri

Satır aralığı değeri metnin satırları arasındaki dikey mesafenin ölçümüdür. Bu sınıfa yönelik genel bakış şemasındaki “Satır aralığı“ ölçümüne bakın.

İlgili API Öğeleri

Genişlik değeri seçilen satırlardaki metnin (metnin tamamının olması gerekmez) piksel olarak genişliğidir. Metin satırının genişliği, metin alanının genişliğiyle aynı değildir. Metin satırının genişliği metin alanının genişliğinden 4 piksellik (her iki tarafta 2 piksel) cilt payı çıkarıldığında elde edilen değere eşdeğerdir. Bu sınıfa yönelik genel bakış şemasındaki “Metin Satırı genişliği“ ölçümüne bakın.

İlgili API Öğeleri

x değeri ilk karakterin piksel olarak sola doğru olan konumudur. Bu değer kenar boşluğunu, girintiyi (varsa) ve cilt payı genişliklerini içerir. Bu sınıfa yönelik genel bakış şemasındaki "Metin Satırı x-konumu" bölümüne bakın.

İlgili API Öğeleri

Bir TextLineMetrics nesnesi oluşturur. TextLineMetrics sınıfı bir metin alanındaki bir metin satırının metin ölçümleri hakkında bilgiler içerir. Bu sınıfın nesneleri flash.text.TextField.getLineMetrics() yöntemiyle döndürülür.

Bağlamdaki özellikler için bu sınıfa genel bakıştaki şekle bakın.

İlgili API Öğeleri

1. label adlı TextField türünde bir özellik oluşturun.
2. Yapıcı şu işlemleri gerçekleştiren configureAssets() öğesini çağırır.
   • Sahne alanının hizalamasını sol üst ve ölçeksiz olarak ayarlar.
   • label adlı yeni bir TextField nesnesi oluşturur.
   • label öğesinin arka planını etkinleştirir ve rengi beyaz olarak ayarlar.
   • label öğesinin metninin, otomatik kelime kaydırmayı kullanarak birden çok satırı yaymasına izin verir.
   • getLabelText() öğesine yapılan bir çağrının sonucunu label öğesinin text özelliğine atar. getLabelText() yöntemi XML türünde bir değişken oluşturur ve bunu uzun bir cümleyle doldurulan body adlı bir XML düğümüne atar.
   • addChild() öğesini kullanarak label öğesini görüntüleme nesnesine ekler.
3. Daha sonra, sahne alanı üzerinde gerçekleştirilen resize olaylarını dinleyen resizeHandler() adlı bir yöntem eklenir. Flash Player pencere boyutu her değiştiğinde, bir RESIZE olayı gönderilir ve şunlar meydana gelir:
   • label öğesinin sahne alanının merkezinde görüntülendiğinden ve 10 piksellik bir arabellek tarafından çevrelendiğinden emin olmak için draw() yöntemi çağrılır.
   • Ardından kısa bir gecikmeden sonra setTimeout() öğesi showMetrics() öğesini yürütür. RESIZE olayı tamamlanana ve sahne alanı tamamen yeniden çizilene kadar satır ölçüleri güncellenmediğinden gecikme eklenir.
   • showMetrics(), getLineMetrics() öğesine yapılan bir çağrının sonucuna metrics adlı bir TextLineMetrics değişkeni gönderir ve bu değişken ardından reader adlı yeni bir LineMetricsReader örneğine iletilir. Ardından ilk (ve tek) label satırını ve toString() yöntemi üzerinden LineMetricsReader örneği tarafından sağlanan bilgileri yazdırmak için trace() öğesine yapılan çağrılar içerisinde iki değişken kullanılır.
4. SWF dosyası ilk yüklendiğinde label öğesinin doğru çizilmesini zorlamak için, yapıcı resize olayının bir kez gönderilmesini zorlar.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}