Event

包	flash.events
类	public class Event
继承	Event Object
子类	AccelerometerEvent, ActionSelectedEvent, ActivityEvent, AdvancedDataGridEvent, AdvancedDataGridHeaderShiftEvent, AdvancedDataGridItemSelectEvent, AIREvent, AlternativeAudioEvent, AnnotationParseEvent, AssetActionCompleteEvent, AssetActionCompleteEvent, AssetActionEvent, AssetActionsChangeEvent, AssetValidationEvent, AttachmentEvent, AudioEvent, AudioOutputChangeEvent, AuthenticationEvent, AutomationAirEvent, AutomationEvent, AutomationFlexNativeMenuEvent, AutomationRecordEvent, AutomationReplayEvent, AVDictionaryDataEvent, AVHTTPStatusEvent, AVPauseAtPeriodEndEvent, BaseEvent, BrowserChangeEvent, BrowserInvokeEvent, BufferEvent, BundleEvent, CalendarLayoutChangeEvent, CaptionChangeEvent, CaptionTargetEvent, ChannelEvent, ChartSelectionChangeEvent, ChildExistenceChangedEvent, CloseEvent, CollectionEvent, ColorPickerEvent, ColorPickerEvent, ComponentEvent, CompositionCompleteEvent, ComputationErrorEvent, ConflictEvent, ContainerChangeEvent, ContextMenuEvent, CubeEvent, CuePointEvent, DamageEvent, DataChangeEvent, DataConflictEvent, DataElementsPanelToolBarEvent, DatagramSocketDataEvent, DataGridEvent, DateChooserEvent, DCTEvent, DDInstanceValueChangeEvent, DeviceRotationEvent, DisplayObjectEvent, DividerEvent, DNSResolverEvent, DocumentPodEvent, DRMAuthenticateEvent, DRMAuthenticationCompleteEvent, DRMDeviceGroupEvent, DRMEvent, DRMLicenseRequestEvent, DRMMetadataEvent, DRMReturnVoucherCompleteEvent, DRMStatusEvent, DropdownEvent, DropDownEvent, DVREvent, DynamicEvent, DynamicStreamEvent, EffectEvent, ElementExistenceEvent, ErrorEvent, ExpressionBuilderEvent, ExpressionEvent, ExpressionInsertEvent, ExpressionRegistrationFailureEvent, ExpressionRegistrationSuccessEvent, ExpressionsPanelToolBarEvent, ExpressionValueChangeEvent, FileEvent, FileEvent, FileListEvent, FlexEvent, FlexNativeMenuEvent, FlowElementMouseEvent, FlowOperationEvent, FocusEvent, FunctionFamilyProviderEvent, FunctionsPanelToolBarEvent, GAEvent, GameInputEvent, GanttActionEvent, GanttEvent, GeolocationEvent, GestureEvent, GridCaretEvent, GridItemEditorEvent, GridSelectionEvent, GridSortEvent, HTMLUncaughtScriptExceptionEvent, HTTPStatusEvent, IKEvent, IndexChangedEvent, IndexChangeEvent, InterManagerRequest, InvokeEvent, ItemClickEvent, KeyboardEvent, LabelEditorEvent, LayoutEvent, LayoutEvent, ListEvent, ListEvent, ListItemSelectEvent, LiveCycleEvent, LiveCycleFaultEvent, LoaderEvent, LoaderInvalidationEvent, LoadEvent, LocationChangeEvent, LogEvent, MarshalledAutomationEvent, MediaElementEvent, MediaErrorEvent, MediaEvent, MediaFactoryEvent, MediaPlayerCapabilityChangeEvent, MediaPlayerStateChangeEvent, MenuShowEvent, Message, MessageEvent, MessageFaultEvent, MetadataEvent, MetadataEvent, MetadataEvent, MotionEvent, MouseEvent, MoveEvent, NativeProcessExitEvent, NativeWindowBoundsEvent, NativeWindowDisplayStateEvent, NetConnectionFactoryEvent, NetDataEvent, NetMonitorEvent, NetStatusEvent, NumericStepperEvent, OptionMenuEvent, OutputProgressEvent, PackageDefinitionLoadFailedEvent, PackageDefinitionReadyEvent, PackageObjectReadyEvent, PermissionEvent, PlayEvent, PluginNotInstalledEvent, PopUpEvent, PreviewEvent, PRMErrorEvent, ProcessComponentEvent, ProgressEvent, ProjectEvent, PropertyChangeEvent, PropertyLoadEvent, QoSInfoEvent, RCAErrorEvent, ReferenceChangedEvent, RelationEvent, RemoteNotificationEvent, RendererExistenceEvent, Request, RequestAwareEvent, ResizeEvent, RSLEvent, SampleDataEvent, SandboxMouseEvent, ScaleChangedEvent, SchedulesStateEvent, ScrollEvent, ScrollEvent, SearchEvent, SearchEvent, SeekEvent, SelectionEvent, SerialElementEvent, ServerSocketConnectEvent, ServiceEvent, SessionFaultEvent, SessionResultEvent, ShaderEvent, SliderEvent, SliderEvent, SoftKeyboardEvent, SoundEvent, SparkDataGridItemSelectEvent, SparkListItemSelectEvent, SparkValueChangeAutomationEvent, SQLEvent, SQLUpdateEvent, StageEvent, StageOrientationEvent, StageParticipantEvent, StageVideoAvailabilityEvent, StageVideoEvent, StartpointEvent, StateChangeEvent, StatusChangeEvent, StatusEvent, StorageVolumeChangeEvent, SwfAppButtonEvent, SwfAppEvent, SWFBridgeEvent, SWFBridgeRequest, SwfDataEvent, SyncEvent, TabLayoutEvent, TaskCompletedEvent, TaskManagerEvent, TaskManagerFaultEvent, TaskPropertyChangedEvent, TeamPodEvent, TemplateEvent, TextEvent, TextLayoutEvent, TextOperationEvent, TextSelectionEvent, ThrottleEvent, TimeEvent, TimerEvent, TitleWindowBoundsEvent, ToolTipEvent, TouchEvent, TouchInteractionEvent, TrackBaseEvent, TreeEvent, TweenEvent, TweenEvent, UpdateCompleteEvent, UpdateEvent, UploadEvent, UserEvent, UserSelectedEvent, ValidationResultEvent, VariableChangeEvent, VersionEvent, VideoEvent, VideoEvent, VideoEvent, VideoTextureEvent, ViewNavigatorEvent, VsyncStateChangeAvailabilityEvent, WorkItemEvent, XFADataLoadFailedEvent, XFADataReadyEvent, XFADataSavedEvent, XFADataSaveFailedEvent, XMLDataReadyEvent, XMLLoadEvent

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event 类作为创建 Event 对象的基类，当发生事件时，Event 对象将作为参数传递给事件侦听器。

