MouseEvent  - AS3

表示 Alt 键是处于活动状态 (true) 还是非活动状态 (false)。仅 Windows 支持。在其他操作系统上，此属性始终设置为 false。

表示鼠标主按键是已按下 (true) 还是未按下 (false)。

表示鼠标按下事件是否为多击序列的一部分。对于除 MouseEvent.mouseDown、MouseEvent.mouseUp、MouseEvent.middleMouseDown、MouseEvent.middleMouseUp、MouseEvent.rightMouseDown 和 MouseEvent.rightMouseUp 以外的所有鼠标事件，此参数将为零。使用 clickCount 参数可以侦听单击、双击或任何多击序列。例如，初始 MouseEvent.mouseDown 和 MouseEvent.mouseUp 的 clickCount 为 1，双击序列中的第二个 MouseEvent.mouseDown 和 MouseEvent.mouseUp 的 clickCount 为 2。如果充分地移动鼠标或多击序列由于某种原因中断，则下一个 MouseEvent.mouseDown 的 clickCount 将为 1。doubleClick 事件将会继续正常触发。

表示是否已激活 Command 键（仅限 Mac）。

commandKey 属性的值将与 Mac 中 ctrlKey 属性的值相同。在 Windows 或 Linux 中始终为 false。

表示在 Mac 中是否已激活 Control 键，以及在 Windows 或 Linux 中是否已激活 Ctrl 键。

在 Windows 或 Linux 中，表示 Ctrl 键是处于活动状态 (true) 还是非活动状态 (false)。在 Macintosh 中，表示是否已激活 Control 键或 Command 键。

表示用户将鼠标滚轮每滚动一个单位应滚动多少行。正 delta 值表示向上滚动；负值表示向下滚动。通常所设的值为 1 到 3；值越大，滚动得越快。此设置取决于设备和操作系统，并且通常可由用户配置。此属性仅应用于 MouseEvent.mouseWheel 事件。

如果为 true，则 relatedObject 属性是出于与安全沙箱相关的原因而设置为 null 的。如果 relatedObject 的标称值是对其他沙箱中的 DisplayObject 的引用，则 relatedObject 将设置为 null，除非具有双向跨越此沙箱边界的权限。通过以下方式确立权限：从 SWF 文件调用 Security.allowDomain()；或者通过从图像文件的服务器提供策略文件，然后在加载图像时设置 LoaderContext.checkPolicyFile 属性。

相关 API 元素

禁用鼠标锁定时，事件发生点相对于所属 Sprite 的水平坐标。将 Stage.mouseLock 设置为 false 以禁用鼠标锁定。

启用鼠标锁定时，localX 和 localY 是 0。启用鼠标锁定时，使用 movementX 和 movementY 确定鼠标位置的更改。

相关 API 元素

禁用鼠标锁定时，事件发生点相对于所属 Sprite 的垂直坐标。将 Stage.mouseLock 设置为 false 以禁用鼠标锁定。

启用鼠标锁定时，localX 和 localY 是 0。启用鼠标锁定时，使用 movementX 和 movementY 确定鼠标位置的更改。

相关 API 元素

启用鼠标锁定时，自上一次鼠标事件以来鼠标位置在 X 方向的更改。将 Stage.mouseLock 设置为 true 以启用鼠标锁定。

以下情况会启用鼠标锁定：

• localX 和 localY 包含 0。
• movementX 和 movementY 包含 delta 值。
• movementX 和 movementY 从未基于舞台转换进行变换。这表示它们总是保持在屏幕坐标中。

Stage.mouseLock 为 false 时，movementX 和 movementY 为 0。

相关 API 元素

启用鼠标锁定时，自上一次鼠标事件以来鼠标位置在 Y 方向的更改。将 Stage.mouseLock 设置为 true 以启用鼠标锁定。

以下情况会启用鼠标锁定：

• localX 和 localY 包含 0。
• movementX 和 movementY 包含 delta 值。
• movementX 和 movementY 从未基于舞台转换进行变换。这表示它们总是保持在屏幕坐标中。

Stage.mouseLock 为 false 时，movementX 和 movementY 为 0。

相关 API 元素

