StorageVolume

Paket	flash.filesystem
Sınıf	public class StorageVolume
Miras Alma	StorageVolume Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

StorageVolume nesnesi, yığın saklama birimini tanımlayan özellikleri içerir. Bu sınıf iki şekilde kullanılır:

StorageVolumeChangeEvent nesnesinin storageVolume özelliği bir StorageVolume nesnesidir. Bu nesne, takılan veya çıkarılan saklama birimini temsil eder.
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() yöntemi, StorageVolume nesnelerinin vektör öğesini döndürür. Bu StorageVolume nesnelerinin her biri takılan bir saklama birimini temsil eder.

Örnekleri görüntüle

İlgili API Öğeleri

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		drive : String [salt okunur] Windows'ta birim sürücüsünün harfi.	StorageVolume
		fileSystemType : String [salt okunur] Saklama birimindeki dosya sisteminin türü (örn. "FAT", "NTFS", "HFS" veya "UFS").	StorageVolume
		isRemovable : Boolean [salt okunur] İşletim sisteminin depolama birimini çıkarılabilir olarak görüp görmediği (görüyorsa, true; görmüyorsa, false).	StorageVolume
		isWritable : Boolean [salt okunur] Bir birimin yazılabilir olup (true) olmadığı (false).	StorageVolume
		name : String [salt okunur] Birimin adı.	StorageVolume
		rootDirectory : File [salt okunur] Birimin kök dizinine karşılık gelen bir File nesnesi.	StorageVolume

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) Yapıcı işlevi.	StorageVolume
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String Belirtilen nesnenin dize olarak temsil edilen halini döndürür.	Object
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object

Özellik Ayrıntısı

drive

özellik

drive:String [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Windows'ta birim sürücüsünün harfi. Diğer platformlarda bu özellik null değerine ayarlanır.

Uygulama
public function get drive():String

fileSystemType

özellik

fileSystemType:String [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Saklama birimindeki dosya sisteminin türü (örn. "FAT", "NTFS", "HFS" veya "UFS").

Uygulama
public function get fileSystemType():String

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki kod, her bir takılı saklama biriminin kök dizini için yerel yolu ve dosya sistemi türünü listeler.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

özellik

isRemovable:Boolean [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

İşletim sisteminin depolama birimini çıkarılabilir olarak görüp görmediği (görüyorsa, true; görmüyorsa, false).

Aşağıdaki tablo, çeşitli aygıt türlerinin StorageVolume.isRemovable özelliğinin değerini listeler.

Aygıtın türü	Mac OS	Windows	Linux
CD/DVD (sabit)	true	true	true
USB flash bellek	true	true	true
USB sabit sürücü	false	false	true
FireWire sabit sürücü	false	false	true
Paylaşılan birim	true	false	- ¹
Ağ sürücüsü	false	false	false
Kart okuyucusu (boş)	- ²	false	- ²
Kart okuyucusu (SD/CF kartı ile)	true	true	true

¹ Linux'ta paylaşılan birim kavramı yoktur.

² Windows'ta, boş bir kart okuyucusu çıkarılamayan bir aygıt olarak listelenir. Mac OS ve Linux'ta boş kart okuyucuları saklama birimleri olarak listelenmez.

Uygulama
public function get isRemovable():Boolean

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki kod, ardından çıkarılabilir saklama birimlerinin bir listesi gelecek şekilde, çıkarılamayan saklama birimlerinin bir listesinin çıktısını verir.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

özellik

isWritable:Boolean [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Bir birimin yazılabilir olup (true) olmadığı (false).

Not: StorageVolume nesnesinin rootDirectory.spaceAvailble özelliğini çağırarak bir birimde kullanılabilir olan alan miktarını belirleyebilirsiniz.

Uygulama
public function get isWritable():Boolean

İlgili API Öğeleri

flash.fileSystem.File.spaceAvailable

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki kod, yazılabilir saklama birimlerinin ve bu birimlerdeki kullanılabilir alanların bir listesinin çıktısını verir.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

özellik

name:String [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Birimin adı. Bir ad yoksa, bu özellik null değerine ayarlanır.

Uygulama
public function get name():String

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki kod, her bir takılı saklama biriminin kök dizini için yerel yolu ve dosya sistemi adını (varsa) listeler.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

özellik

rootDirectory:File [salt okunur]

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Birimin kök dizinine karşılık gelen bir File nesnesi.

Uygulama
public function get rootDirectory():File

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki kod, her bir takılı saklama biriminin kök dizini için yerel yolu listeler.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Yapıcı Ayrıntı

()

Yapıcı

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Yapıcı işlevi. Genellikle bu yapıcı işlevini doğrudan çağırmazsınız (yeni StorageVolume nesneleri oluşturmak için). Bunun yerine, StorageVolumeChangeEvent nesnesinin storageVolume özelliğine erişerek veya StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() öğesini çağırarak StorageVolume nesnelerine başvurursunuz.

Parametreler

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Örnekler Bu örnek nasıl kullanılır?

StorageVolumeExample.as

Aşağıdaki kod, takılan saklama biriminin her birinin özelliklerini listeler:

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

Aşağıdaki kod, takılan veya çıkarılan saklama biriminin her birinin özelliklerini listeler. StorageVolumeChangeEvent öğesinin storageVolume özelliğinin yalnızca storageVolumeMount olayı için ayarlandığını; bunun storageVolumeUnmount olayı için null olduğunu unutmayın:

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

StorageVolume - AS3

Sınıflar x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume