TextFormat  - AS3

Paragrafın hizalamasını gösterir. Geçerli değerler TextFormatAlign sabitleridir.

Varsayılan değer şudur TextFormatAlign.LEFT.

İlgili API Öğeleri

Piksel olarak blok girintisini gösterir. Blok girintisi bir metin bloğunun tamamına, yani metnin tüm satırlarına uygulanır. Bunun aksine, normal girinti (TextFormat.indent) yalnızca her paragrafın ilk satırını etkiler. Bu özellik null olursa, TextFormat nesnesi blok girintisini belirtmez (blok girintisi 0 olur).

Metnin kalın harfli olup olmadığını belirtir. Varsayılan değer null şeklindedir. Buna göre kalın harf kullanılmaz. Değer true olursa metin kalın harfli olur.

Metnin madde imli listenin parçası olduğunu gösterir. Madde imli bir listede metnin her paragrafı girintili olur. Her paragrafın ilk satırının soluna doğru bir madde imi simgesi görüntülenir. Varsayılan değer null şeklindedir. Buna göre madde imli bir liste kullanılmaz.

Metnin rengini gösterir. Üç adet 8 bit RGB bileşeni içeren bir sayı; örneğin, 0xFF0000 kırmızıdır ve 0x00FF00 yeşildir. Varsayılan değer null şeklindedir ve Flash Player'ın siyah rengi (0x000000) kullandığı anlamına gelir.

Bu metin biçimindeki metin için dize olarak font adı. Varsayılan değer null şeklindedir ve Flash Player'ın metin için Times New Roman fontunu kullandığı anlamına gelir.

Sol kenardan paragraftaki ilk harfe kadar olan girintiyi gösterir. Varsayılan değer null şeklindedir ve girinti kullanılmadığını belirtir.

İlgili API Öğeleri

Bu metin biçimindeki metin yatık yapılabiliyor mu, gösterir. Varsayılan değer null şeklindedir ve italik harf kullanılmadığı anlamına gelir.

Karakter aralığının etkin (true) veya devre dışı (false) olduğunu gösteren Boolean değeri. Karakter aralığı, okunabilirliği artırmak üzere belirli karakter çiftleri arasındaki pikselleri ayarlar ve büyük fontlardaki üstbilgiler gibi yalnızca gerekli olduğu durumlarda kullanılmalıdır. Karakter aralığı yalnızca gömülü fontlar için desteklenir.

Verdana gibi belirli fontlar ve Courier New gibi eşaralıklı fontlar karakter aralığını desteklemez.

Varsayılan değer null şeklindedir ve karakter aralığının etkinleştirilmediği anlamına gelir.

Satırlar arasındaki dikey boşluğu (satır aralığı denir) temsil eden bir tam sayı. Varsayılan değer null şeklindedir ve kullanılan satır aralığı miktarının 0 olduğunu gösterir.

Piksel olarak paragrafın sol kenar boşluğu. Varsayılan değer null şeklindedir ve sol kenar boşluğunun 0 piksel olduğunu gösterir.

Tüm karakterler arasında eşit olarak dağıtılmış boşluk miktarını temsil eden bir sayı. Değer, her karakterden sonraki başlangıca eklenen piksel sayısını belirtir. Varsayılan değer null şeklindedir ve 0 piksellik harf aralığı kullanıldığı anlamına gelir. 1,75 gibi ondalık değerler kullanabilirsiniz.

Paragrafın piksel olarak sol kenar boşluğu. Varsayılan değer null şeklindedir ve sağ kenar boşluğunun 0 piksel olduğunu belirtir.

Bu metin biçiminde piksel olarak metnin boyutu. Varsayılan değer null şeklindedir ve 12 boyutunun kullanıldığı anlamına gelir.

Özel sekme duraklarını negatif olmayan tam sayılar dizisi olarak belirtir. Her sekme durağı piksel olarak belirtilir. Özel sekme durakları belirtilmezse (null), varsayılan sekme durağı 4 (ortalama karakter genişliği) olur.

Köprünün gösterildiği hedef pencereyi gösterir. Hedef pencere boş bir dizeyse, metin _self varsayılan hedef penceresinde görüntülenir. Özel bir ad veya şu dört addan birini seçebilirsiniz: _self geçerli penceredeki geçerli kareyi belirtir, _blank yeni bir pencereyi belirtir, _parent geçerli karenin üst öğesini belirtir ve _top geçerli penceredeki üst düzey kareyi belirtir. TextFormat.url parametresi boş bir dizeyse veya null değerindeyse, bu parametreyi alabilirsiniz veya ayarlayabilirsiniz, ancak bu durumda özellik herhangi bir etkiye sahip olmaz.

İlgili API Öğeleri

Bu metin biçimini kullanan metnin altının çizili olup (true) olmadığını (false) belirtir. Bu alt çizgi <U> etiketi tarafından oluşturulan alt çizgiye benzer ancak, altındaki öğeleri doğru biçimde atlamadığından ikincisi doğru alt çizgi değildir. Varsayılan değer null şeklindedir ve alt çizginin kullanılmadığını belirtir.

Bu metin biçimindeki metnin hedef URL'sini gösterir. url özelliği boş bir dizeyse metin bir köprüye sahip olmaz. Varsayılan değer null şeklindedir ve metnin bir köprüye sahip olmadığını belirtir.

Not: Atanmış bir metin biçimine sahip bir metin, köprünün çalışması için htmlText özelliğiyle ayarlanmalıdır.

İlgili API Öğeleri

Belirtilen özelliklere sahip bir TextFormat nesnesi oluşturur. Metin alanlarının biçimlendirmesini değiştirmek için daha sonra TextFormat nesnesinin özelliklerini değiştirebilirsiniz.

Tanımlanmadığını göstermek için herhangi bir parametre null olarak ayarlanabilir. Tüm parametreler isteğe bağlıdır; atlanan herhangi bir parametreye null olarak müdahale edilir.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. TextField türünde bir label özelliği oluşturulur.
2. Sınıf yapıcısı configureLabel() işlevini çağırır.
3. configureLabel() işlevi ilk olarak yeni bir TextField nesnesi oluşturur ve bunu label öğesine atar, ardından bu nesnenin parametrelerini şu şekilde ayarlar
   • Metin alanını sola yaslayarak
   • Arka plan dolgusunu etkinleştirerek
   • Kenarlığı etkinleştirerek.
4. Ardından, configureLabel() öğesi, format yerel değişkenini oluşturur ve bunu parametreleri şöyle ayarlı olacak şekilde yeni bir TextFormat örneğine atar:
   • Font type = Verdana
   • Font Color = solid red
   • Font size = 10
   • Font underline = true.
5. Etiketin defaultTextFormat özelliği format olarak ayarlanır, label örneği görüntüleme nesnesine eklenir ve böylece metin alanı sahne alanı üzerinde ilk olarak metinsiz (beyaz arka plana sahip küçük bir kutu) görüntülenir.
6. Son olarak (yapıcıya geri dönüldüğünde), etiketin metni setLabel() öğesini çağırarak x = 0, y = 0 koordinatlarında "Hello World and welcome to the show" mesajını görüntüleyecek şekilde ayarlanır.

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}