JSON  - AS3

JSON formatlı bir Dizeyi kabul eder ve bu değeri temsil eden bir ActionScript nesnesi döndürür. JSON nesneleri, dizileri, dizeleri, sayıları, Boolean öğeleri ve null öğeleri, aşağıda gösterilen ilgili ActionScript değerlerine eşlenir:

reviver parametresi, iki parametre alan bir işlevdir: bir tuş ve bir değer. Bu işlevi, her bir tuş/değer çiftini ayrıştırıldığında dönüştürmek veya filtrelemek için kullanabilirsiniz. Bir reviver işlevi sağlamanız durumunda, parse() işlevi çıktısında varsayılan ayrıştırma yerine, her bir çift için dönüştürülen veya filtrelenen değeriniz döndürülür. reviver işlevi herhangi bir çift için undefined döndürürse, özellik nihai sonuçtan silinir.

reviver parametresine iletilen bağımsız değişken bir işlev olmadığında, ActionScript kJSONInvalidReviver hata kimliğine sahip bir TypeError atar. Ayrıca, yerelleştirilmiş bir hata mesajı da gönderir.

parse() işlevi bir nesne içinde kopya tuşlarla karşılaşırsa, son karşılaşılan kopya tuş, söz konusu tuşun tüm önceki örneklerine yönelik değeri sağlar.

Parametreler

Bir ActionScript değerini temsil eden bir String öğesini JSON formatında döndürür. stringify yöntemi üç parametre alabilir.

value parametresi gerekir. Bu parametre bir ActionScript değeridir. Genellikle bu bir Object veya Array öğesidir, ancak bir String, Boolean, Number veya null öğesi de olabilir.

İsteğe bağlı replacer parametresi bir işlev veya bir dize ya da sayı dizisi olabilir. Bu bir işlevse, işlev iki parametre alır: bir tuş ve bir değer. Bu işlevi, her bir tuş/değer çiftini ayrıştırıldığında dönüştürmek veya filtrelemek için kullanabilirsiniz. Bir replacer işlevi sağlamanız durumunda, parse() işlevi çıktısında varsayılan ayrıştırma yerine, her bir çift için dönüştürülen veya filtrelenen değeriniz döndürülür. replacer işlevi herhangi bir çift için undefined döndürürse, özellik nihai sonuçtan silinir. replacer bir diziyse, hangi özelliklerin çıktıya dahil edileceğini belirlemek için bir filtre olarak kullanılır.

replacer parametresine iletilen bağımsız değişken bir sizi veya işlev değilse, ActionScript kJSONInvalidReplacer hata kimliğine sahip bir TypeError atar. Ayrıca, yerelleştirilmiş bir hata mesajı da gönderir.

İsteğe bağlı space parametresi, okunabilirliği kolaylaştırmak amacıyla beyaz boşluğun döndürülen dizeye eklenmesine olanak tanıyan bir String veya Number öğesidir. Oluşturulan JSON nesnelerinde ve dizilerindeki girişler, space parametresinden türetilen bir boşlukla ayrılır. Bu aralık her zaman 0 ila 10 karakter genişliğindedir. Boşluk bir dize ise, türetilen aralık bu dizenin ilk on karakteridir. Boşluk negatif olmayan sayı x ise, aralık en fazla on boşluk olmak üzere x boşluk karakteri uzunluğundadır. space parametresine iletilen bağımsız değişken bir String veya Number değilse, çıktıdaki aralık olarak kullanılmak üzere bir String öğesine dönüştürülür. Ardından çalıştırma işlemi devam eder.

stringify() yöntemi döngüsel bir yapıyla karşılaştığında, kJSONCyclicStructure hata kimliğine sahip bir TypeError atar. Ayrıca, yerelleştirilmiş bir hata mesajı da gönderir.

Parametreler