Event 类的属性包含有关事件的基本信息，例如事件的类型或者是否可以取消事件的默认行为。对于许多事件（如由 Event 类常量表示的事件），此基本信息就足够了。但其他事件可能需要更详细的信息。例如，与鼠标单击关联的事件需要包括有关单击事件的位置以及在单击事件期间是否按下了任何键的其他信息。您可以通过扩展 Event 类（MouseEvent 类执行的操作）将此类其他信息传递给事件侦听器。ActionScript 3.0 API 为需要其他信息的常见事件定义多个 Event 子类。与每个 Event 子类关联的事件将在每个类的文档中加以介绍。

Event 类的方法可以在事件侦听器函数中使用以影响事件对象的行为。某些事件有关联的默认行为。例如，doubleClick 事件有关联的默认行为，此行为突出显示事件发生时鼠标指针下的词。通过调用 preventDefault() 方法，您的事件侦听器可以取消此行为。也可以通过调用 stopPropagation() 或 stopImmediatePropagation() 方法，将当前事件侦听器作为处理事件的最后一个事件侦听器。

其他信息源包括：

Ted Patrick 的博客条目 Flash Player 心智模型 — 塑胶跑道中关于事件计时、代码执行、在运行时进行渲染等方面的有用说明。
Johannes Tacskovics 的博客条目影片剪辑生命周期中关于帧事件（如 ENTER_FRAME、EXIT_FRAME）计时的内容。
Trevor McCauley 的一篇讲述 ActionScript 操作的顺序的文章：ActionScript 中的操作顺序。
Matt Przybylski 关于创建自定义事件的博客条目：AS3：自定义事件。

查看示例

相关 API 元素

flash.events.EventDispatcher

公共属性

隐藏继承的公共属性

显示继承的公共属性

	属性		由以下参数定义
		bubbles : Boolean [只读] 表示事件是否为冒泡事件。	Event
		cancelable : Boolean [只读] 表示是否可以阻止与事件相关联的行为。	Event
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		currentTarget : Object [只读] 当前正在使用某个事件侦听器处理 Event 对象的对象。	Event
		eventPhase : uint [只读] 事件流中的当前阶段。	Event
		target : Object [只读] 事件目标。	Event
		type : String [只读] 事件的类型。	Event

公共方法

隐藏继承的公共方法

显示继承的公共方法

	方法		由以下参数定义
		Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) 创建一个作为参数传递给事件侦听器的 Event 对象。	Event
		clone():Event 复制 Event 子类的实例。	Event
		formatToString(className:String, ... arguments):String 用于在自定义 ActionScript 3.0 Event 类中实现 toString() 方法的实用程序函数。	Event
		hasOwnProperty(name:String):Boolean 表示对象是否已经定义了指定的属性。	Object
		isDefaultPrevented():Boolean 检查是否已对事件调用 preventDefault() 方法。	Event
		isPrototypeOf(theClass:Object):Boolean 表示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		preventDefault():void 如果可以取消事件的默认行为，则取消该行为。	Event
		propertyIsEnumerable(name:String):Boolean 表示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		stopImmediatePropagation():void 防止对事件流中当前节点中和所有后续节点中的事件侦听器进行处理。	Event
		stopPropagation():void 防止对事件流中当前节点的后续节点中的所有事件侦听器进行处理。	Event
		toLocaleString():String 返回此对象的字符串表示形式，其格式设置遵守区域设置特定的约定。	Object
		toString():String 返回一个字符串，其中包含 Event 对象的所有属性。	Event
		valueOf():Object 返回指定对象的原始值。	Object

