QName  - AS3

QName nesnesinin yerel adı.

QName nesnesinin Tekdüzen Kaynak Tanımlayıcısı (URI).

Başka bir QName nesnesinin kopyası olan bir QName nesnesi oluşturur. Yapıcıya iletilen parametre bir QName nesnesiyse, QName nesnesinin bir kopyası oluşturulur. Parametre bir QName nesnesi değilse, bir dizeye dönüştürülür ve yeni QName nesnesinin localName özelliğine atanır. Parametre undefined ise veya belirtilmediyse, localName özelliği boş dizeye ayarlanmış yeni bir QName nesnesi oluşturulur.

Not: Bu sınıf iki yapıcı girişini gösterir. Bunun nedeni her ikisinin de farklı parametreleri kabul etmesidir. İletilen parametrelerin türüne ve sayısına bağlı olarak yapıcı farklı davranır (her giriş için ayrıntılı olarak belirtilmiştir). ActionScript 3.0, yöntem veya yapıcı aşırı yüklemesini desteklemez.

Namespace nesnesinden bir URI öğesi ve QName nesnesinden bir localName öğesi ile QName nesnesi oluşturur. İki parametreden herhangi biri beklenen veri türünde değilse, parametre dizeye dönüştürülür ve yeni QName nesnesinin ilgili özelliğine atanır. Örneğin, her iki parametre de dizeyse, uri özelliği ilk parametreye ve localName özelliği de ikinci parametreye ayarlanmış yeni bir QName nesnesi döndürülür. Başka bir deyişle, diğerlerinin yanı sıra şu permütasyonlar geçerli yapıcı formlarıdır:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

uri parametresi için null değerini iletirseniz, yeni QName nesnesinin uri özelliği null olarak ayarlanır.

Not: Bu sınıf iki yapıcı girişini gösterir. Bunun nedeni her ikisinin de farklı parametreleri kabul etmesidir. İletilen parametrelerin türüne ve sayısına bağlı olarak yapıcı farklı davranır (her giriş için ayrıntılı olarak belirtilmiştir). ActionScript 3.0, yöntem veya yapıcı aşırı yüklemesini desteklemez.

URI'den ve QName nesnesinin "::" ile ayrılmış bir yerel adından oluşan bir dize döndürür.

Biçim, QName nesnesinin uri özelliğine bağlıdır:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

QName nesnesini döndürür.

1. Bir Namespace örneği oluşturma ve sonra bunu QName yapıcısına girdi olarak kullanma. Bu yaklaşım en çok, daha sonra başka amaçlarla Namespace.prefix özelliği kullanmak isterseniz kullanışlıdır.
2. QName yapıcısında uri parametresi için basit bir dize değeri kullanarak bir QName örneği oluşturma.

Bu kod şunları yapar:

1. rssXML adlı bir XML değişkenini tanımlar.
2. dc önekine sahip yeni bir Namespace nesnesi oluşturur.
3. Namespace nesnesini creator yerel adını kullanarak yeni bir QName nesnesi oluşturur.
4. showDescendants() yöntemini çağırır. Bu yöntem, nitelenmiş adı, verilen QName örneğiyle eşleşen tüm alt öğeleri içeren bir XMLList örneği almak için XML.descendants() yöntemini kullanır.
5. for each döngüsü kullanarak listedeki her öğenin nitelenmiş adını ve metin değerini görüntüler.
6. uri parametresi ve date yerel adı için bir dize değeri kullanarak başka bir QName nesnesi oluşturur.
7. Alt öğelerin adlarını ve metin değerlerini görüntülemek için showDescendants() yöntemini tekrar çağırır.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}