1. JSONExample yapıcısı, üst sınıfın text üyesine bir dize atar ve dahili bir sayaç başlatır.
2. Ayrıca sınıf, JSON'a dışa aktarılmış JSONExample nesnelerini içeren bir diziyi tanımlar.
3. JSONExample, toJSON() yöntemini ve revive() yöntemini de tanımlar. toJSON() yöntemi, JSONExample nesnelerini JSON'a serileştirmek üzere JSON.stringify() öğesi tarafından çağrılır. revive() yöntemi, JSONExample nesnesinin tamamını geri yüklemek için JSON.parse() yöntemlerinden çağrılabilir. Bu geri yükleme işlemi, orijinal nesnenin yeniden oluşturulabilir nesneler dizisinden alınması için belirtilen bir kimliğin kullanımıyla gerçekleştirilir.
4. Sınıf tanımını kullanan komut dosyası, iki TextField nesnesi ve bir JSONExample nesnesi içeren bir nesne oluşturur. Ayrıca JSON'a dışa aktarılmış TextField nesnelerinin depolanması için yeniden oluşturulabilir bir nesneler dizisi oluşturur.
5. JSON.stringify() öğesinin replacer işlevi TextField nesnelerini JSON dizesi dışında filtreler. replacer, kaldırılan her bir nesne yerine daha sonra nesneyi almak için kullanılabilecek bir kimliğe sahip işaretleyici sağlar. Bunun yanı sıra, JSONExample nesneleri kendi yerel JSON kodlamalarına göre geçiş yapar.
6. parse() yönteminin reviver işlevi, başvurulan tüm TextField ve JSONExample nesnelerini alarak orijinal nesneyi yeniden oluşturur.

 
 package {
    import flash.text.TextField;
    public class JSONExample extends TextField
    {
        static var nextId = 10000;
        static var revivable_objects:Array = [];
            public var id;

        public function JSONExample(s:String){
            super.text = s;
            id = ++nextId;
        }
        public function toJSON(k):*
        {
            // To be called internally by the JSON.stringify() method.
            // Save the original object internally.
            // Write out only a generated ID and the text value.
            revivable_objects[id] = this;
            return {"classJSONExample":{"reviveId":id,"contents":this.text}};
        }
        public static function revive(id:int):JSONExample
        {
            // For explicit use in the JSON.parse() method.
            // Revives the object using the ID obtained from the JSON string.
            return revivable_objects[id];
        }
    }
}

import flash.text.TextField;

var lastId = 20000;
var tf1:TextField = new TextField();
tf1.text = "Lorem ipsum";
var tf2:TextField = new TextField();
tf2.text = "Laughing cows";
var nt:JSONExample = new JSONExample("It was the best of times; it was the worst of times.");

var obj:Object = {a:tf1, b:nt, c:tf2};
var revivable_objects:Array = new Array();

var json_out = JSON.stringify(obj, function(k,v){
        if (v is JSONExample)
        {
            // Send JSONExample objects to the JSON output.
            // Note that stringify() calls JSONExample.toJSON() to serialize this object.
            return v;
        }
        if (v is TextField)
        {
            // Remove TextField objects from the JSON output.
            // Save the original object for reviving later.
            // Return a new object containing an identification marker
            // and the original object's revival ID.
            revivable_objects[++lastId] = v;
            return {"classTextField":{"reviveId":lastId}};
        }
        return v;
    }
);
               
trace("json_out: " + json_out);

var json_in = JSON.parse(json_out, function(k,v) {
        if ("classTextField" in v) { // special marker tag from stringify() replacer code
            // Retrieve the original object based on the ID stored in the stringify() replacer function.
            var id = v["classTextField"].reviveId;
            return revivable_objects[id];
        } else if ("classJSONExample" in v){
            // Retrieve the original object based on the ID generated in JSONExample.toJSON().
            return JSONExample.revive(v["classJSONExample"].reviveId);
        }
        return v;
    }
);

if (json_in.a)
{
    if (json_in.a.hasOwnProperty("text"))
        {
            trace("json_in.a: " + json_in.a.text);
        }
}
if (json_in.b)
{
    if (json_in.b.hasOwnProperty("text"))
        {
            trace("json_in.b: " + json_in.b.text);
        }
}

if (json_in.c)
{
    if (json_in.c.hasOwnProperty("text"))
        {
            trace("json_in.c: " + json_in.c.text);
        }
}