XML

Paket	Üst Düzey
Sınıf	public final dynamic class XML
Miras Alma	XML Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9, Flash Lite 4

XML sınıfı XML nesneleriyle çalışmak için yöntemler ve özellikler içerir. XML sınıfı (aynı zamanda XMLList, Namespace ve QName sınıfları da) XML için ECMAScript (E4X) ifadesinde (ECMA-357 sürüm 2) tanımlanan güçlü XML işleme standartlarını uygular.

XML nesnesinin basit veya karmaşık içeriğe sahip olduğuna bakılmaksızın XML nesnesinin dize olarak temsil edilen bir halini döndürmek için toXMLString() yöntemini kullanın.

Not: ActionScript 2.0'daki XML sınıfı (aynı zamanda ilgili sınıflar) XMLDocument olarak yeniden adlandırılmış ve flash.xml paketine taşınmıştır. Geriye dönük olarak uyumluluk sağlamak için ActionScript 3.0'a dahil edilmiştir.

Örnekleri görüntüle

Daha fazla bilgi

XML belirtimi için ECMASCript (E4X) (ECMA-357 sürüm 2)

İlgili API Öğeleri

Namespace
QName
XMLList
XML.toXMLString()

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		ignoreComments : Boolean [statik] XML nesneleri kaynak XML verilerini ayrıştırırken XML yorumlarının yok sayılıp yok sayılmayacağını belirler.	XML
		ignoreProcessingInstructions : Boolean [statik] XML nesneleri kaynak XML verilerini ayrıştırırken XML işleme talimatlarının yok sayılıp yok sayılmayacağını belirler.	XML
		ignoreWhitespace : Boolean [statik] Metin düğümlerinin başında ve sonundaki beyaz boşluk karakterlerinin ayrıştırma sırasında yok sayılıp yok sayılmayacağını belirler.	XML
		prettyIndent : int [statik] toString() ve toXMLString() yöntemleri tarafından, XML.prettyPrinting özelliği true yapıldığında uygulanan girinti miktarını belirler.	XML
		prettyPrinting : Boolean [statik] toString() ve toXMLString() yöntemlerinin bazı etiketler arasındaki beyaz boşluk karakterlerini normalleştirip normalleştirmeyeceğini belirler.	XML

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		XML(value:Object) Yeni bir XML nesnesi oluşturur.	XML
		addNamespace(ns:Object):XML XML nesnesi için kapsam dahilindeki ad alanları kümesine bir ad alanı ekler.	XML
		appendChild(child:Object):XML Belirli bir alt öğeyi XML nesnesinin özelliklerinin sonuna ekler.	XML
		attribute(attributeName:*):XMLList attributeName parametresi ile eşlenen ada sahip XML niteliğinin değerini döndürür.	XML
		attributes():XMLList Belirli bir XML nesnesi için bir nitelik değerleri listesi döndürür.	XML
		child(propertyName:Object):XMLList Bir XML nesnesinin alt öğelerini listeler.	XML
		childIndex():int Bu XML nesnesinin üst öğesi bağlamında sıfır dizinli konumunu tanımlar.	XML
		children():XMLList XML nesnesinin alt öğelerini, göründükleri sırada listeler.	XML
		comments():XMLList XML yorumlarını içeren XML nesnesinin özelliklerini listeler.	XML
		contains(value:XML):Boolean XML nesnesini verilen değer parametresi ile karşılaştırır.	XML
		copy():XML Belirli bir XML nesnesinin bir kopyasını döndürür.	XML
		defaultSettings():Object [statik] Şu özellikleri varsayılan değerlere ayarlı bir nesne döndürür: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent ve prettyPrinting.	XML
		descendants(name:Object = *):XMLList XML nesnesinin belirli bir name parametresine sahip tüm alt öğelerini (alt öğe, alt alt öğe vb.) döndürür.	XML
		elements(name:Object = *):XMLList Bir XML nesnesinin öğelerini listeler.	XML
		hasComplexContent():Boolean XML nesnesinde karmaşık içerik olup olmadığını kontrol eder.	XML
		hasOwnProperty(p:String):Boolean Nesnenin p parametresiyle belirtilen özelliği olup olmadığını kontrol eder.	XML
		hasSimpleContent():Boolean XML nesnesinde basit içerik olup olmadığını kontrol eder.	XML
		inScopeNamespaces():Array Nesnenin üst öğesini esas alarak XML nesnesinin ad alanlarını listeler.	XML
		insertChildAfter(child1:Object, child2:Object):* Bu XML nesnesindeki verilen child2 parametresini child1 parametresinden sonraya ekler ve sonuç nesnesini döndürür.	XML
		insertChildBefore(child1:Object, child2:Object):* Bu XML nesnesindeki verilen child2 parametresini child1 parametresinden önceye ekler ve sonuç nesnesini döndürür.	XML
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		length():int XML nesneleri için bu yöntem daima 1 tam sayısını döndürür.	XML
		localName():Object XML nesnesinin nitelenmiş adının yerel ad bölümünü verir.	XML
		name():Object XML nesnesinin nitelenmiş adını verir.	XML
		namespace(prefix:String = null):* Herhangi bir parametre verilmezse, bu XML nesnesinin nitelenmiş adı ile ilişkilendirilmiş ad alanını verir.	XML
		namespaceDeclarations():Array Kendi üst öğesi bağlamında XML nesnesi ile ilişkili ad alanı bildirimlerini listeler.	XML
		nodeKind():String Düğüm türünü belirtir: metin, yorum, işleme talimatı, nitelik veya öğe.	XML
		normalize():XML XML nesnesi ve tüm alt XML nesneleri için bitişik metin düğümlerini birleştirir ve boş metin düğümlerini giderir.	XML
		parent():* XML nesnesinin üst öğesini döndürür.	XML
		prependChild(value:Object):XML Sağlanan alt nesnenin bir kopyasını XML öğesine, o öğenin var olan XML özelliklerinin öncesine ekler.	XML
		processingInstructions(name:String = "*"):XMLList Bir name parametresi sağlanırsa, XML nesnesinin o ada sahip işleme talimatlarını içeren tüm alt öğelerini listeler.	XML
		propertyIsEnumerable(p:String):Boolean p özelliğinin, XML nesnesine uygulanan bir for..in ifadesinde yinelenebilen özellikler kümesinde olup olmadığını kontrol eder.	XML
		removeNamespace(ns:Namespace):XML Bu nesnenin ve tüm alt öğelerinin verilen ad alanını kaldırır	XML
		replace(propertyName:Object, value:XML):XML propertyName parametresi ile belirtilen özellikleri belirli bir değer parametresi ile değiştirir.	XML
		setChildren(value:Object):XML XML nesnesinin alt öğe özelliklerini, value parametresinde sağlanan belirli XML özellik kümesiyle değiştirir.	XML
		setLocalName(name:String):void XML nesnesinin yerel adını belirli bir name parametresine çevirir.	XML
		setName(name:String):void XML nesnesinin adını belirli bir nitelenmiş ad veya nitelik adı olarak ayarlar.	XML
		setNamespace(ns:Namespace):void XML nesnesi ile ilişkili ad alanını ayarlar.	XML
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		setSettings(... rest):void [statik] Şu XML özelliklerinin değerlerini ayarlar: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent ve prettyPrinting.	XML
		settings():Object [statik] Şu özellikleri alır: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent ve prettyPrinting.	XML
		text():XMLList XML nesnesinin, XML metin düğümlerini temsil eden tüm XML özelliklerinin bir XMLList nesnesini döndürür.	XML
		toJSON(k:String):* Bir XML nesnesindeki değerlerin JSON kodlamasını özelleştirmek için geçersiz kılınabilir bir yöntem sağlar.	XML
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String XML nesnesinin dize olarak temsilini döndürür.	XML
		toXMLString():String XML nesnesinin dize olarak temsilini döndürür.	XML
		valueOf():XML XML nesnesini döndürür.	XML