公共常量

	常量		由以下参数定义
		ACTIVATE : String = "activate" [静态] ACTIVATE 常量定义 activate 事件对象的 type 属性的值。	Event
		ADDED : String = "added" [静态] Event.ADDED 常量定义 added 事件对象的 type 属性值。	Event
		ADDED_TO_STAGE : String = "addedToStage" [静态] Event.ADDED_TO_STAGE 常量定义 addedToStage 事件对象的 type 属性值。	Event
		BROWSER_ZOOM_CHANGE : String = "browserZoomChange" [静态] Event.BROWSER_ZOOM_CHANGE 常量定义 browserZoomChange 事件对象的 type 属性的值。	Event
		CANCEL : String = "cancel" [静态] Event.CANCEL 常量定义 cancel 事件对象的 type 属性的值。	Event
		CHANGE : String = "change" [静态] Event.CHANGE 常量定义 change 事件对象的 type 属性值。	Event
		CHANNEL_MESSAGE : String = "channelMessage" [静态] Event.CHANNEL_MESSAGE 常量定义 channelMessage 事件对象的 type 属性的值。	Event
		CHANNEL_STATE : String = "channelState" [静态] Event.CHANNEL_STATE 常量定义 channelState 事件对象的 type 属性的值。	Event
		CLEAR : String = "clear" [静态] Event.CLEAR 常量定义 clear 事件对象的 type 属性值。	Event
		CLOSE : String = "close" [静态] Event.CLOSE 常量定义 close 事件对象的 type 属性的值。	Event
		CLOSING : String = "closing" [静态] Event.CLOSING 常量定义 closing 事件对象的 type 属性值。	Event
		COMPLETE : String = "complete" [静态] Event.COMPLETE 常量定义 complete 事件对象的 type 属性值。	Event
		CONNECT : String = "connect" [静态] Event.CONNECT 常量定义 connect 事件对象的 type 属性值。	Event
		CONTEXT3D_CREATE : String = "context3DCreate" [静态] Event.CONTEXT3D_CREATE 常量定义 context3Dcreate 事件对象的 type 属性值。	Event
		COPY : String = "copy" [静态] 定义 copy 事件对象的 type 属性值。	Event
		CUT : String = "cut" [静态] 定义 cut 事件对象的 type 属性值。	Event
		DEACTIVATE : String = "deactivate" [静态] Event.DEACTIVATE 常量定义 deactivate 事件对象的 type 属性值。	Event
		DISPLAYING : String = "displaying" [静态] Event.DISPLAYING 常量定义 displaying 事件对象的 type 属性值。	Event
		ENTER_FRAME : String = "enterFrame" [静态] Event.ENTER_FRAME 常量定义 enterFrame 事件对象的 type 属性值。	Event
		EXIT_FRAME : String = "exitFrame" [静态] Event.EXIT_FRAME 常量定义 exitFrame 事件对象的 type 属性的值。	Event
		EXITING : String = "exiting" [静态] Event.EXITING 常量定义 exiting 事件对象的 type 属性值。	Event
		FRAME_CONSTRUCTED : String = "frameConstructed" [静态] Event.FRAME_CONSTRUCTED 常量定义 frameConstructed 事件对象的 type 属性的值。	Event
		FRAME_LABEL : String = "frameLabel" [静态] Event.FRAME_LABEL 常量定义 frameLabel 事件对象的 type 属性的值。	Event
		FULLSCREEN : String = "fullScreen" [静态] Event.FULL_SCREEN 常量定义 fullScreen 事件对象的 type 属性值。	Event
		HTML_BOUNDS_CHANGE : String = "htmlBoundsChange" [静态] Event.HTML_BOUNDS_CHANGE 常量定义 htmlBoundsChange 事件对象的 type 属性值。	Event
		HTML_DOM_INITIALIZE : String = "htmlDOMInitialize" [静态] Event.HTML_DOM_INITIALIZE 常量定义 htmlDOMInitialize 事件对象的 type 属性值。	Event
		HTML_RENDER : String = "htmlRender" [静态] Event.HTML_RENDER 常量定义 htmlRender 事件对象的 type 属性值。	Event
		ID3 : String = "id3" [静态] Event.ID3 常量定义 id3 事件对象的 type 属性值。	Event
		INIT : String = "init" [静态] Event.INIT 常量定义 init 事件对象的 type 属性值。	Event
		LOCATION_CHANGE : String = "locationChange" [静态] Event.LOCATION_CHANGE 常量定义 locationChange 事件对象的 type 属性值。	Event
		MOUSE_LEAVE : String = "mouseLeave" [静态] Event.MOUSE_LEAVE 常量定义 mouseLeave 事件对象的 type 属性值。	Event
		NETWORK_CHANGE : String = "networkChange" [静态] Event.NETWORK_CHANGE 常量定义 networkChange 事件对象的 type 属性值。	Event
		OPEN : String = "open" [静态] Event.OPEN 常量用于定义 open 事件对象的 type 属性值。	Event
		PASTE : String = "paste" [静态] Event.PASTE 常量定义 paste 事件对象的 type 属性的值。	Event
		PREPARING : String = "preparing" [静态] Event.PREPARING 常量定义 preparing 事件对象的 type 属性值。	Event
		REMOVED : String = "removed" [静态] Event.REMOVED 常量定义 removed 事件对象的 type 属性值。	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [静态] Event.REMOVED_FROM_STAGE 常量定义 removedFromStage 事件对象的 type 属性值。	Event
		RENDER : String = "render" [静态] Event.RENDER 常量定义 render 事件对象的 type 属性的值。	Event
		RESIZE : String = "resize" [静态] Event.RESIZE 常量定义 resize 事件对象的 type 属性的值。	Event
		SCROLL : String = "scroll" [静态] Event.SCROLL 常量定义 scroll 事件对象的 type 属性值。	Event
		SELECT : String = "select" [静态] Event.SELECT 常量定义 select 事件对象的 type 属性的值。	Event
		SELECT_ALL : String = "selectAll" [静态] Event.SELECT_ALL 常量定义 selectAll 事件对象的 type 属性的值。	Event
		SOUND_COMPLETE : String = "soundComplete" [静态] Event.SOUND_COMPLETE 常量定义 soundComplete 事件对象的 type 属性值。	Event
		STANDARD_ERROR_CLOSE : String = "standardErrorClose" [静态] Event.STANDARD_ERROR_CLOSE 常量定义 standardErrorClose 事件对象的 type 属性的值。	Event
		STANDARD_INPUT_CLOSE : String = "standardInputClose" [静态] Event.STANDARD_INPUT_CLOSE 常量定义 standardInputClose 事件对象的 type 属性的值。	Event
		STANDARD_OUTPUT_CLOSE : String = "standardOutputClose" [静态] Event.STANDARD_OUTPUT_CLOSE 常量定义 standardOutputClose 事件对象的 type 属性的值。	Event
		SUSPEND : String = "suspend" [静态] Event.SUSPEND 常量定义 suspend 事件对象的 type 属性的值。	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [静态] Event.TAB_CHILDREN_CHANGE 常量定义 tabChildrenChange 事件对象的 type 属性值。	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [静态] Event.TAB_ENABLED_CHANGE 常量定义 tabEnabledChange 事件对象的 type 属性值。	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [静态] Event.TAB_INDEX_CHANGE 常量定义 tabIndexChange 事件对象的 type 属性值。	Event
		TEXT_INTERACTION_MODE_CHANGE : String = "textInteractionModeChange" [静态] Event.TEXT_INTERACTION_MODE_CHANGE 常量定义交互模式事件对象的 type 属性值。	Event
		TEXTURE_READY : String = "textureReady" [静态] Event.TEXTURE_READY 常量定义 textureReady 事件对象的类型属性值。	Event
		UNLOAD : String = "unload" [静态] Event.UNLOAD 常量定义 unload 事件对象的 type 属性值。	Event
		USER_IDLE : String = "userIdle" [静态] Event.USER_IDLE 常量定义 userIdle 事件对象的 type 属性值。	Event
		USER_PRESENT : String = "userPresent" [静态] Event.USER_PRESENT 常量定义 userPresent 事件对象的 type 属性值。	Event
		VIDEO_FRAME : String = "videoFrame" [静态] Event.VIDEO_FRAME 常量定义 videoFrame 事件对象的 type 属性的值。	Event
		WORKER_STATE : String = "workerState" [静态] Event.WORKER_STATE 常量定义 workerState 事件对象的 type 属性的值。	Event

