TouchEvent

包	flash.events
类	public class TouchEvent
继承	TouchEvent Event Object

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

使用 TouchEvent 类，您可以处理设备上那些检测用户与设备之间的接触（例如触摸屏上的手指）的事件。

当用户与带有触摸屏的移动电话或平板电脑等设备交互时，用户通常使用手指或指针设备接触屏幕。可使用 TouchEvent 类开发响应基本触摸事件（如单个手指点击）的应用程序。使用此类中定义的事件类型创建事件侦听器。对于具有接个接触点的用户交互（例如在触摸屏上同时移动多根手指），请使用相关的 GestureEvent 类、PressAndTapGestureEvent 类和 TransformGestureEvent 类。并使用这些类的属性和方法来构造响应用户触摸设备的事件处理程序。

使用 Multitouch 类确定当前环境的触摸交互支持，如果当前环境支持触摸交互，则对其进行管理。

注意：当对象嵌套在显示列表中时，触摸事件的目标将是显示列表中可见的最深的可能嵌套对象。此对象称为目标节点。要使目标节点的祖代（祖代是一个包含显示列表中所有目标节点的对象，从舞台到目标节点的父节点均包括在内）接收触摸事件的通知，请对祖代节点使用 EventDispatcher.addEventListener() 并将 type 参数设置为要检测的特定触摸事件。

在 AIR 3 或更高版本中，您可以侦听具有活动笔针的受支持的 Android 设备上的邻近事件。在此类设备上，proximityMove 和 touchMove 事件对象提供一个字节数组，其中包含从上一移动事件以后取得的路径和压力样本。您可以使用这些样本构造触摸事件之间的笔针的路径。（请注意，带显示列表的笔针输入的交互点击测试仅发生在路径片段的结尾。）

查看示例

公共属性

隐藏继承的公共属性

显示继承的公共属性

	属性		由以下参数定义
		altKey : Boolean 表示 Alt 键是处于活动状态 (true) 还是非活动状态 (false)。	TouchEvent
		bubbles : Boolean [只读] 表示事件是否为冒泡事件。	Event
		cancelable : Boolean [只读] 表示是否可以阻止与事件相关联的行为。	Event
		commandKey : Boolean 表示是否已激活 Command 键（仅限 Mac）。	TouchEvent
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		controlKey : Boolean 表示在 Mac 中是否已激活 Control 键，以及在 Windows 或 Linux 中是否已激活 Ctrl 键。	TouchEvent
		ctrlKey : Boolean 在 Windows 或 Linux 中，表示 Ctrl 键是处于活动状态 (true) 还是非活动状态 (false)。	TouchEvent
		currentTarget : Object [只读] 当前正在使用某个事件侦听器处理 Event 对象的对象。	Event
		eventPhase : uint [只读] 事件流中的当前阶段。	Event
		isPrimaryTouchPoint : Boolean 表示第一个接触点是否映射到鼠标事件。	TouchEvent
		isRelatedObjectInaccessible : Boolean 如果为 true，则 relatedObject 属性是出于与安全沙箱相关的原因而设置为 null 的。	TouchEvent
		isTouchPointCanceled : Boolean 报告操作系统已取消此触摸输入序列。	TouchEvent
		localX : Number 事件发生点相对于所属 Sprite 的水平坐标。	TouchEvent
		localY : Number 事件发生点相对于所属 Sprite 的垂直坐标。	TouchEvent
		pressure : Number 0.0 和 1.0 之间的值表示强制接触设备。	TouchEvent
		relatedObject : InteractiveObject 对与事件相关的显示列表对象的引用。	TouchEvent
		shiftKey : Boolean 表示 Shift 键是处于活动状态 (true) 还是非活动状态 (false)。	TouchEvent
		sizeX : Number 接触区域的宽度。	TouchEvent
		sizeY : Number 接触区域的高度。	TouchEvent
		stageX : Number [只读] 事件发生点在全局舞台坐标中的水平坐标。	TouchEvent
		stageY : Number [只读] 事件发生点在全局舞台坐标中的垂直坐标。	TouchEvent
		target : Object [只读] 事件目标。	Event
		timestamp : Number 报告事件的时间（相对毫秒）。	TouchEvent
		touchIntent : String 报告触摸是由笔针的主要部分产生还是由笔针的橡皮擦末端产生。	TouchEvent
		touchPointID : int 分配给触摸点的唯一标识号（作为 int）。	TouchEvent
		type : String [只读] 事件的类型。	Event

