FocusManager  - AS3 Flash

Geçerli varsayılan düğmeyi alır veya ayarlar.

Varsayılan düğme, bir form üzerinde bulunan ve Enter tuşuna basıldığında odağın o anda nerede olduğuna bağlı olarak bir click olayı gönderen bir düğmedir.

Varsayılan düğmenin etkinleştirilmiş olup olmadığını gösteren bir değer alır veya ayarlar. Bu değer true olarak ayarlanırsa odak yöneticisi Enter tuşunu izler ve Button bileşeni olmayan bir bileşen odak aldığında Enter tuşuna basılırsa, varsayılan düğmeye bir click olayı gönderir. Değer false olarak ayarlanmışsa, odak yöneticisi Enter tuşunu izlemez. Enter tuşunu kullanan bileşenler, kullanıcı Enter tuşuna bastığında, varsa, varsayılan düğmeye bir click olayının gönderilmesini önlemek için bu özelliği false olarak ayarlar.

IFocusManager için temel DisplayObjectContainer öğesi. Genellikle sahne alanı.

Bu sekme döngüsünde kullanmak üzere yeni benzersiz sekme dizinini alır.

Odak alan nesnenin, görsel bir odak göstergesiyle işaretlenip işaretlenmemesi gerektiğini gösteren bir değer alır veya ayarlar.

Yeni bir FocusManager örneği oluşturur.

Odak yöneticisi bir DisplayObjectContainer nesnesinin alt öğeleri arasındaki odağı yönetir.

FocusManager örneğini etkinleştirir.

FocusManager örneği, odakla ilgili klavye ve fare etkinliklerini izlemesini sağlayan olay işleyicileri ekler.

FocusManager öğesini devre dışı bırakır.

FocusManager, odakla ilgili klavye ve fare etkinliklerini izlemesini sağlayan olay işleyicilerini kaldırır.

Varsa belirli nesneyi içeren etkileşimli nesneyi alır. Flash Player, odağı bir Flash bileşeninin alt bileşeni üzerine getirebilir; bu yöntem, bileşen açısından hangi etkileşimli nesnenin odak aldığını belirler.

Parametreler

O anda odağın üzerinde olduğu etkileşimli nesneyi alır. Bu yöntem odağın hangi bileşen üzerinde olduğunu gösterdiğinden Adobe, Stage nesnesini kullanmak yerine bu yöntemi çağırmanızı önerir. Stage nesnesi, o bileşen içinde bir alt bileşeni döndürebilir.

Kullanıcı sonraki nesneye geçmek için Sekme tuşuna bastığında odağın üzerine geleceği etkileşimli nesneyi alır. Bu yöntem, uygulamada geçerli başka nesnelerin olmaması durumunda o anda odağın üzerinde olduğu nesneyi alır.

Parametreler

showFocusIndicator değerini false olarak ayarlar ve görsel odak göstergesini varsa odaktaki nesneden kaldırır.

Odağı bir IFocusManagerComponent bileşeni üzerine getirir. Bu yöntem, bileşenin görünürlüğünü, etkinleştirilmiş durumunu veya diğer koşulları denetlemez.

Parametreler

showFocusIndicator değerini true olarak ayarlar ve görsel odak göstergesini varsa odaktaki nesneye götürür.

Örneği çalıştırmak için şu adımları izleyin:

1. TextInput bileşenini kütüphaneye ekleyin.
2. Bu kodu FLA dosyanızla aynı dizine FocusManagerExample.as olarak kaydedin.
3. FLA dosyasındaki Document sınıfını FocusManagerExample olarak ayarlayın.

package
{
    import fl.controls.TextInput;
    import fl.managers.FocusManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.utils.Timer;

    public class FocusManagerExample extends Sprite 
    {
        private var fm:FocusManager;
        
        public function FocusManagerExample() {
            buildGridOfTextInputs();

            fm = new FocusManager(this);
            var t:Timer = new Timer(1000);
            t.addEventListener(TimerEvent.TIMER,secondPassed);
            t.start();
        }
        private function buildGridOfTextInputs():void {
            var rowSpacing:uint = 30;
            var colSpacing:uint = 110;
            var totalRows:uint = 4;
            var totalCols:uint = 3;
            var i:uint;
            
            for(i = 0; i < totalRows * totalCols; i++) {
                var ti:TextInput = new TextInput()
                ti.name = "component"+i.toString();
                ti.addEventListener(FocusEvent.FOCUS_IN,focusChange);
                ti.setSize(100,20);
                ti.x = 10 + ((i % totalCols) * colSpacing);
                ti.y = 10 + (Math.floor(i / totalCols) * rowSpacing);
                ti.tabEnabled = true;
                addChild(ti);
            }
        }
        private function secondPassed(e:TimerEvent):void {
            var nextComponent:InteractiveObject = fm.getNextFocusManagerComponent();
            fm.setFocus(nextComponent);    
        }
        
        private function focusChange(e:FocusEvent):void {
            trace("Focus change: " + e.target.name);
        }
    }
}