Özellik Ayrıntısı

ignoreComments

özellik

ignoreComments:Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesneleri kaynak XML verilerini ayrıştırırken XML yorumları göz ardı ediliyor mu, belirler. Varsayılan olarak, yorumlar yok sayılır (true). XML yorumlarını dahil etmek için bu özelliği false değerine ayarlayın. ignoreComments özelliği, myXMLObject.child(*).toXMLString() gibi herhangi bir yöntem çağrılırken değil, yalnızca XML ayrıştırması sırasında kullanılır. Kaynak XML, yorum düğümleri içeriyorsa, bunlar XML ayrıştırması sırasında tutulur veya atılır.

Uygulama
public static function get ignoreComments():Boolean
public static function set ignoreComments(value:Boolean):void

İlgili API Öğeleri

XML.child()
XML.toXMLString()

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, XML.ignoreComments öğesinin false ve true değerine ayarlanmasının etkisini gösterir:

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreProcessingInstructions

özellik

ignoreProcessingInstructions:Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesneleri kaynak XML verilerini ayrıştırırken XML işleme talimatları göz ardı ediliyor mu, belirler. Varsayılan olarak, işleme talimatları yok sayılır (true). XML işleme talimatlarını dahil etmek için bu özelliği false değerine ayarlayın. ignoreProcessingInstructions özelliği, myXMLObject.child(*).toXMLString() gibi herhangi bir yöntem çağrılırken değil, yalnızca XML ayrıştırması sırasında kullanılır. Kaynak XML, işletme talimatları düğümleri içeriyorsa, bunlar XML ayrıştırması sırasında tutulur veya atılır.

Uygulama
public static function get ignoreProcessingInstructions():Boolean
public static function set ignoreProcessingInstructions(value:Boolean):void

İlgili API Öğeleri

XML.child()
XML.toXMLString()

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, XML.ignoreProcessingInstructions öğesinin false ve true değerine ayarlanmasının etkisini gösterir:

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreWhitespace

özellik

ignoreWhitespace:Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Metin düğümlerinin başında ve sonundaki boşluk karakterleri ayrıştırma sırasında göz ardı ediliyor mu, belirler. Varsayılan olarak, beyaz boşluk yok sayılır (true). Bir metin düğümü %100 beyaz boşluksa ve ignoreWhitespace özelliği true değerine ayarlanmışsa, düğüm oluşturulmaz. Metin düğümü içindeki beyaz boşluğu göstermek için, ignoreWhitespace özelliğini false değerine ayarlayın.

Bir XML nesnesi oluşturduğunuzda, ignoreWhitespace özelliğinin geçerli değerini önbelleğe alır. ignoreWhitespace öğesini değiştirmek varolan XML nesnelerinin davranışını değiştirmez.

Uygulama
public static function get ignoreWhitespace():Boolean
public static function set ignoreWhitespace(value:Boolean):void

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, XML.ignoreWhitespace öğesinin false ve true değerine ayarlanmasının etkisini gösterir:

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

prettyIndent

özellik

prettyIndent:int

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML.prettyPrinting özelliği true değerine ayarlandığında toString() ve toXMLString() yöntemleri tarafından uygulanan girinti miktarını belirler. Girinti, sekme karakteriyle değil, boşluk karakteriyle uygulanır. Varsayılan değer 2'dir.

Uygulama
public static function get prettyIndent():int
public static function set prettyIndent(value:int):void

İlgili API Öğeleri

prettyPrinting
toString()
toXMLString()

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, XML.prettyIndent statik özelliğinin ayarlanmasının etkisini gösterir.

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

prettyPrinting

özellik

prettyPrinting:Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

toString() ve toXMLString() yöntemlerinin bazı etiketler arasındaki beyaz boşluk karakterlerini normalleştirip normalleştirmeyeceğini belirler. Varsayılan değer true şeklindedir.

Uygulama
public static function get prettyPrinting():Boolean
public static function set prettyPrinting(value:Boolean):void

İlgili API Öğeleri

prettyIndent
toString()
toXMLString()

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, XML.prettyPrinting statik özelliğinin ayarlanmasının etkisini gösterir.

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Yapıcı Ayrıntı

()

Yapıcı

public function XML(value:Object)

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Yeni bir XML nesnesi oluşturur. Herhangi bir XML sınıfı yöntemi çağırmadan önce XML nesnesi oluşturmak için yapıcıyı kullanmanız gerekir.