公共方法

隐藏继承的公共方法

显示继承的公共方法

	方法		由以下参数定义
		TouchEvent(type:String, bubbles:Boolean = true, cancelable:Boolean = false, touchPointID:int = 0, isPrimaryTouchPoint:Boolean = false, localX:Number = NaN, localY:Number = NaN, sizeX:Number = NaN, sizeY:Number = NaN, pressure:Number = NaN, relatedObject:InteractiveObject = null, ctrlKey:Boolean = false, altKey:Boolean = false, shiftKey:Boolean = false, commandKey:Boolean = false, controlKey:Boolean = false, timestamp:Number = NaN, touchIntent:String, samples:ByteArray = null, isTouchPointCanceled:Boolean = false) 创建包含有关触摸事件信息的 Event 对象。	TouchEvent
		clone():Event [覆盖] 创建 TouchEvent 对象的副本，并将每个属性的值设置为与原始属性值相匹配。	TouchEvent
		formatToString(className:String, ... arguments):String 用于在自定义 ActionScript 3.0 Event 类中实现 toString() 方法的实用程序函数。	Event
		getSamples(buffer:ByteArray, append:Boolean = false):uint 使用多点触摸事件的高频数据点更新指定的 ByteArray 对象。	TouchEvent
		hasOwnProperty(name:String):Boolean 表示对象是否已经定义了指定的属性。	Object
		isDefaultPrevented():Boolean 检查是否已对事件调用 preventDefault() 方法。	Event
		isPrototypeOf(theClass:Object):Boolean 表示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		isToolButtonDown(index:int):Boolean 报告已按下指定索引上的硬件按钮。	TouchEvent
		preventDefault():void 如果可以取消事件的默认行为，则取消该行为。	Event
		propertyIsEnumerable(name:String):Boolean 表示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		stopImmediatePropagation():void 防止对事件流中当前节点中和所有后续节点中的事件侦听器进行处理。	Event
		stopPropagation():void 防止对事件流中当前节点的后续节点中的所有事件侦听器进行处理。	Event
		toLocaleString():String 返回此对象的字符串表示形式，其格式设置遵守区域设置特定的约定。	Object
		toString():String [覆盖] 返回一个字符串，其中包含 TouchEvent 对象的所有属性。	TouchEvent
		updateAfterEvent():void 如果已修改显示列表，则将表示 Flash Player 或 Adobe AIR 在此事件处理完成后呈示结果。	TouchEvent
		valueOf():Object 返回指定对象的原始值。	Object

公共常量

隐藏继承的公共常量

显示继承的公共常量

	常量		由以下参数定义
		PROXIMITY_BEGIN : String = "proximityBegin" [静态] 定义 PROXIMITY_BEGIN 触摸事件对象的 type 属性的值。	TouchEvent
		PROXIMITY_END : String = "proximityEnd" [静态] 定义 PROXIMITY_END 触摸事件对象的 type 属性的值。	TouchEvent
		PROXIMITY_MOVE : String = "proximityMove" [静态] 定义 PROXIMITY_MOVE 触摸事件对象的 type 属性的值。	TouchEvent
		PROXIMITY_OUT : String = "proximityOut" [静态] 定义 PROXIMITY_OUT 触摸事件对象的 type 属性的值。	TouchEvent
		PROXIMITY_OVER : String = "proximityOver" [静态] 定义 PROXIMITY_OVER 触摸事件对象的 type 属性的值。	TouchEvent
		PROXIMITY_ROLL_OUT : String = "proximityRollOut" [静态] 定义 PROXIMITY_ROLL_OUT 触摸事件对象的 type 属性的值。	TouchEvent
		PROXIMITY_ROLL_OVER : String = "proximityRollOver" [静态] 定义 PROXIMITY_ROLL_OVER 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_BEGIN : String = "touchBegin" [静态] 定义 TOUCH_BEGIN 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_END : String = "touchEnd" [静态] 定义 TOUCH_END 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_MOVE : String = "touchMove" [静态] 定义 TOUCH_MOVE 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_OUT : String = "touchOut" [静态] 定义 TOUCH_OUT 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_OVER : String = "touchOver" [静态] 定义 TOUCH_OVER 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_ROLL_OUT : String = "touchRollOut" [静态] 定义 TOUCH_ROLL_OUT 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_ROLL_OVER : String = "touchRollOver" [静态] 定义 TOUCH_ROLL_OVER 触摸事件对象的 type 属性的值。	TouchEvent
		TOUCH_TAP : String = "touchTap" [静态] 定义 TOUCH_TAP 触摸事件对象的 type 属性的值。	TouchEvent