属性详细信息

bubbles

属性

bubbles:Boolean [只读]

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

表示事件是否为冒泡事件。如果事件可以冒泡，则此值为 true；否则为 false。

发生事件时，该事件在事件流的三个阶段中移动：捕获阶段，该阶段从显示列表层次结构的顶部流动到目标节点之前的节点；目标阶段，该阶段只包括目标节点；冒泡阶段，该阶段从目标节点的后续节点沿显示列表层次结构向上往回流动。

某些事件（例如 activate 和 unload 事件）没有冒泡阶段。对于没有冒泡阶段的事件，bubbles 属性的值为 false。

实现
public function get bubbles():Boolean

cancelable

属性

cancelable:Boolean [只读]

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

表示是否可以阻止与事件相关联的行为。如果可以取消该行为，则此值为 true；否则为 false。

实现
public function get cancelable():Boolean

相关 API 元素

Event.preventDefault()

currentTarget

属性

currentTarget:Object [只读]

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

当前正在使用某个事件侦听器处理 Event 对象的对象。例如，如果用户单击“确定”按钮，则当前目标可以是包含该按钮的节点，也可以是它的已为该事件注册了事件侦听器的祖代之一。

实现
public function get currentTarget():Object

eventPhase

属性

eventPhase:uint [只读]

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

事件流中的当前阶段。此属性可以包含以下数值：

捕获阶段 (EventPhase.CAPTURING_PHASE)。
目标阶段 (EventPhase.AT_TARGET)。
冒泡阶段 (EventPhase.BUBBLING_PHASE)。

实现
public function get eventPhase():uint

target

属性

target:Object [只读]

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

事件目标。此属性包含目标节点。例如，如果用户单击“确定”按钮，则目标节点就是包含该按钮的显示列表节点。

实现
public function get target():Object

type

属性

type:String [只读]

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

事件的类型。类型区分大小写。

实现
public function get type():String

构造函数详细信息

()

构造函数

public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

创建一个作为参数传递给事件侦听器的 Event 对象。

参数

	`type:String` — 事件的类型，可以作为 `Event.type` 访问。

	`bubbles:Boolean` (default = `false`) — 确定 Event 对象是否参与事件流的冒泡阶段。默认值为 `false`。

	`cancelable:Boolean` (default = `false`) — 确定是否可以取消 Event 对象。默认值为 `false`。

方法详细信息

clone

()

方法

public function clone():Event

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

复制 Event 子类的实例。

返回一个新的 Event 对象，它是 Event 对象的原始实例的副本。通常您不需要调用 clone()；当您重新调度事件，即调用 dispatchEvent(event)（从正在处理 event 的处理函数）时，EventDispatcher 类会自动调用它。

新的 Event 对象包括原始对象的所有属性。

当您创建自己的自定义 Event 类时，必须覆盖继承的 Event.clone() 方法，以复制自定义类的属性。如果您未设置在事件子类中添加的所有属性，则当侦听器处理重新调度的事件时，这些属性将不会有正确的值。

在本示例中，PingEvent 是 Event 的子类，因此它可以实现其自己的 clone() 版本。

     class PingEvent extends Event {
         var URL:String;
         
     public override function clone():Event {
              return new PingEvent(type, bubbles, cancelable, URL);
        }
     }

Event — 一个新的 Event 对象，它与原始对象相同。

formatToString

()

方法

public function formatToString(className:String, ... arguments):String

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

用于在自定义 ActionScript 3.0 Event 类中实现 toString() 方法的实用程序函数。建议覆盖 toString() 方法，但不是必须覆盖。

	 class PingEvent extends Event {
	  var URL:String;
	 
	 public override function toString():String { 
	  return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL"); 
	    }
	 }

参数

	`className:String` — 自定义 Event 类的名称。在上面的示例中，`className` 参数为 `PingEvent`。

	`... arguments` — Event 类的属性和在自定义 Event 类中添加的属性。在上面的示例中，`...arguments` 参数包括 `type`、`bubbles`、`cancelable`、`eventPhase` 和 `URL`。

String — 自定义 Event 类的名称和 ...arguments 参数的字符串值。

isDefaultPrevented

()

方法

public function isDefaultPrevented():Boolean

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

检查是否已对事件调用 preventDefault() 方法。如果已调用 preventDefault() 方法，则返回 true；否则返回 false。

Boolean — 如果已调用 preventDefault()，将返回 true；否则将返回 false。

相关 API 元素

flash.events.Event.preventDefault()

preventDefault

()

方法

public function preventDefault():void

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

如果可以取消事件的默认行为，则取消该行为。

许多事件都有默认执行的关联行为。例如，如果用户在文本字段中键入一个字符，则默认行为就是在文本字段中显示该字符。由于可以取消 TextEvent.TEXT_INPUT 事件的默认行为，因此您可以使用 preventDefault() 方法来防止显示该字符。

不可取消行为的一个示例是与 Event.REMOVED 事件关联的默认行为，只要 Flash Player 从显示列表中删除显示对象，就会生成该事件。由于无法取消默认行为（删除元素），因此 preventDefault() 方法对此默认行为无效。