XML nesnesinin basit veya karmaşık içeriğe sahip olduğuna bakılmaksızın XML nesnesinin dize olarak temsil edilen bir halini döndürmek için toXMLString() yöntemini kullanın.

Parametreler

value:Object — Üst düzey XML() işleviyle XML'e dönüştürülebilen bir nesne.

İlgili API Öğeleri

XML() genel işlevi
XML.toXMLString()

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki örnek, Flash Professional'da URLLoader sınıfını kullanarak ActionScript 3.0'a uzak bir XML belgesini nasıl yükleyebileceğinizi gösterir. Örnek, ActionScriptExamples.com tarafından sağlanmıştır.

//
// Requires:
//   - TextArea control UI component in the Flash Professional Library.
//
import fl.controls.TextArea;
 
var xml:XML;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
 
var urlLoader:URLLoader = new URLLoader();
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
var textArea:TextArea = new TextArea();
textArea.move(5, 5);
textArea.setSize(stage.stageWidth - 10, stage.stageHeight - 10);
addChild(textArea);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.currentTarget.data);
    textArea.text = xml.toXMLString();
}

Burada, tüm ActionScript'i kullanan başka bir çeşitleme verilmiştir. Örnek, ActionScriptExamples.com tarafından sağlanmıştır.

var xml:XML;
var textArea:TextField = new TextField();
textArea.width = 300;
 
var urlRequest:URLRequest = new URLRequest("http://www.helpexamples.com/flash/xml/menu.xml");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    xml = new XML(evt.target.data);
    textArea.text = xml.toXMLString();
    addChild(textArea);
}

Yöntem Ayrıntısı

addNamespace

()

yöntem

AS3 function addNamespace(ns:Object):XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesi için kapsam dahilindeki ad alanları kümesine bir ad alanı ekler. XML nesnesinin (verilen parametrenin önekine eşleşen önek ile) kapsam dahilindeki ad alanlarında ad alanı zaten varsa, var olan ad alanının öneki undefined olarak ayarlanır. input parametresi bir Namespace nesnesiyse, doğrudan kullanılır. Bu bir QName nesnesiyse, yeni bir ad alanı oluşturmak için input parametresinin URI'si kullanılır; aksi takdirde bu bir String'e dönüştürülür ve bu String'den bir ad alanı oluşturulur.

Parametreler

ns:Object — XML nesnesine eklenecek ad alanı.

Döndürür

XML — Ad alanı eklenmiş şekilde yeni XML nesnesi eklenir.

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, bir XML nesnesinde tanımlı ad alanını kullanır ve bu ad alanını başka bir XML nesnesine uygular:

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

appendChild

()

yöntem

AS3 function appendChild(child:Object):XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Belirli bir alt öğeyi XML nesnesinin özelliklerinin sonuna ekler. appendChild() yöntemi bir XML nesnesini, XMLList nesnesini veya daha sonra String'e dönüştürülen başka bir veri türünü alır.

XML düğümlerini kaldırmak için delete (XML) operatörünü kullanın.

Parametreler

child:Object — Eklenecek XML nesnesi.

Döndürür

XML — Sonuç XML nesnesi.

İlgili API Öğeleri

delete (XML) operatörü

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, bir XML nesnesinin alt öğe listesinin sonuna yeni bir öğe ekler.

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

attribute

()

yöntem

AS3 function attribute(attributeName:*):XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

attributeName parametresi ile eşlenen ada sahip XML niteliğinin değerini döndürür. Nitelikler XML öğeleri içinde bulunur. Şu örnekte öğenin "boy": <first gender="boy">John</first> değerini içeren "gender" adında bir niteliği vardır.

attributeName parametresi herhangi bir veri türü olabilir; ancak kullanılan en yaygın veri türü String şeklindedir. QName nesnesi dışında bir nesne iletilirken parametreyi bir dizeye dönüştürmek için attributeName parametresi toString() yöntemini kullanır.

Nitelenmiş bir ad başvurusu gerekirse, bir QName nesnesi iletebilirsiniz. QName nesnesi bir ad alanını ve yerel adı tanımlar, bir niteliğin nitelenmiş adını tanımlamak için bunu kullanabilirsiniz. Dolayısıyla attribute(qname) çağrılması attribute(qname.toString()) çağrılmasıyla aynı değildir.

Parametreler

attributeName:* — Nitelik adı.

Döndürür

XMLList — Bir XMLList nesnesi veya boş bir XMLList nesnesi. Bir nitelik değeri tanımlanmadığında boş bir XMLList nesnesi döndürür.

İlgili API Öğeleri

XML.attributes()
QName
Namespace
XML.elements()
nitelik tanımlayıcısı (@) operatörü

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, attribute() yöntemine iletilen bir QName nesnesini gösterir. localName özelliği attr olur ve namespace özelliği de ns olur.

 var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
 var qn:QName = new QName("http://uri", "attr");
 trace (xml.attribute(qn)); // 7

Ayrılmış bir ActionScript kelimesiyle eşleşen adı içeren bir nitelik döndürmek için, şu örnekteki gibi, nitelik tanımlayıcı (@) operatörü yerine attribute() yöntemini kullanın:

 var xml:XML = <example class="first" />
 trace(xml.attribute("class"));

attributes

()

yöntem

AS3 function attributes():XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Belirli bir XML nesnesi için bir nitelik değerleri listesi döndürür. Bir niteliğin adını döndürmek için attributes() yöntemiyle name() yöntemini kullanın. xml.attributes(), xml.@* öğesinin eşdeğeridir.

Döndürür

XMLList — Nitelik değerleri listesi.

İlgili API Öğeleri

XML.attribute()
XML.name()
@ operatörü

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, niteliğin adını döndürür:

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

Bu örnek, tüm niteliklerin adlarını döndürür:

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace (attNamesList is XMLList); // true
trace (attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace (typeof (attNamesList[i])); // xml
    trace (attNamesList[i].nodeKind()); // attribute
    trace (attNamesList[i].name()); // id and color
}

child

()

yöntem

AS3 function child(propertyName:Object):XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bir XML nesnesinin alt öğelerini listeler. XML alt öğesi bir XML öğesi, metin düğümü, yorum veya işleme talimatıdır.