属性详细信息

altKey

属性

altKey:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2

表示 Alt 键是处于活动状态 (true) 还是非活动状态 (false)。仅 Windows 和 Linux 操作系统支持。

实现
public function get altKey():Boolean
public function set altKey(value:Boolean):void

commandKey

属性

commandKey:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2

表示是否已激活 Command 键（仅限 Mac）。

在 Mac OS 上，commandKey 属性的值与 ctrlKey 属性相同。在 Windows 或 Linux 上，此属性始终是 false。

实现
public function get commandKey():Boolean
public function set commandKey(value:Boolean):void

controlKey

属性

controlKey:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2

表示在 Mac 中是否已激活 Control 键，以及在 Windows 或 Linux 中是否已激活 Ctrl 键。

实现
public function get controlKey():Boolean
public function set controlKey(value:Boolean):void

ctrlKey

属性

ctrlKey:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2

在 Windows 或 Linux 中，表示 Ctrl 键是处于活动状态 (true) 还是非活动状态 (false)。在 Macintosh 中，表示是否已激活 Control 键或 Command 键。

实现
public function get ctrlKey():Boolean
public function set ctrlKey(value:Boolean):void

isPrimaryTouchPoint

属性

isPrimaryTouchPoint:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

表示第一个接触点是否映射到鼠标事件。

实现
public function get isPrimaryTouchPoint():Boolean
public function set isPrimaryTouchPoint(value:Boolean):void

相关 API 元素

flash.events.MouseEvent

isRelatedObjectInaccessible

属性

isRelatedObjectInaccessible:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

如果为 true，则 relatedObject 属性是出于与安全沙箱相关的原因而设置为 null 的。如果 relatedObject 的标称值是对其他沙箱中的 DisplayObject 的引用，则 relatedObject 将设置为 null，除非具有双向跨越此沙箱边界的权限。通过以下方式确立权限：从 SWF 文件调用 Security.allowDomain()；或者通过从图像文件的服务器提供策略文件，然后在加载图像时设置 LoaderContext.checkPolicyFile 属性。

实现
public function get isRelatedObjectInaccessible():Boolean
public function set isRelatedObjectInaccessible(value:Boolean):void

isTouchPointCanceled

属性

isTouchPointCanceled:Boolean

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

报告操作系统已取消此触摸输入序列。

触摸事件可由于多种原因而被取消，例如，由于正在使用笔针而拒绝手掌产生的触摸。isTouchPointCanceled 仅可在 touchEnd 事件中为 true。

实现
public function get isTouchPointCanceled():Boolean
public function set isTouchPointCanceled(value:Boolean):void

localX

属性

localX:Number

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

事件发生点相对于所属 Sprite 的水平坐标。

实现
public function get localX():Number
public function set localX(value:Number):void

localY

属性

localY:Number

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

事件发生点相对于所属 Sprite 的垂直坐标。

实现
public function get localY():Number
public function set localY(value:Number):void

pressure

属性

pressure:Number

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

0.0 和 1.0 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 1.0。

实现
public function get pressure():Number
public function set pressure(value:Number):void

relatedObject

属性

relatedObject:InteractiveObject

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

对与事件相关的显示列表对象的引用。例如，发生 touchOut 事件时，relatedObject 表示指针设备当前指向的显示列表对象。此属性适用于 touchOut、touchOver、touchRollOut 和 touchRollOver 事件。

在以下两种情况下，此属性的值可以为 null：无相关对象；存在相关对象，但该对象位于您无法访问的安全沙箱中。使用 isRelatedObjectInaccessible() 属性可确定上述哪一个原因适用。

实现
public function get relatedObject():InteractiveObject
public function set relatedObject(value:InteractiveObject):void

相关 API 元素

TouchEvent.isRelatedObjectInaccessible

shiftKey

属性

shiftKey:Boolean

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2

表示 Shift 键是处于活动状态 (true) 还是非活动状态 (false)。

实现
public function get shiftKey():Boolean
public function set shiftKey(value:Boolean):void

sizeX

属性

sizeX:Number

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

接触区域的宽度。