对与事件相关的显示列表对象的引用。例如，发生 mouseOut 事件时，relatedObject 表示指针设备当前所指向的显示列表对象。此属性应用于 mouseOut、mouseOver、rollOut 和 rollOver 事件。

在以下两种情况下，此属性的值可以为 null：不存在任何相关对象；存在相关对象，但该对象位于您无法访问的安全沙箱中。使用 isRelatedObjectInaccessible() 属性可确定上述哪一个原因适用。

相关 API 元素

表示 Shift 键是处于活动状态 (true) 还是非活动状态 (false)。

事件发生点在全局舞台坐标中的水平坐标。当设置 localX 属性时会计算此属性。

事件发生点在全局舞台坐标中的垂直坐标。当设置 localY 属性时会计算此属性。

创建一个 Event 对象，其中包含有关鼠标事件的信息。将 Event 对象作为参数传递给事件侦听器。

创建 MouseEvent 对象的副本，并设置每个属性的值以匹配原始属性值。

返回一个字符串，其中包含 MouseEvent 对象的所有属性。字符串的格式如下：

[MouseEvent type=value bubbles=value cancelable=value ... delta=value]

如果已修改显示列表，则将表示 Flash Player 或 Adobe AIR 在此事件处理完成后呈示结果。

定义 click 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

MouseEvent.CONTEXT_MENU 常量定义 contextMenu 事件对象的 type 属性的值。

此事件具有以下属性：

定义 doubleClick 事件对象的 type 属性值。对象的 doubleClickEnabled 属性必须为 true 以生成 doubleClick 事件。

此事件具有以下属性：

相关 API 元素

定义 middleClick 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 middleMouseDown 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 middleMouseUp 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 mouseDown 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 mouseMove 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

定义 mouseOut 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 mouseOver 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 mouseUp 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 mouseWheel 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 releaseOutside 事件对象的 type 属性的值。

此事件具有以下属性：

相关 API 元素

定义 rightClick 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 rightMouseDown 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 rightMouseUp 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 rollOut 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

定义 rollOver 事件对象的 type 属性值。

此事件具有以下属性：

相关 API 元素

1. 本示例声明了有关大小（100 x 100 像素）和背景颜色（橙色）的属性，以便在稍后绘制正方形时使用。
2. 构造函数创建新的 ChildSprite 对象 child。其构造函数首先通过调用其 draw() 方法在坐标 (0,0) 处绘制一个 100 x 100 像素的橙色正方形，然后添加七个事件侦听器/订阅者。
   • click / clickHandler()：当用户用鼠标左键在正方形上单击时调度。
   • doubleClick / doubleClickHandler()：当用户在正方形上双击鼠标左键时调度。
   • mouseDown / mouseDownHandler()：当单击 ChildSprite 对象（橙色正方形）时，会在屏幕上输出 trace() 消息，然后调用 ChildSprite.draw()，这样就会在 mouseOverHandler() 中绘制一个代替浅蓝色正方形的深黄色正方形。mouseDownHandler() 方法还添加一个 mouseMove 事件侦听器和 mouseMoveHandler() 订阅者（如下所述），以处理鼠标的移动。然后调用 startDrag() 方法，此方法允许拖动 Sprite 对象。
   • mouseOut / mouseOutHandler()：每次指针离开正方形区域时调度。调用 draw() 方法以将正方形恢复为其正常大小和颜色。
   • mouseOver/mouseOverHandler()：当鼠标指针位于正方形上方时调度。此方法可以重绘正方形，以使正方形更大并且其背景颜色为深黄色。
   • mouseUp / mouseUpHandler()：当用户释放鼠标按键时，将删除 mouseMove 事件侦听器并调用 stopDrag，这样就会冻结当前位置的正方形。
   • mouseMove/mouseMoveHandler()：作为 mouseDownHandler() 函数的一部分进行调用，在用户按住鼠标左键并拖动正方形时调度。
   • mouseWheel / mouseWheelHandler()：当用户在正方形上方滚动鼠标滚轮时调度。
3. 然后 ChildSprite 实例 child 通过 addChild()（立即绘制橙色正方形）添加到显示列表中。

注意：

• MouseEventExample 类应为文档根。
• 前面列出的某些事件方法声明了局部变量 sprite，它用于 event.target 到类型 Sprite 的强制转换。

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}