Belirli bir XML alt öğesinin içeriklerini listelemek için propertyName parametresini kullanın. Örneğin, <first> adlı bir alt öğenin içeriğini döndürmek için XML nesnesinde child("first") öğesini çağırın. Alt öğenin dizin sayısını kullanarak da aynı sonucu oluşturabilirsiniz. Dizin sayısı, diğer XML alt öğesinin listesinde alt öğenin konumunu tanımlar. Örneğin, child(0) öğesi bir listedeki ilk alt öğeyi döndürür.

Bir XML belgesindeki tüm alt öğelerin çıktısını almak için bir asterisk (*) kullanın. Örneğin, doc.child("*").

Toplam alt öğe sayısının çıktısını almak için child() yönteminin asterisk (*) parametresiyle length() yöntemini kullanın. Örneğin, numChildren = doc.child("*").length().

Parametreler

propertyName:Object — Alt XML'in öğe adı veya tam sayısı

Döndürür

XMLList — input parametresiyle eşlenen alt düğümlerden oluşan bir XMLList nesnesi.

İlgili API Öğeleri

XML.elements()
XMLList sınıfı
XML.length()

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, belirtilen bir ada sahip alt öğeleri tanımlamak için child() yönteminin kullanımını gösterir:

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

childIndex

()

yöntem

AS3 function childIndex():int

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bu XML nesnesinin üst öğesi bağlamında sıfır dizinli konumunu tanımlar.

Döndürür

int — Nesnenin konumu. Pozitif tam sayıların yanı sıra -1 değerini döndürür.

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek childIndex() yönteminin kullanımını gösterir:

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

children

()

yöntem

AS3 function children():XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin alt öğelerini, göründükleri sırada listeler. XML alt öğesi bir XML öğesi, metin düğümü, yorum veya işleme talimatıdır.

Döndürür

XMLList — XML nesnesinin alt öğesinin XMLList nesnesi.

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek children() yönteminin kullanımını gösterir:

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

comments

()

yöntem

AS3 function comments():XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML yorumlarını içeren XML nesnesinin özelliklerini listeler.

Döndürür

XMLList — Özelliklerin yorum içeren XMLList nesnesi.

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek comments() yönteminin kullanımını gösterir:

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

contains

()

yöntem

AS3 function contains(value:XML):Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesini belirli bir value parametresi ile karşılaştırır.

Parametreler

value:XML — Geçerli XML nesnesiyle karşılaştırılacak bir değer.

Döndürür

Boolean — XML nesnesi value parametresiyle eşleşirse true; eşleşmezse false.

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek contains() yönteminin kullanımını gösterir:

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

copy

()

yöntem

AS3 function copy():XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Belirli bir XML nesnesinin bir kopyasını döndürür. Kopya, tüm düğüm ağacının aynısıdır. Kopyalanan XML nesnesinin üst öğesi yoktur ve parent() yöntemini çağırmayı denerseniz null değerini döndürür.

Döndürür

XML — Nesnenin kopyası.

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek, copy() yönteminin yeni bir XML nesnesi örneği oluşturduğunu gösterir. Kopyayı değiştirdiğinizde, orijinali değişmeden kalır:

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

defaultSettings

()

yöntem

AS3 static function defaultSettings():Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Şu özellikleri varsayılan değerlere ayarlı bir nesne döndürür: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent ve prettyPrinting. Varsayılan değerler şu şekildedir:

ignoreComments = true
ignoreProcessingInstructions = true
ignoreWhitespace = true
prettyIndent = 2
prettyPrinting = true

Not: Bu yöntem bir XML sınıfı örneğine uygulanmaz; şu kodda olduğu gibi XML öğesine uygulanır: var df:Object = XML.defaultSettings().

Döndürür

Object — Özellikleri varsayılan değerlere ayarlı bir nesne.

İlgili API Öğeleri

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.setSettings()
XML.settings()

Örnek ( Bu örnek nasıl kullanılır? )

Şu örneğin gösterdikleri: bir XML nesnesi ayarlamadan önce bazı özel ayarların (dahil edilen yorumlar ve işleme talimatları için) nasıl uygulandığı, daha sonra başka bir XML nesnesi ayarlamadan önce varsayılan ayarlara nasıl geri dönüldüğü ve sonra tekrar özel ayarların nasıl ayarlandığı (daha fazla XML nesnesi ayarlamak için):

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

descendants

()

yöntem

AS3 function descendants(name:Object = *):XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin belirli bir name parametresine sahip tüm alt öğelerini (alt öğe, alt alt öğe vb.) döndürür. name parametresi isteğe bağlıdır. name parametresi bir QName nesnesi, String veri türü veya daha sonra String veri türüne dönüştürülecek herhangi bir veri türü olabilir.

Tüm alt öğeleri döndürmek için "*" parametresini kullanın. Herhangi bir parametre iletilmezse, "*" dizesi iletilir ve XML nesnesinin tüm alt öğelerini döndürür.

Parametreler

name:Object (default = *) — Eşlenecek öğenin adı.

Döndürür

XMLList — Eşlenen alt öğelerin bir XMLList nesnesi. Alt öğe yoksa boş bir XMLList nesnesini döndürür.

İlgili API Öğeleri

descendant accessor (..) operator

Örnek ( Bu örnek nasıl kullanılır? )

Ayrılmış ActionScript kelimeleriyle eşlenen adları içeren alt öğeleri döndürmek için descendant (..) operatörü yerine şu örnekteki gibi descendants() yöntemini kullanın:

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class"));

Şu örnek, descendants() yönteminin, alt öğe, alt alt öğe, vb. dahil tüm alt öğe nesnelerini içeren bir XMLList nesnesi döndürdüğünü gösterir.

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

elements

()

yöntem

AS3 function elements(name:Object = *):XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bir XML nesnesinin öğelerini listeler. Bir öğe başlangıç ve bitiş etiketinden oluşur; örneğin <first></first>. name parametresi isteğe bağlıdır. name parametresi bir QName nesnesi, String veri türü veya daha sonra String veri türüne dönüştürülecek herhangi bir veri türü olabilir. Belirli bir öğeyi listelemek için name parametresini kullanın. Örneğin, bu örnekte "first" öğesi, "John" döndürür: <first>John</first>.