您可以使用 Event.cancelable 属性来检查是否可以防止与特定事件关联的默认行为。如果 Event.cancelable 的值为 true，则可以使用 preventDefault() 来取消事件；否则，preventDefault() 无效。

stopImmediatePropagation

()

方法

public function stopImmediatePropagation():void

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

防止对事件流中当前节点中和所有后续节点中的事件侦听器进行处理。此方法会立即生效，并且会影响当前节点中的事件侦听器。相比之下，在当前节点中的所有事件侦听器都完成处理之前，stopPropagation() 方法不会生效。

注意：此方法不会取消与此事件相关联的行为；有关此功能的信息，请参阅 preventDefault()。

stopPropagation

()

方法

public function stopPropagation():void

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

防止对事件流中当前节点的后续节点中的所有事件侦听器进行处理。此方法不会影响当前节点 (currentTarget) 中的任何事件侦听器。相比之下，stopImmediatePropagation() 方法可以防止对当前节点中和后续节点中的事件侦听器进行处理。对此方法的其他调用没有任何效果。可以在事件流的任何阶段中调用此方法。

注意：此方法不会取消与此事件相关联的行为；有关此功能的信息，请参阅 preventDefault()。

toString

()

方法

public function toString():String

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

返回一个字符串，其中包含 Event 对象的所有属性。字符串的格式如下：

[Event type=value bubbles=value cancelable=value]

String — 一个字符串，其中包含 Event 对象的所有属性。

常量详细信息

ACTIVATE

常量

public static const ACTIVATE:String = "activate"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

ACTIVATE 常量定义 activate 事件对象的 type 属性的值。

注意：此事件既不具有“捕获阶段”也不具有“冒泡阶段”，这意味着必须直接将事件侦听器添加到任何潜在的目标，而无论目标是否位于显示列表中。

AIR for TV 设备从不自动调度此事件。但是您可以手动调度。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `activate` 事件注册的侦听器的任何 DisplayObject 实例。

ADDED

常量

public static const ADDED:String = "added"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.ADDED 常量定义 added 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	要添加到显示列表中的 DisplayObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

ADDED_TO_STAGE

常量

public static const ADDED_TO_STAGE:String = "addedToStage"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9.0.28.0, Flash Lite 4

Event.ADDED_TO_STAGE 常量定义 addedToStage 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	DisplayObject 实例将添加到舞台的显示列表中，可直接添加它，也可以添加包含 DisplayObject 实例的子树。如果 DisplayObject 实例将被直接添加，会在此事件之前发生 `added` 事件。

BROWSER_ZOOM_CHANGE

常量

public static const BROWSER_ZOOM_CHANGE:String = "browserZoomChange"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 15, AIR 15

Event.BROWSER_ZOOM_CHANGE常量定义 browserZoomChange 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	Stage 实例。

相关 API 元素

flash.display.Stage.browserZoomChange

CANCEL

常量

public static const CANCEL:String = "cancel"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.CANCEL 常量定义 cancel 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	对已取消其操作的对象的引用。

相关 API 元素

flash.net.FileReference.cancel

CHANGE

常量

public static const CHANGE:String = "change"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.CHANGE 常量定义 change 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已修改其值的对象。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

CHANNEL_MESSAGE

常量

public static const CHANNEL_MESSAGE:String = "channelMessage"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11.4, AIR 3.4

Event.CHANNEL_MESSAGE 常量定义 channelMessage 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	调度此事件的对象。

CHANNEL_STATE

常量

public static const CHANNEL_STATE:String = "channelState"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11.4, AIR 3.4

Event.CHANNEL_STATE 常量定义 channelState 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	调度此事件的对象。

相关 API 元素

flash.system.Worker.channelState

CLEAR

常量

public static const CLEAR:String = "clear"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5, Flash Lite 4

Event.CLEAR 常量定义 clear 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `clear` 事件注册的侦听器的任何 InteractiveObject 实例。

注意：TextField 对象不会调度 clear、copy、cut、paste 或 selectAll 事件。TextField 对象的上下文菜单中始终包含“剪切”、“复制”、“粘贴”、“清除”和“全选”命令。您不能从 TextField 对象的上下文菜单中删除这些命令。对于 TextField 对象，选择这些命令（或等效键盘命令）不会生成 clear、copy、cut、paste 或 selectAll 事件。但是，扩展 InteractiveObject 类的其他类，包括使用 Flash 文本引擎 (FTE) 构建的组件，将调度这些事件，以响应诸如键盘快捷键和上下文菜单这样的用户操作。

相关 API 元素

flash.display.InteractiveObject.clear

CLOSE

常量

public static const CLOSE:String = "close"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.CLOSE 常量定义 close 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已关闭其连接的对象。

CLOSING

常量

public static const CLOSING:String = "closing"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Lite 4

Event.CLOSING 常量定义 closing 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`true`；取消此事件对象将停止关闭操作。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	要关闭其连接的对象。

相关 API 元素

flash.display.NativeWindow.closing

COMPLETE

常量

public static const COMPLETE:String = "complete"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.COMPLETE 常量定义 complete 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已完成加载的网络对象。

CONNECT

常量

public static const CONNECT:String = "connect"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.CONNECT 常量定义 connect 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已建立网络连接的 Socket 或 XMLSocket 对象。

CONTEXT3D_CREATE

常量

public static const CONTEXT3D_CREATE:String = "context3DCreate"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11, AIR 3

Event.CONTEXT3D_CREATE 常量定义 context3Dcreate 事件对象的 type 属性值。仅由 Stage3D 对象在响应对 Stage3D.requestContext3D 的调用或响应操作系统触发的对绑定到 Stage3D 对象的 Context3D 的重置时引发此事件。检查 Stage3D.context3D 属性以获取新创建的 Context3D 对象。

相关 API 元素

Stage3D

COPY

常量

public static const COPY:String = "copy"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5, Flash Lite 4

定义 copy 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `copy` 事件注册的侦听器的任何 InteractiveObject 实例。