实现
public function get sizeX():Number
public function set sizeX(value:Number):void

sizeY

属性

sizeY:Number

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

接触区域的高度。

实现
public function get sizeY():Number
public function set sizeY(value:Number):void

stageX

属性

stageX:Number [只读]

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

事件发生点在全局舞台坐标中的水平坐标。当设置 localX 属性时会计算此属性。

实现
public function get stageX():Number

stageY

属性

stageY:Number [只读]

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

事件发生点在全局舞台坐标中的垂直坐标。当设置 localY 属性时会计算此属性。

实现
public function get stageY():Number

timestamp

属性

timestamp:Number

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

报告事件的时间（相对毫秒）。

报告的时间相对于应用程序开始执行的时间。对于返回样本缓冲区中一系列点的事件，时间戳反映了缓冲区中上一样本的运行时间。

实现
public function get timestamp():Number
public function set timestamp(value:Number):void

相关 API 元素

getSamples()

touchIntent

属性

touchIntent:String

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

报告触摸是由笔针的主要部分产生还是由笔针的橡皮擦末端产生。

如果触摸事件由手指或其他非笔针输入方法产生，或者由不受支持的高频运动跟踪的笔针产生，则此属性报告值：TouchEventIntent.UNKNOWN。

TouchEventIntent 类定义此属性的可能值的常量，包括：

TouchEventIntent.ERASER
TouchEventIntent.PEN
TouchEventIntent.UNKNOWN

实现
public function get touchIntent():String
public function set touchIntent(value:String):void

相关 API 元素

TouchEventIntent

touchPointID

属性

touchPointID:int

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

分配给触摸点的唯一标识号（作为 int）。

实现
public function get touchPointID():int
public function set touchPointID(value:int):void

示例 ( 如何使用本示例 )

以下示例建立了一个变量 touchMoveID，用于测试正确的 touchPointID 值，以便对触摸移动事件做出响应。此外，其他触摸输入也会触发事件处理函数。请注意，用于侦听移动和结束阶段的侦听器位于舞台上，而不是显示对象上。如果用户的触摸超出了显示对象的范围，那么舞台会侦听移动阶段或结束阶段。

Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT; 

var mySprite:Sprite = new Sprite(); 
mySprite.graphics.beginFill(0x336699); 
mySprite.graphics.drawRect(0,0,40,40); 
addChild(mySprite); 

var myTextField:TextField = new TextField(); 
addChild(myTextField); 
myTextField.width = 200; 
myTextField.height = 20; 

var touchMoveID:int = 0; 
 
mySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin); 
function onTouchBegin(event:TouchEvent) { 
    if(touchMoveID != 0) { 
        myTextField.text = "already moving. ignoring new touch";     
        return; 
    } 
    touchMoveID = event.touchPointID; 
 
    myTextField.text = "touch begin" + event.touchPointID; 
    stage.addEventListener(TouchEvent.TOUCH_MOVE, onTouchMove); 
    stage.addEventListener(TouchEvent.TOUCH_END, onTouchEnd); 
} 
function onTouchMove(event:TouchEvent) { 
    if(event.touchPointID != touchMoveID) { 
        myTextField.text = "ignoring unrelated touch"; 
        return; 
    } 
    mySprite.x = event.stageX; 
    mySprite.y = event.stageY; 
    myTextField.text = "touch move" + event.touchPointID; 
} 
function onTouchEnd(event:TouchEvent) { 
    if(event.touchPointID != touchMoveID) { 
        myTextField.text = "ignoring unrelated touch end"; 
        return; 
    } 
    touchMoveID = 0; 
    stage.removeEventListener(TouchEvent.TOUCH_MOVE, onTouchMove); 
    stage.removeEventListener(TouchEvent.TOUCH_END, onTouchEnd); 
    myTextField.text = "touch end" + event.touchPointID; 
}

构造函数详细信息

()

构造函数

public function TouchEvent(type:String, bubbles:Boolean = true, cancelable:Boolean = false, touchPointID:int = 0, isPrimaryTouchPoint:Boolean = false, localX:Number = NaN, localY:Number = NaN, sizeX:Number = NaN, sizeY:Number = NaN, pressure:Number = NaN, relatedObject:InteractiveObject = null, ctrlKey:Boolean = false, altKey:Boolean = false, shiftKey:Boolean = false, commandKey:Boolean = false, controlKey:Boolean = false, timestamp:Number = NaN, touchIntent:String, samples:ByteArray = null, isTouchPointCanceled:Boolean = false)

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