Tüm öğeleri listelemek için parametre olarak asterisk (*) kullanın. asterisk ayrıca varsayılan parametredir.

Toplam öğe sayısının çıktısını almak için asterisk parametresiyle length() yöntemini kullanın. Örneğin, numElement = addressbook.elements("*").length().

Parametreler

name:Object (default = *) — Öğenin adı. Öğenin adı, açılı ayraçları içine alınır. Örneğin, bu örnekte "first" name öğesidir: <first></first>.

Döndürür

XMLList — Öğenin XMLList nesnesinin içeriği. Öğenin içeriği başlangıç ve bitiş etiketleri arasında bulunur. Tüm öğeleri çağırmak için asterisk (*) kullanırsanız, hem öğenin etiketleri hem de içerik döndürülür.

İlgili API Öğeleri

XML.child()
XMLList sınıfı
XML.length()
XML.attribute()
XML dot (.) operator

Örnek ( Bu örnek nasıl kullanılır? )

Aşağıdaki örnek, elements() yönteminin yalnızca öğelerden oluşan, yorum, metin özellikleri, işlem talimatı içermeyen bir liste döndürdüğünü gösterir:

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

Ayrılmış ActionScript kelimeleriyle eşlenen adları içeren öğeleri döndürmek için XML dot (.) operatörü yerine şu örnekteki gibi elements() yöntemini kullanın:

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class"));

hasComplexContent

()

yöntem

AS3 function hasComplexContent():Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinde karmaşık içerik olup olmadığını kontrol eder. Bir XML nesnesi alt öğelere sahipse, karmaşık içerik barındırır. Nitelikleri, yorumları, işleme talimatlarını ve metin düğümlerini temsil eden XML nesnelerinin karmaşık içeriği yoktur. Ancak bunları içeren bir nesnenin yine de karmaşık içerik barındırdığı düşünülebilir (nesnenin alt öğeleri varsa).

Döndürür

Boolean — XMLList nesnesinde karmaşık içerik varsa true; yoksa false.

İlgili API Öğeleri

XML.hasSimpleContent()

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, basit içeriği olan a adında bir özellik ve karmaşık içeriği olan a adında bir özellik içeren bir XML nesnesi gösterir:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

hasOwnProperty

()

yöntem

AS3 function hasOwnProperty(p:String):Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Nesnenin p parametresiyle belirtilen özelliği olup olmadığını kontrol eder.

Parametreler

p:String — Eşleşecek özellik.

Döndürür

Boolean — Özellik varsa true, aksi halde false olur.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, özelliği kullanan bir ifadeyi (b == "11") değerlendirmeden önce o özelliğin (b) olmasını sağlamak için hasOwnProperty() yöntemini kullanır.

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11"));

Bu örnekteki son satır şu olsaydı, a adındaki birinci öğenin b adında bir özelliği olmayacağından Flash Player bir istisna atardı:

trace(xml.a.(b == "11"));

Şu örnek, özelliği kullanan bir ifadeyi (item.contains("toothbrush")) değerlendirmeden önce o özelliğin (item) olmasını sağlamak için hasOwnProperty() yöntemini kullanır.

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));

hasSimpleContent

()

yöntem

AS3 function hasSimpleContent():Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinde basit içerik olup olmadığını kontrol eder. XML nesnesi bir metin düğümünü, bir nitelik düğümünü veya alt öğesi olmayan bir XML öğesini temsil ediyorsa basit içerik barındırır. Yorumları ve işleme talimatlarını temsil eden XML nesneleri basit içerik barındırmaz.

Döndürür

Boolean — XML nesnesinde basit içerik varsa true; yoksa false.

İlgili API Öğeleri

XML.hasComplexContent()

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, basit içeriği olan a adında bir özellik ve karmaşık içeriği olan a adında bir özellik içeren bir XML nesnesi gösterir:

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

inScopeNamespaces

()

yöntem

AS3 function inScopeNamespaces():Array

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Nesnenin üst öğesini esas alarak XML nesnesinin ad alanlarını listeler.

Döndürür

Array — Namespace nesneleri dizisi.

insertChildAfter

()

yöntem

AS3 function insertChildAfter(child1:Object, child2:Object):*

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bu XML nesnesindeki verilen child2 parametresini child1 parametresinden sonraya ekler ve sonuç nesnesini döndürür. child1 parametresi null ise, yöntem, XML nesnesinin tüm alt öğelerinden önce (başka bir deyişle, none öğesinden sonra) child2 içeriklerini ekler. child1 sağlandığı halde XML nesnesinde yoksa, XML nesnesi değiştirilmez ve undefined döndürülür.

Öğe (metin, nitelikler, yorumlar, pi, vb.) olmayan bir XML nesnesinde bu yöntemi çağırırsanız undefined döndürülür.

XML düğümlerini kaldırmak için delete (XML) operatörünü kullanın.

Parametreler

	`child1:Object` — `child2` öğesinden önce eklediğiniz kaynak nesnedeki nesne.

	`child2:Object` — Eklenecek nesne.

Döndürür

* — Sonuç XML nesnesi veya undefined.

İlgili API Öğeleri

XML.insertChildBefore()
delete (XML) operatörü

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, XML nesnesinin alt öğelerinin sonuna bir öğe ekler:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

trace() çıktısı şudur:

 <menu>
     <item>burger</item>
     <saleItem>fries</saleItem>
     <item>soda</item>
 </menu>

insertChildBefore

()

yöntem

AS3 function insertChildBefore(child1:Object, child2:Object):*

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bu XML nesnesindeki verilen child2 parametresini child1 parametresinden önceye ekler ve sonuç nesnesini döndürür. child1 parametresi null ise, yöntem, XML nesnesinin tüm alt öğelerinden sonra (başka bir deyişle, none öğesinden sonra) child2 içeriklerini ekler. child1 sağlandığı halde XML nesnesinde yoksa, XML nesnesi değiştirilmez ve undefined döndürülür.

Öğe (metin, nitelikler, yorumlar, pi, vb.) olmayan bir XML nesnesinde bu yöntemi çağırırsanız undefined döndürülür.

XML düğümlerini kaldırmak için delete (XML) operatörünü kullanın.