相关 API 元素

flash.display.InteractiveObject.copy

CUT

常量

public static const CUT:String = "cut"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5, Flash Lite 4

定义 cut 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `cut` 事件注册的侦听器的任何 InteractiveObject 实例。

相关 API 元素

flash.display.InteractiveObject.cut

DEACTIVATE

常量

public static const DEACTIVATE:String = "deactivate"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.DEACTIVATE 常量定义 deactivate 事件对象的 type 属性值。

AIR for TV 设备从不自动调度此事件。但是您可以手动调度。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `deactivate` 事件注册的侦听器的任何 DisplayObject 实例。

DISPLAYING

常量

public static const DISPLAYING:String = "displaying"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Lite 4

Event.DISPLAYING 常量定义 displaying 事件对象的 type 属性值。

注意：无论目标是否出现在显示列表中，此事件都不会通过“捕获阶段”，而是被直接调度给此目标。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	将要显示的对象。

ENTER_FRAME

常量

public static const ENTER_FRAME:String = "enterFrame"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.ENTER_FRAME 常量定义 enterFrame 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `enterFrame` 事件注册的侦听器的任何 DisplayObject 实例。

相关 API 元素

flash.display.DisplayObject.enterFrame

EXIT_FRAME

常量

public static const EXIT_FRAME:String = "exitFrame"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.EXIT_FRAME 常量定义 exitFrame 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `enterFrame` 事件注册的侦听器的任何 DisplayObject 实例。

相关 API 元素

flash.display.DisplayObject.exitFrame

EXITING

常量

public static const EXITING:String = "exiting"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Lite 4

Event.EXITING 常量定义 exiting 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`true`；取消此事件对象将停止退出操作。
`currentTarget`	NativeApplication 对象。
`target`	NativeApplication 对象。

相关 API 元素

flash.desktop.NativeApplication.exiting

FRAME_CONSTRUCTED

常量

public static const FRAME_CONSTRUCTED:String = "frameConstructed"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.FRAME_CONSTRUCTED 常量定义 frameConstructed 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `frameConstructed` 事件注册的侦听器的任何 DisplayObject 实例。

FRAME_LABEL

常量

public static const FRAME_LABEL:String = "frameLabel"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11.3, AIR 3.3

Event.FRAME_LABEL 常量定义 frameLabel 事件对象的 type 属性的值。

注意：此事件既不具有“捕获阶段”，也不具有“冒泡阶段”，这表示必须将事件侦听器直接添加到 FrameLabel 对象。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用事件侦听器处理 Event 对象的 FrameLabel 对象。
`target`	具有为 `frameLabel` 事件注册的侦听器的任何 FrameLabel 实例。

相关 API 元素

flash.display.FrameLabel.frameLabel

FULLSCREEN

常量

public static const FULLSCREEN:String = "fullScreen"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.FULL_SCREEN 常量定义 fullScreen 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	Stage 对象。

相关 API 元素

flash.display.Stage.fullScreen

HTML_BOUNDS_CHANGE

常量

public static const HTML_BOUNDS_CHANGE:String = "htmlBoundsChange"

运行时版本:

AIR 1.0, Flash Lite 4

Event.HTML_BOUNDS_CHANGE 常量定义 htmlBoundsChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	HTMLLoader 对象。
`target`	HTMLLoader 对象。

相关 API 元素

htmlBoundsChange 事件

HTML_DOM_INITIALIZE

常量

public static const HTML_DOM_INITIALIZE:String = "htmlDOMInitialize"

运行时版本:

AIR 1.0, Flash Lite 4

Event.HTML_DOM_INITIALIZE 常量定义 htmlDOMInitialize 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	HTMLLoader 对象。
`target`	HTMLLoader 对象。

相关 API 元素

htmlDOMInitialize 事件

HTML_RENDER

常量

public static const HTML_RENDER:String = "htmlRender"

运行时版本:

AIR 1.0, Flash Lite 4

Event.HTML_RENDER 常量定义 htmlRender 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	HTMLLoader 对象。
`target`	HTMLLoader 对象。

相关 API 元素

htmlRender 事件

ID3

常量

public static const ID3:String = "id3"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.ID3 常量定义 id3 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	加载 MP3 的 Sound 对象，ID3 数据现在可用于此对象。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

相关 API 元素

flash.media.Sound.id3

INIT

常量

public static const INIT:String = "init"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.INIT 常量定义 init 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	与所加载的 SWF 文件相关联的 LoaderInfo 对象。

相关 API 元素

flash.display.LoaderInfo.init

LOCATION_CHANGE

常量

public static const LOCATION_CHANGE:String = "locationChange"

运行时版本:

AIR 1.0, Flash Lite 4

Event.LOCATION_CHANGE 常量定义 locationChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	HTMLLoader 对象。
`target`	HTMLLoader 对象。

相关 API 元素

locationChange 事件

MOUSE_LEAVE

常量

public static const MOUSE_LEAVE:String = "mouseLeave"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.MOUSE_LEAVE 常量定义 mouseLeave 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	Stage 对象。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

NETWORK_CHANGE

常量

public static const NETWORK_CHANGE:String = "networkChange"

运行时版本:

AIR 1.0, Flash Lite 4

Event.NETWORK_CHANGE 常量定义 networkChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	NativeApplication 对象。

OPEN

常量

public static const OPEN:String = "open"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.OPEN 常量用于定义 open 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已打开连接的网络对象。

PASTE

常量

public static const PASTE:String = "paste"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5, Flash Lite 4

Event.PASTE 常量定义 paste 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`true`（对于 AIR 运行时为 `false`。）
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `paste` 事件注册的侦听器的任何 InteractiveObject 实例。

相关 API 元素

flash.display.InteractiveObject.paste

PREPARING

常量

public static const PREPARING:String = "preparing"

语言版本:

ActionScript 3.0

运行时版本:

AIR 2.6

Event.PREPARING 常量定义 preparing 事件对象的 type 属性值。