创建包含有关触摸事件信息的 Event 对象。将 Event 对象作为参数传递给事件侦听器。

参数

	`type:String` — 事件的类型。可能的值包括： `TouchEvent.PROXIMITY_BEGIN`、`TouchEvent.PROXIMITY_END`、`TouchEvent.PROXIMITY_MOVE`、`TouchEvent.PROXIMITY_OUT`、`TouchEvent.PROXIMITY_OVER`、`TouchEvent.PROXIMITY_ROLL_OUT`、`TouchEvent.PROXIMITY_ROLL_OVER`、`TouchEvent.TOUCH_BEGIN`、`TouchEvent.TOUCH_END`、`TouchEvent.TOUCH_MOVE`、`TouchEvent.TOUCH_OUT`、`TouchEvent.TOUCH_OVER`、`TouchEvent.TOUCH_ROLL_OUT`、`TouchEvent.TOUCH_ROLL_OVER` 和 `TouchEvent.TOUCH_TAP`。

	`bubbles:Boolean` (default = `true`) — 确定 Event 对象是否参与事件流的冒泡阶段。

	`cancelable:Boolean` (default = `false`) — 确定是否可以取消 Event 对象。

	`touchPointID:int` (default = `0`) — 分配给触摸点的唯一标识号（作为 int）。

	`isPrimaryTouchPoint:Boolean` (default = `false`) — 表示第一个接触点是否映射到鼠标事件。

	`localX:Number` (default = `NaN`) — 事件发生点相对于所属 Sprite 的水平坐标。

	`localY:Number` (default = `NaN`) — 事件发生点相对于所属 Sprite 的垂直坐标。

	`sizeX:Number` (default = `NaN`) — 接触区域的宽度。

	`sizeY:Number` (default = `NaN`) — 接触区域的高度。

	`pressure:Number` (default = `NaN`) — `0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。

	`relatedObject:InteractiveObject` (default = `null`) — 受事件影响的补充 InteractiveObject 实例。例如，发生 `touchOut` 事件时，`relatedObject` 表示指针设备当前指向的显示列表对象。

	`ctrlKey:Boolean` (default = `false`) — 在 Windows 或 Linux 中，表示是否已激活 Ctrl 键。在 Mac 中，表示是否已激活 Ctrl 键或 Command 键。

	`altKey:Boolean` (default = `false`) — 表示是否已激活 Alt 键（仅限 Windows 或 Linux）。

	`shiftKey:Boolean` (default = `false`) — 表示是否已激活 Shift 键。

	`commandKey:Boolean` (default = `false`) — （仅 AIR）表示 Command 键是否已激活（仅限 Mac）。此参数仅适用于 Adobe AIR；请勿对 Flash Player 内容设置此参数。

	`controlKey:Boolean` (default = `false`) — （仅 AIR）表示 Control 或 Ctrl 键是否已激活。此参数仅适用于 Adobe AIR；请勿对 Flash Player 内容设置此参数。

	`timestamp:Number` (default = `NaN`) — （仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。

	`touchIntent:String` (default = `NaN`) — （仅 AIR）来自 TouchEventIntent 类的值。

	`samples:ByteArray` (default = `null`) — （仅 AIR）ByteArray 对象，包含从序列中上次触摸或邻近事件以来记录的每个中间样本的位置和压力读数。

	`isTouchPointCanceled:Boolean` (default = `false`) — （仅 AIR）如果由于触摸类型受拒绝而取消触摸事件，则值为 `true`。

方法详细信息

clone

()

方法

override public function clone():Event

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

创建 TouchEvent 对象的副本，并将每个属性的值设置为与原始属性值相匹配。

Event — 其属性值与原始属性值相匹配的新 TouchEvent 对象。

getSamples

()

方法

public function getSamples(buffer:ByteArray, append:Boolean = false):uint

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

使用多点触摸事件的高频数据点更新指定的 ByteArray 对象。

使用此次与上次触摸事件之间的中间数据点的值更新 buffer 参数引用的 ByteArray 对象。为每个样本添加三个浮点值：x 坐标、y 坐标和压力值。舞台坐标中报告的位置值。采用 0 与 1 之间的一个值的形式报告压力。采用常规时间间隔记录样本。精确频率依赖于设备硬件和硬件驱动程序。典型的样本频率大概是 133 Hz 左右。请注意，不会以精确的间隔调度触摸事件。因此，类似事件的缓冲区可包含不同的样本数。缓冲区的最后样本具有与此触摸事件对象的 stageX、stageY 和 pressure 属性相同的数据。

样本缓冲区包含在为 proximityMove 和 touchMove 事件调度的事件对象中。

参数

	`buffer:ByteArray` — 要接收样本数据的 ByteArray 对象。

	`append:Boolean` (default = `false`) — 当值为 `True` 时，样本会添加到以数组的当前 `position` 属性开始的 `buffer` 字节数组。当值为 `False`（默认值）时，在添加样本前，会丢弃 buffer 对象中的现有数据。

uint — 添加到缓冲区的样本数单位。每个样本包含三个浮点数。

示例 ( 如何使用本示例 )

下面的示例说明如何从 touchMove 或 proximityMove 事件检索示例数据。

function touchMoveHandler( event:TouchEvent ):void
{
    if( (event.type == TouchEvent.TOUCH_MOVE ||
        event.type == TouchEvent.PROXIMITY_MOVE) &&
        event.touchEventIntent != TouchEventIntent.UNKNOWN )
    {
        var samples:ByteArray = new ByteArray();
        event.getSamples( samples, true );
        samples.position = 0;     // rewind to beginning of array before reading
        
        var xCoord:Number, yCoord:Number, pressure:Number;
        
        while( samples.bytesAvailable > 0 )
        {
            xCoord = samples.readFloat();
            yCoord = samples.readFloat();
            pressure = samples.readFloat();
            //do something with the sample data
        }
    }
}

下面的示例说明如何从 touchMove 或 proximityMove 事件检索示例数据。在此例中，这些示例会追加到现有字节数组。

var samples:ByteArray = new ByteArray();

function touchMoveHandler( event:TouchEvent ):void
{
    if( (event.type == TouchEvent.TOUCH_MOVE ||
        event.type == TouchEvent.PROXIMITY_MOVE) &&
        event.touchEventIntent != TouchEventIntent.UNKNOWN )
    {
        var sampleCount:uint = event.getSamples( samples, true );         
        var xCoord:Number, yCoord:Number, pressure:Number;
        
        for( var i:int; i < sampleCount; i++ )
        {
            xCoord = samples.readFloat();
            yCoord = samples.readFloat();
            pressure = samples.readFloat();
            //do something with the sample data
        }
    }
}

isToolButtonDown

()

方法

public function isToolButtonDown(index:int):Boolean

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

报告已按下指定索引上的硬件按钮。

参数

index:int — 笔针类型的输入设备支持按钮的从零开始的索引。

Boolean

toString

()

方法

override public function toString():String

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

返回一个字符串，其中包含 TouchEvent 对象的所有属性。字符串的格式如下：

[TouchEvent type=value bubbles=value cancelable=value ... ]

String — 一个字符串，其中包含 TouchEvent 对象的所有属性。

updateAfterEvent

()

方法

public function updateAfterEvent():void

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

如果已修改显示列表，则将表示 Flash Player 或 Adobe AIR 在此事件处理完成后呈示结果。

常量详细信息

PROXIMITY_BEGIN

常量

public static const PROXIMITY_BEGIN:String = "proximityBegin"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_BEGIN 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

PROXIMITY_END

常量

public static const PROXIMITY_END:String = "proximityEnd"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_END 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

PROXIMITY_MOVE

常量

public static const PROXIMITY_MOVE:String = "proximityMove"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_MOVE 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

PROXIMITY_OUT

常量

public static const PROXIMITY_OUT:String = "proximityOut"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_OUT 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

PROXIMITY_OVER

常量

public static const PROXIMITY_OVER:String = "proximityOver"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_OVER 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

PROXIMITY_ROLL_OUT

常量

public static const PROXIMITY_ROLL_OUT:String = "proximityRollOut"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_ROLL_OUT 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

PROXIMITY_ROLL_OVER

常量

public static const PROXIMITY_ROLL_OVER:String = "proximityRollOver"

语言版本:

ActionScript 3.0

运行时版本:

AIR 3

定义 PROXIMITY_ROLL_OVER 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。
`timestamp`	（仅 AIR）相对于应用程序开始的事件时间戳（毫秒）。
`touchIntent`	（仅 AIR）来自 TouchEventIntent 类的值。
`isTouchPointCanceled`	（仅 AIR）如果由于设备的触摸拒绝逻辑而取消触摸事件，则值为 `true`。

TOUCH_BEGIN

常量

public static const TOUCH_BEGIN:String = "touchBegin"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_BEGIN 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_END

常量

public static const TOUCH_END:String = "touchEnd"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_END 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_MOVE

常量

public static const TOUCH_MOVE:String = "touchMove"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_MOVE 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_OUT

常量

public static const TOUCH_OUT:String = "touchOut"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_OUT 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_OVER

常量

public static const TOUCH_OVER:String = "touchOver"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_OVER 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_ROLL_OUT

常量

public static const TOUCH_ROLL_OUT:String = "touchRollOut"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_ROLL_OUT 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_ROLL_OVER

常量

public static const TOUCH_ROLL_OVER:String = "touchRollOver"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_ROLL_OVER 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

TOUCH_TAP

常量

public static const TOUCH_TAP:String = "touchTap"

语言版本:

ActionScript 3.0

运行时版本:

Flash Player 10.1, AIR 2, Flash Lite 4

定义 TOUCH_TAP 触摸事件对象的 type 属性的值。

调度的 TouchEvent 对象具有下列属性：

属性	值
`altKey`	如果 Alt 键处于活动状态，则为 `true`（Windows 或 Linux）。
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`commandKey`	在 Mac 中，如果 Command 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。在 Windows 中始终为 `false`。
`controlKey`	如果 Ctrl 或 Control 键处于活动状态，则为 `true`，如果处于非活动状态，则为 `false`。
`ctrlKey`	在 Windows 或 Linux 中，如果 Ctrl 键处于活动状态，则为 `true`。在 Mac 中，如果 Ctrl 键或 Command 键处于活动状态，则为 `true`。否则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`eventPhase`	事件流中的当前阶段。
`isRelatedObjectInaccessible`	如果由于安全沙箱规则的原因将 relatedObject 属性设置为 `null`，则为 `true`。
`localX`	事件发生点相对于所属 Sprite 的水平坐标。
`localY`	事件发生点相对于所属 Sprite 的垂直坐标。
`pressure`	`0.0` 和 `1.0` 之间的值表示强制接触设备。如果设备不支持检测压力，则此值为 `1.0`。
`relatedObject`	对与此事件相关的显示列表对象的引用。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`sizeX`	接触区域的宽度。
`sizeY`	接触区域的高度。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	触摸设备下的 InteractiveObject 实例。`target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`touchPointID`	分配给触摸点的唯一标识号（作为 int）。