Parametreler

	`child1:Object` — `child2` öğesinden sonra eklediğiniz kaynak nesnedeki nesne.

	`child2:Object` — Eklenecek nesne.

Döndürür

* — Sonuç XML nesnesi veya undefined.

İlgili API Öğeleri

XML.insertChildAfter()
delete (XML) operatörü

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, XML nesnesinin alt öğelerinin sonuna bir öğe ekler:

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

trace() çıktısı şudur:

 <menu>
     <saleItem>fries</saleItem>
     <item>burger</item>
     <item>soda</item>
 </menu>

length

()

yöntem

AS3 function length():int

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesneleri için bu yöntem daima 1 tam sayısını döndürür. XMLList sınıfının length() yöntemi yalnızca bir değer içeren bir XMLList nesnesi için 1 değerini döndürür.

Döndürür

int — Herhangi bir XML nesnesi için daima 1 döndürür.

localName

()

yöntem

AS3 function localName():Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin nitelenmiş adının yerel ad bölümünü verir.

Döndürür

Object — Yerel ad String veya null olur.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, localName() yönteminin kullanımını gösterir:

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

name

()

yöntem

AS3 function name():Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin nitelenmiş adını verir.

Döndürür

Object — Nitelenmiş ad QName veya null olur.

İlgili API Öğeleri

XML.attributes()
attribute identifier

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinin nitelenmiş adını almak için name() yönteminin kullanımını gösterir:

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

Şu örnek, bir XML özelliğinde, bir metin öğesinde ve bir nitelikte çağrılan name() yönteminin kullanımını gösterir:

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

namespace

()

yöntem

AS3 function namespace(prefix:String = null):*

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Herhangi bir parametre verilmezse, bu XML nesnesinin nitelenmiş adı ile ilişkilendirilmiş ad alanını verir. Bir prefix parametresi belirtilirse, yöntem, prefix parametresiyle eşleşen ve XML nesnesinin kapsamında olan ad alanını döndürür. Böyle bir ad alanı yoksa, yöntem undefined döndürür.

Parametreler

prefix:String (default = null) — Eşleştirmek istediğiniz önek.

Döndürür

* — null, undefined veya bir ad alanı döndürür.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinin ad alanını alıp bunu daha sonra xml nesnesinin bir özelliğini (xml.soap::Body[0]) tanımlamada kullanılacak soap adında bir Namespace nesnesine atamak için namespace() yöntemini kullanır.

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

Şu örnek, bir düğümün varsayılan ad alanını ve belirli bir önekin ad alanını ("dc") almak için namespace() yöntemini kullanır.

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

namespaceDeclarations

()

yöntem

AS3 function namespaceDeclarations():Array

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Kendi üst öğesi bağlamında XML nesnesi ile ilişkili ad alanı bildirimlerini listeler.

Döndürür

Array — Namespace nesneleri dizisi.

İlgili API Öğeleri

XML.namespace()

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinin ad alanı bildirimlerinin çıktısını alır:

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":" , ns.uri);
}

trace() çıktısı şudur:

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
 dc: http://purl.org/dc/elements/1.1/
 (default): http://purl.org/rss/1.0/

nodeKind

()

yöntem

AS3 function nodeKind():String

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Düğüm türünü belirtir: metin, yorum, işleme talimatı, nitelik veya öğe.

Döndürür

String — Kullanılan düğüm türü.

İlgili API Öğeleri

attribute identifier

Örnek ( Bu örnek nasıl kullanılır? )

Bu örnek beş düğüm türünün hepsini izler:

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

normalize

()

yöntem

AS3 function normalize():XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesi ve tüm alt XML nesneleri için bitişik metin düğümlerini birleştirir ve boş metin düğümlerini giderir.

Döndürür

XML — Normalleştirilmiş sonuç XML nesnesi.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, normalize() yöntemi çağrısının etkisini gösterir:

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

parent

()

yöntem

AS3 function parent():*

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin üst öğesini döndürür. XML nesnesinin üst öğesi yoksa, yöntem undefined döndürür.

Döndürür

* — Üst düğümün XML başvurusu veya XML nesnesi bir üst öğeye sahip değilse undefined değeri.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML yapısındaki belirli bir öğenin üst öğesini tanımlamak için parent() yöntemini kullanır:

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

prependChild

()

yöntem

AS3 function prependChild(value:Object):XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Sağlanan child nesnesinin bir kopyasını XML öğesine, o öğenin var olan XML özelliklerinin öncesine ekler.

XML düğümlerini kaldırmak için delete (XML) operatörünü kullanın.

Parametreler

value:Object — Eklenecek nesne.

Döndürür

XML — Sonuç XML nesnesi.

İlgili API Öğeleri

delete (XML) operatörü

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinin başına öğe eklemek için prependChild() yöntemini kullanır:

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

processingInstructions

()

yöntem

AS3 function processingInstructions(name:String = "*"):XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bir name parametresi sağlanırsa, XML nesnesinin o name öğesine sahip işleme talimatlarını içeren tüm alt öğelerini listeler. Parametre olmadığında, yöntem, XML nesnesinin herhangi bir işleme talimatı içeren tüm alt öğelerini listeler.

Parametreler

name:String (default = "*") — Eşleşecek işleme talimatlarının adı.

Döndürür

XMLList — Eşlenen at öğelerin listesi.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinin işleme talimatları dizisini almak için processingInstructions() yöntemini kullanır:

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

propertyIsEnumerable

()

yöntem

AS3 function propertyIsEnumerable(p:String):Boolean

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

p özelliğinin, XML nesnesine uygulanan bir for..in ifadesinde yinelenebilen özellikler kümesinde olup olmadığını kontrol eder. Ancak toString(p) == "0" olduğunda true döndürür.

Parametreler

p:String — Kontrol etmek istediğiniz özellik.

Döndürür

Boolean — Özellik, for..in ifadesinde yinelenebiliyorsa, true; aksi takdirde false.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, propertyNameIsEnumerable() yönteminin bir XML nesnesi için yalnızca 0 değerine true değeri döndürdüğünü; bir XMLList nesnesi içinse XMLList nesnesinin her bir geçerli dizin değerine true değeri döndürdüğünü gösterir.

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

removeNamespace

()

yöntem