注意：无论目标是否出现在显示列表中，此事件都不会通过“捕获阶段”，而是被直接调度给此目标。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`
`currentTarget`	调度此事件的对象。
`target`	调度此事件的对象。

REMOVED

常量

public static const REMOVED:String = "removed"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.REMOVED 常量定义 removed 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	要从显示列表中删除的 DisplayObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

REMOVED_FROM_STAGE

常量

public static const REMOVED_FROM_STAGE:String = "removedFromStage"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9.0.28.0, Flash Lite 4

Event.REMOVED_FROM_STAGE 常量定义 removedFromStage 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	DisplayObject 实例将从舞台的显示列表中删除，可直接删除它，也可以删除包含 DisplayObject 实例的子树。如果 DisplayObject 实例将被直接删除，会在此事件之前发生 `removed` 事件。

RENDER

常量

public static const RENDER:String = "render"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.RENDER 常量定义 render 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；不能取消默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `render` 事件注册的侦听器的任何 DisplayObject 实例。

RESIZE

常量

public static const RESIZE:String = "resize"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.RESIZE 常量定义 resize 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	Stage 对象。

相关 API 元素

flash.display.Stage.resize

SCROLL

常量

public static const SCROLL:String = "scroll"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.SCROLL 常量定义 scroll 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	已滚动的 TextField 对象。`target` 属性不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

SELECT

常量

public static const SELECT:String = "select"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.SELECT 常量定义 select 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	对象，已在其中选定了一个项目。

SELECT_ALL

常量

public static const SELECT_ALL:String = "selectAll"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10, AIR 1.5, Flash Lite 4

Event.SELECT_ALL 常量定义 selectAll 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	具有为 `selectAll` 事件注册的侦听器的任何 InteractiveObject 实例。

SOUND_COMPLETE

常量

public static const SOUND_COMPLETE:String = "soundComplete"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.SOUND_COMPLETE 常量定义 soundComplete 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	其中声音已播放完毕的 SoundChannel 对象。

相关 API 元素

flash.media.SoundChannel.soundComplete

STANDARD_ERROR_CLOSE

常量

public static const STANDARD_ERROR_CLOSE:String = "standardErrorClose"

语言版本:

ActionScript 3.0

运行时版本:

AIR 2, Flash Lite 4

Event.STANDARD_ERROR_CLOSE 常量定义 standardErrorClose 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`target`	NativeProcess 对象。

STANDARD_INPUT_CLOSE

常量

public static const STANDARD_INPUT_CLOSE:String = "standardInputClose"

语言版本:

ActionScript 3.0

运行时版本:

AIR 2, Flash Lite 4

Event.STANDARD_INPUT_CLOSE 常量定义 standardInputClose 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`target`	NativeProcess 对象。

STANDARD_OUTPUT_CLOSE

常量

public static const STANDARD_OUTPUT_CLOSE:String = "standardOutputClose"

语言版本:

ActionScript 3.0

运行时版本:

AIR 2, Flash Lite 4

Event.STANDARD_OUTPUT_CLOSE 常量定义 standardOutputClose 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`target`	NativeProcess 对象。

SUSPEND

常量

public static const SUSPEND:String = "suspend"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3.3

Event.SUSPEND 常量定义 suspend 事件对象的 type 属性的值。此事件仅在 AIR iOS 上调度。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	NativeApplication 对象。
`target`	NativeApplication 对象。

相关 API 元素

flash.desktop.NativeApplication.suspend

TAB_CHILDREN_CHANGE

常量

public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.TAB_CHILDREN_CHANGE 常量定义 tabChildrenChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	其 tabChildren 标志已更改的对象。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

TAB_ENABLED_CHANGE

常量

public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.TAB_ENABLED_CHANGE 常量定义 tabEnabledChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	其 tabEnabled 标志已更改的 InteractiveObject。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

TAB_INDEX_CHANGE

常量

public static const TAB_INDEX_CHANGE:String = "tabIndexChange"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.TAB_INDEX_CHANGE 常量定义 tabIndexChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	其 tabIndex 已更改的对象。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

TEXT_INTERACTION_MODE_CHANGE

常量

public static const TEXT_INTERACTION_MODE_CHANGE:String = "textInteractionModeChange"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 11, Flash Lite 4

Event.TEXT_INTERACTION_MODE_CHANGE 常量定义 interaction mode 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	其 interaction mode 属性已更改的 TextField 对象。例如，在 Android 上，您可以通过上下文菜单将 interaction mode 更改为 SELECTION。`target` 属性不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

TEXTURE_READY

常量

public static const TEXTURE_READY:String = "textureReady"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11.4, AIR 3.4

Event.TEXTURE_READY 常量定义 textureReady 事件对象的 type 属性值。此事件由 Texture 和 CubeTexture 对象调度，表示异步上传完成。通过在 Texture 或 CubeTexture 上使用 uploadCompressedTextureFromByteArray() 方法，请求异步上传。此事件不会冒泡，也不可取消。

相关 API 元素

Texture.uploadCompressedTextureFromByteArray()
CubeTexture.uploadCompressedTextureFromByteArray()

UNLOAD

常量

public static const UNLOAD:String = "unload"

语言版本:

ActionScript 3.0

运行时版本:

AIR 1.0, Flash Player 9, Flash Lite 4

Event.UNLOAD 常量定义 unload 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	LoaderInfo 对象与将被卸载或替换的 SWF 文件相关联。

相关 API 元素

flash.display.LoaderInfo.unload

USER_IDLE

常量

public static const USER_IDLE:String = "userIdle"

运行时版本:

AIR 1.0, Flash Lite 4

Event.USER_IDLE 常量定义 userIdle 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`target`	NativeApplication 对象。

USER_PRESENT

常量

public static const USER_PRESENT:String = "userPresent"

运行时版本:

AIR 1.0, Flash Lite 4

Event.USER_PRESENT 常量定义 userPresent 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`target`	NativeApplication 对象。

VIDEO_FRAME

常量

public static const VIDEO_FRAME:String = "videoFrame"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11.4, AIR 3.4

Event.VIDEO_FRAME 常量定义 videoFrame 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`target`	调度了此事件的 Camera 对象。

相关 API 元素

flash.media.Camera

WORKER_STATE

常量

public static const WORKER_STATE:String = "workerState"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 11.4, AIR 3.4

Event.WORKER_STATE 常量定义 workerState 事件对象的 type 属性的值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	调度此事件的对象。

相关 API 元素

flash.system.Worker.workerState

示例如何使用本示例

EventExample.as

以下示例使用 EventExample 类和 Square 自定义类来说明如何管理事件冒泡。

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class EventExample extends Sprite {
        
        public function EventExample() {
            var square_0:Square = new Square(300, 0x336633);
            addChild(square_0);
            
            var square_1:Square = new Square(250, 0x669966);
            square_0.addChild(square_1);

            var square_2:Square = new Square(200, 0x66CC66);
            square_1.addChild(square_2);

            var square_3:Square = new Square(150, 0xAA0000);
            square_3.shouldBubble = false;
            square_2.addChild(square_3);

            var square_4:Square = new Square(100, 0x66FF66);
            square_3.addChild(square_4);

            var square_5:Square = new Square(50, 0xCC0000);
            square_5.shouldBubble = false;
            square_4.addChild(square_5);

            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(e:Event):void {
            trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
            trace(">> --------------------------------------------");
        }
    }
}

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

class Square extends Sprite {
    private var sideLen:int;
    private var color:Number;
    public var shouldBubble:Boolean = true;

    public function Square(sideLen:int, color:Number) {
        this.sideLen = sideLen;
        this.color = color;
        init();
        draw();
    }
        
    private function init():void {
        buttonMode = true;
        this.addEventListener(MouseEvent.CLICK, firstClickHandler);
        this.addEventListener(MouseEvent.CLICK, secondClickHandler);
        this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
    }
        
    private function draw():void {
        this.graphics.beginFill(color);
        this.graphics.drawRect(0, 0, sideLen, sideLen);
    }
        
    private function firstClickHandler(e:Event):void {
        trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopPropagation();
        }
    }

    private function secondClickHandler(e:Event):void {
        trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopImmediatePropagation();
            trace(">> --------------------------------------------");
        }
    }

    private function thirdClickHandler(e:Event):void {
        trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
    }
}

EventExample2.as

以下示例创建 ADDED 和 ADDED_TO_STAGE 事件以及 REMOVED 和 REMOVED_FROM_STAGE 事件之间区别的演示。单击 Sprite 将从舞台将其删除，同时还删除其中嵌套的所有内容。例如，单击最大的 Sprite 将导致一个 REMOVED 事件和三个 REMOVED_FROM_STAGE 事件触发。

 package {
    import flash.display.Sprite;
    import flash.events.*;

    public class EventExample2 extends Sprite {
        public function EventExample2():void {
            var parentSprite:Sprite = createSprite("parentSprite",200);
            var childSprite:Sprite = createSprite("childSprite",100);
            var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);
            
            trace(":: Adding to Stage ::");
            this.addChild(parentSprite);
            trace(":: Adding to Stage ::");
            parentSprite.addChild(childSprite);
            trace(":: Adding to Stage ::");
            childSprite.addChild(childOfChildSprite);
        }
        private function createSprite(name:String,size:uint):Sprite {
            trace(":: Creating Sprite ::");
            var newSprite:Sprite = new Sprite();
            newSprite.name = name;
            newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
            newSprite.graphics.drawRect(0,0,size,size);
            newSprite.graphics.endFill();
            newSprite.addEventListener(Event.ADDED, spriteAdded);
            newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
            newSprite.addEventListener(Event.REMOVED, spriteRemoved);
            newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
            newSprite.addEventListener(MouseEvent.CLICK, remove);
            return newSprite;
        }
        private function remove(event:Event) {
            if(event.target == event.currentTarget) {
                trace(":: Removing Clicked Sprite ::");
                var target:Sprite = Sprite(event.target);
                target.parent.removeChild(target);
            }
        }
        private function spriteRemovedFromStage(event:Event):void {
            trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteRemoved(event:Event):void {
            trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
        }
        private function spriteAddedToStage(event:Event):void {
            trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteAdded(event:Event):void {
            trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
        }
    }
}

法律声明 | 在线隐私策略

Event - AS3

类 x

bubbles

cancelable

currentTarget

eventPhase

target

type

Event

clone

formatToString

isDefaultPrevented

preventDefault

stopImmediatePropagation

stopPropagation

toString

ACTIVATE

ADDED

ADDED_TO_STAGE

BROWSER_ZOOM_CHANGE

CANCEL

CHANGE

CHANNEL_MESSAGE

CHANNEL_STATE

CLEAR

CLOSE

CLOSING

COMPLETE

CONNECT

CONTEXT3D_CREATE

COPY

CUT

DEACTIVATE

DISPLAYING

ENTER_FRAME

EXIT_FRAME

EXITING

FRAME_CONSTRUCTED

FRAME_LABEL

FULLSCREEN

HTML_BOUNDS_CHANGE

HTML_DOM_INITIALIZE

HTML_RENDER

ID3

INIT

LOCATION_CHANGE

MOUSE_LEAVE

NETWORK_CHANGE

OPEN

PASTE

PREPARING

REMOVED

REMOVED_FROM_STAGE

RENDER

RESIZE

SCROLL

SELECT

SELECT_ALL

SOUND_COMPLETE

STANDARD_ERROR_CLOSE

STANDARD_INPUT_CLOSE

STANDARD_OUTPUT_CLOSE

SUSPEND

TAB_CHILDREN_CHANGE

TAB_ENABLED_CHANGE

TAB_INDEX_CHANGE

TEXT_INTERACTION_MODE_CHANGE

TEXTURE_READY

UNLOAD

USER_IDLE

USER_PRESENT

VIDEO_FRAME

WORKER_STATE