示例 ( 如何使用本示例 )

以下示例在启用触摸的屏幕上点击在 mySprite 上绘制的正方形时显示一条信息：

Multitouch.inputMode=MultitouchInputMode.TOUCH_POINT;

var mySprite:Sprite = new Sprite();
var myTextField:TextField = new TextField();

mySprite.graphics.beginFill(0x336699);
mySprite.graphics.drawRect(0,0,40,40);
addChild(mySprite);

mySprite.addEventListener(TouchEvent.TOUCH_TAP, taphandler);

function taphandler(e:TouchEvent): void {
    myTextField.text = "I've been tapped";
    myTextField.y = 50;
    addChild(myTextField);
}

示例如何使用本示例

TouchEventExample.as

以下示例显示针对 TOUCH_BEGIN 事件、TOUCH_MOVE 事件和 TOUCH_END 事件的事件处理。当接触点在屏幕上移动 (onTouchMove) 时，会跟踪相对于舞台的 X 坐标以便输出。对于 onTouchBegin 函数中的 Sprite.startTouchDrag 参数，touchPointID 的值是分配给事件对象的值。bounds 参数是定义父显示对象（bg 是包含 MySprite 的显示对象）的边界的矩形。

Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT;

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_MOVE, onTouchMove);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(eBegin:TouchEvent) {
     eBegin.target.startTouchDrag(eBegin.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }

function onTouchMove(eMove:TouchEvent) {
    trace(eMove.stageX);
}
 
function onTouchEnd(eEnd:TouchEvent) {
     eEnd.target.stopTouchDrag(eEnd.touchPointID);
     trace("touch end");
}

TouchExample2.as

下面的示例说明如何处理触摸事件和触摸事件阶段，以及 Multitouch.maxTouchPoints 和触摸事件对象的 touchPointID 属性。此示例由 Christian Cantrell 提供，他在快速入门指南中对此示例进行了更详细介绍：Multi-touch and gesture support on the Flash Platform。

 package
{
    import flash.display.Sprite;
    import flash.events.TouchEvent;
    import flash.text.AntiAliasType;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.ui.Multitouch;
    import flash.ui.MultitouchInputMode;

    [SWF(width=320, height=460, frameRate=24, backgroundColor=0xEB7F00)]
    public class TouchExample2 extends Sprite
    {
        private var dots:Object;
        private var labels:Object;
        private var labelFormat:TextFormat;
        private var dotCount:uint;
        private var dotsLeft:TextField;
        private static const LABEL_SPACING:uint = 15;
        
        public function TouchExample2()
        {
            super();

            this.labelFormat = new TextFormat();
            labelFormat.color = 0xACF0F2;
            labelFormat.font = "Helvetica";
            labelFormat.size = 11;
            
            this.dotCount = 0;

            this.dotsLeft = new TextField();
            this.dotsLeft.width = 300;
            this.dotsLeft.defaultTextFormat = this.labelFormat;
            this.dotsLeft.x = 3;
            this.dotsLeft.y = 0;
            this.stage.addChild(this.dotsLeft);
            this.updateDotsLeft();

            this.dots = new Object();
            this.labels = new Object();

            Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT;
            this.stage.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
            this.stage.addEventListener(TouchEvent.TOUCH_MOVE, onTouchMove);
            this.stage.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);
        }

        private function onTouchBegin(e:TouchEvent):void
        {
            if (this.dotCount == Multitouch.maxTouchPoints) return;
            var dot:Sprite = this.getCircle();
            dot.x = e.stageX;
            dot.y = e.stageY;
            this.stage.addChild(dot);
            dot.startTouchDrag(e.touchPointID, true);
            this.dots[e.touchPointID] = dot;
            
            ++this.dotCount;

            var label:TextField = this.getLabel(e.stageX + ", " + e.stageY);
            label.x = 3;
            label.y = this.dotCount * LABEL_SPACING;
            this.stage.addChild(label);
            this.labels[e.touchPointID] = label;

            this.updateDotsLeft();
        }
        
        private function onTouchMove(e:TouchEvent):void
        {
            var label:TextField = this.labels[e.touchPointID];
            label.text = (e.stageX + ", " + e.stageY);
        }
        
        private function onTouchEnd(e:TouchEvent):void
        {
            var dot:Sprite = this.dots[e.touchPointID];
            var label:TextField = this.labels[e.touchPointID];
            
            this.stage.removeChild(dot);
            this.stage.removeChild(label);
            
            delete this.dots[e.touchPointID];
            delete this.labels[e.touchPointID];
            
            --this.dotCount;

            this.updateDotsLeft();
        }
        
        private function getCircle(circumference:uint = 40):Sprite
        {
            var circle:Sprite = new Sprite();
            circle.graphics.beginFill(0x1695A3);
            circle.graphics.drawCircle(0, 0, circumference);
            return circle;
        }

        private function getLabel(initialText:String):TextField
        {
            var label:TextField = new TextField();
            label.defaultTextFormat = this.labelFormat;
            label.selectable = false;
            label.antiAliasType = AntiAliasType.ADVANCED;
            label.text = initialText;
            return label;
        }
        
        private function updateDotsLeft():void
        {
            this.dotsLeft.text = "Touches Remaining: " + (Multitouch.maxTouchPoints - this.dotCount);
        }
    }
}

法律声明 | 在线隐私策略

TouchEvent - AS3

类 x

altKey

commandKey

controlKey

ctrlKey

isPrimaryTouchPoint

isRelatedObjectInaccessible

isTouchPointCanceled

localX

localY

pressure

relatedObject

shiftKey

sizeX

sizeY

stageX

stageY

timestamp

touchIntent

touchPointID

TouchEvent

clone

getSamples

isToolButtonDown

toString

updateAfterEvent

PROXIMITY_BEGIN

PROXIMITY_END

PROXIMITY_MOVE

PROXIMITY_OUT

PROXIMITY_OVER

PROXIMITY_ROLL_OUT

PROXIMITY_ROLL_OVER

TOUCH_BEGIN

TOUCH_END

TOUCH_MOVE

TOUCH_OUT

TOUCH_OVER

TOUCH_ROLL_OUT

TOUCH_ROLL_OVER

TOUCH_TAP