AS3 function removeNamespace(ns:Namespace):XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Bu nesnenin ve tüm alt öğelerinin belirli ad alanını kaldırır Ad alanına nesnenin nitelenmiş adı veya nesne niteliklerinin nitelenmiş adı ile başvurulursa, removeNamespaces() yöntemi o ad alanını kaldırmaz.

Parametreler

ns:Namespace — Kaldırılacak ad alanı.

Döndürür

XML — Sonuç XML nesnesinin bir kopyası.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, XML nesnesinden bir ad alanı bildiriminin nasıl kaldırılacağını gösterir:

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

replace

()

yöntem

AS3 function replace(propertyName:Object, value:XML):XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

propertyName parametresi ile belirtilen özellikleri, verilen value parametresi ile değiştirir. Herhangi bir özellik propertyName ile eşleşmezse, XML nesnesi değiştirilmeden bırakılır.

Parametreler

	`propertyName:Object` — Sayısal bir değer, XML öğeleri kümesi için nitelenmemiş bir ad, XML öğeleri kümesi için nitelenmiş bir ad veya asterisk jokeri ("*") olabilir. Varsayılan ad alanında XML öğelerini tanımlamak için nitelenmemiş bir ad kullanın.

	`value:XML` — Yerini alan değer. Bu bir XML nesnesi, bir XMLList nesnesi veya `toString()` ile dönüştürülebilen herhangi bir değer olabilir.

Döndürür

XML — Eşlenen özellikleri değiştirilmiş sonuç XML nesnesi.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, birinci parametre olarak bir tam sayı içeren replace() yönteminin çağrılmasını gösterir:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

Bu çağrı şu trace() çıktısını verir:


 <body>
     <p>Hello</p>
     <p>Bob</p>
     <hr/>
 </body>

Şu örnek, birinci parametre olarak bir dize içeren replace() yöntemini çağırır:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

Bu çağrı şu trace() çıktısını verir:


 <body>
     <p>Hi</p>
     <hr/>
 </body>;

Şu örnek, birinci parametre olarak bir QName içeren replace() yönteminin çağrılmasını gösterir:

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

Bu çağrı şu trace() çıktısını verir:


 <ns:body xmlns:ns = "myNS">
     <p>Bob</p>
     <hr/>
 </ns:body>

Şu örnek, birinci parametre olarak "*" dizesini içeren replace() yönteminin çağrılmasını gösterir:

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

Bu çağrı şu trace() çıktısını verir:


 <body>
     <img src="hello.jpg"/>
 </body>

setChildren

()

yöntem

AS3 function setChildren(value:Object):XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin alt öğe özelliklerini value parametresinde sağlanan belirli XML özellik kümesiyle değiştirir.

Parametreler

value:Object — Yerini alan XML özellikleri. Tek bir XML nesnesi veya bir XMLList nesnesi olabilir.

Döndürür

XML — Sonuç XML nesnesi.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, parametre olarak ilk önce bir XML nesnesi ve daha sonra parametre olarak XMLList nesnesi kullanılarak setChildren() yönteminin çağrılmasını gösterir.

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

setLocalName

()

yöntem

AS3 function setLocalName(name:String):void

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin yerel adını belirli bir name parametresine çevirir.

Parametreler

name:String — Yerel adın yerini alan ad.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML öğesinin yerel adını değiştirmek için setLocalName() yöntemini kullanır:

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

setName

()

yöntem

AS3 function setName(name:String):void

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin adını belirli bir nitelenmiş ad veya nitelik adı olarak ayarlar.

Parametreler

name:String — Nesnenin yeni adı.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML öğesinin yerel adını değiştirmek için setName() yöntemini kullanır:

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

setNamespace

()

yöntem

AS3 function setNamespace(ns:Namespace):void

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesi ile ilişkili ad alanını ayarlar.

Parametreler

ns:Namespace — Yeni ad alanı.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinde tanımlı soap ad alanını kullanır ve bunu başka bir XML nesnesinin (xml2) ad alanına uygular:

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

setSettings

()

yöntem

AS3 static function setSettings(... rest):void

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Şu XML özelliklerinin değerlerini ayarlar: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent ve prettyPrinting. Herhangi bir setObj parametresi sağlanmadığında uygulanan varsayılan ayarlar şunlardır:

XML.ignoreComments = true
XML.ignoreProcessingInstructions = true
XML.ignoreWhitespace = true
XML.prettyIndent = 2
XML.prettyPrinting = true

Not: Bu yöntem bir XML sınıfı örneğine uygulanmaz; şu kodda olduğu gibi XML öğesine uygulanır: XML.setSettings().

Parametreler

... rest — Şu özelliklerin her birini içeren bir nesne:

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

İlgili API Öğeleri

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting
defaultSettings()
settings()

Örnek ( Bu örnek nasıl kullanılır? )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

settings

()

yöntem

AS3 static function settings():Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

Şu özellikleri alır: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent ve prettyPrinting.

Döndürür

Object — Şu XML özelliklerini içeren bir nesne.

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

İlgili API Öğeleri

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.defaultSettings()
XML.setSettings()

Örnek ( Bu örnek nasıl kullanılır? )

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

text

()

yöntem

AS3 function text():XMLList

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin, XML metin düğümlerini temsil eden tüm XML özelliklerinin bir XMLList nesnesini döndürür.

Döndürür

XMLList — Özellik listesi.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, bir XML nesnesinin metin düğümlerini almak için text() yöntemini kullanır:

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

toJSON

()

yöntem

AS3 function toJSON(k:String):*

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

Flash Player 11, AIR 3, Flash Lite 4

Bir XML nesnesindeki değerlerin JSON kodlamasını özelleştirmek için geçersiz kılınabilir bir yöntem sağlar.

JSON.stringify() yöntemi, geçtiği her nesnede bir toJSON() yöntemi arar. toJSON() yöntemi bulunursa JSON.stringify() yöntemi, karşılaştığı her bir değer için onu çağırır ve değerle eşleşen tuşu iletir.

XML; toJSON() yönteminin yalnızca sınıf adını döndüren bir varsayılan uygulamasını sağlar. XML nesnelerini JSON sınıfına dışa aktarmak isteyen istemcilerin kendi uygulamalarını sağlamaları gereklidir. toJSON() yöntemini sınıf prototipinde yeniden tanımlayarak bunu gerçekleştirebilirsiniz.

toJSON() yöntemi herhangi bir türde değer döndürebilir. Bir nesne döndürürse, stringify() o nesne içinde kendi kendini yineler. toJSON() bir dize döndürürse, stringify() kendi kendini yinelemez ve geçişine devam eder.

Parametreler

k:String — JSON.stringify() yönteminin bu nesneyi geçişinde karşılaştığı bir tuş/değer çiftinin tuşu.

Döndürür

* — Sınıf adı dizesi.

İlgili API Öğeleri

Object
Object.prototype

toString

()

yöntem

AS3 function toString():String

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin dize olarak temsilini döndürür. Bu dönüştürmeyle ilgili kurallar XML nesnesinin basit içeriğe veya karmaşık içeriğe sahip olmasına bağlıdır.

XML nesnesi basit içeriğe sahipse toString() yöntemi, XML nesnesinin String içeriğini şu öğeler ayıklanmış olarak döndürür: başlangıç etiketi, nitelikler, ad alanı bildirimleri ve bitiş etiketi.

XML nesnesi karmaşık içeriğe sahipse toString() yöntemi, başlangıç etiketi, nitelikler, ad alanı bildirimleri ve bitiş etiketi de dahil olmak üzere tüm XML nesnesini temsil eden XML kodlu bir String döndürür.

Her defasında tüm XML nesnesini döndürmek için toXMLString() yöntemini kullanın.

Döndürür

String — XML nesnesinin dize olarak temsili.

İlgili API Öğeleri

XML.hasSimpleContent()
XML.hasComplexContent()
XML.toXMLString()

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, XML nesnesi basit içeriğe sahip olduğunda toStirng() yönteminin ne döndüreceğini gösterir:

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

Şu örnek, XML nesnesi karmaşık içeriğe sahip olduğunda toStirng() yönteminin ne döndüreceğini gösterir:

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type>

toXMLString

()

yöntem

AS3 function toXMLString():String

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesinin dize olarak temsilini döndürür. toString() yönteminin tersine toXMLString() yöntemi XML nesnesinin basit içeriğe veya karmaşık içeriğe sahip olmasına bakmadan her zaman başlangıç etiketini, nitelikleri ve bitiş etiketini döndürür. (toString() yöntemi basit içeriğe sahip XML nesneleri için bu öğeleri ayıklar.)

Döndürür

String — XML nesnesinin dize olarak temsili.

İlgili API Öğeleri

XML.toString()

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, toString() yönteminin kullanımı (varsayılan olarak trace() yönteminin tüm parametrelerine uygulanan) ile toXMLString() yönteminin kullanımı arasındaki farkı gösterir:

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

valueOf

()

yöntem

AS3 function valueOf():XML

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 1.0, Flash Player 9

XML nesnesini döndürür.

Döndürür

XML — XML örneğinin temel değeri.

Örnek ( Bu örnek nasıl kullanılır? )

Şu örnek, valueOf() yönteminin döndürdüğü değerin, kaynak XML nesnesi ile aynı olduğunu gösterir:

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true

Örnekler Bu örnek nasıl kullanılır?

XMLExample.as

Şu örnek ilk önce bir XML değişkeni oluşturur ve bunlara düğüm ekler. Daha sonra XML düğümlerini bulup yazdırmak için XML özellikleri kullanılır. Nitelik adına göre bilgilerin yerini bulmak için birçok trace() çağrısında "at" (@) sembolünün kullanıldığına dikkat edin.

package {
    import flash.display.Sprite;

    public class XmlExample extends Sprite {        
        public function XmlExample() {
            var employees:XML =
                <employees>
                    <employee ssn="123-123-1234">
                        <name first="John" last="Doe"/>
                        <address>
                            <street>11 Main St.</street>
                            <city>San Francisco</city>
                            <state>CA</state>
                            <zip>98765</zip>
                        </address>
                    </employee>
                    <employee ssn="789-789-7890">
                        <name first="Mary" last="Roe"/>
                        <address>
                            <street>99 Broad St.</street>
                            <city>Newton</city>
                            <state>MA</state>
                            <zip>01234</zip>
                        </address>
                    </employee>
                </employees>;

            trace(employees.employee[0].address.zip);   // 98765

            trace(employees.employee[1].@ssn);          // 789-789-7890

            trace(employees.employee.name);             // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees..zip[0]);                   // 98765

            trace(employees..@ssn[1]);                  // 789-789-7890

            trace(employees..name);                     // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees.employee[0].address.*);     // <street>11 Main St.</street>    
                                                        // <city>San Francisco</city>
                                                        // <state>CA</state>
                                                        // <zip>98765</zip>
            var node:String = "zip";
            trace(employees.employee[0].address[node]); // 98765
            
            var attribute:String = "ssn";
            trace(employees.employee[1].@[attribute]);  // 789-789-7890
            
            for each (var num:XML in employees..@ssn) {
                trace(num);                             // 123-123-1234
            }                                           // 789-789-7890
            
            var ssnToFind:String = "789-789-7890";
            trace(employees.employee.(@ssn == ssnToFind).toXMLString());
                                                        // <employee ssn="789-789-7890">
                                                        // <name first="Mary" last="Roe"/>
                                                        // <address>
                                                        // <street>99 Broad St.</street>
                                                        // <city>Newton</city>
                                                        // <state>MA</state>
                                                        // <zip>01234</zip>
                                                        // </address>
                                                        // </employee>
        }
    }
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

XML - AS3

Sınıflar x

ignoreComments

ignoreProcessingInstructions

ignoreWhitespace

prettyIndent

prettyPrinting

XML

addNamespace

appendChild

attribute

attributes

child

childIndex

children

comments

contains

copy

defaultSettings

descendants

elements

hasComplexContent

hasOwnProperty

hasSimpleContent

inScopeNamespaces

insertChildAfter

insertChildBefore

length

localName

name

namespace

namespaceDeclarations

nodeKind

normalize

parent

prependChild

processingInstructions

propertyIsEnumerable

removeNamespace

replace

setChildren

setLocalName

setName

setNamespace

setSettings

settings

text

toJSON

toString

toXMLString

valueOf