LoaderInfo  - AS3

被加载的 SWF 文件的 ActionScript 版本。通过使用 ActionScriptVersion 类中的枚举（如 ActionScriptVersion.ACTIONSCRIPT2 和 ActionScriptVersion.ACTIONSCRIPT3）来指定语言版本。

注意：此属性始终具有值 ActionScriptVersion.ACTIONSCRIPT2 或 ActionScriptVersion.ACTIONSCRIPT3。ActionScript 1.0 和 2.0 都被报告为 ActionScriptVersion.ACTIONSCRIPT2（版本 2.0）。此属性只对 ActionScript 1.0 和 2.0 与 ActionScript 3.0 进行区分。

相关 API 元素

加载外部 SWF 文件后，包含在已加载类中的所有 ActionScript 3.0 定义将存储在 applicationDomain 属性中。

SWF 文件中的所有代码被定义为存在于应用程序域中。主应用程序就在当前的应用程序域中运行。系统域包含所有应用程序域，包括当前域和由 Flash Player 或 Adobe AIR 使用的所有类。

所有应用程序域（系统域除外）都有关联的父域。主应用程序的 applicationDomain 的父域为系统域。已加载的类仅在其父级中没有相关定义时才进行定义。不能用较新的定义覆盖已加载的类定义。

有关应用程序域的使用示例，请参阅《ActionScript 3.0 开发人员指南》中的“客户端系统环境”一章。

相关 API 元素

与 LoaderInfo 对象相关联的字节数。

媒体已加载的字节数。如果此数字与 bytesTotal 的值相等，则会加载所有字节。

整个媒体文件中压缩的字节数。

在此 LoaderInfo 对象相应的 Loader 对象调度第一个 progress 事件之前，bytesTotal 为 0。在该 Loader 对象调度第一个 progress 事件之后，bytesTotal 反映的是要下载的实际字节数。

注意（仅限 iOS）：在 iOS 上运行应用程序时，返回值与其他平台上的返回值不同。

相关 API 元素

表示内容（子级）对加载者（父级）的信任关系。如果子项允许父项访问，则为 true；否则为 false。如果子对象已调用 allowDomain() 方法向父域授予权限，或者在子域中加载了向父域授予权限的 URL 策略，则将此属性设置为 true。如果子级和父级在同一域中，则此属性设置为 true。

有关安全性的详细信息，请参阅 Flash Player 开发人员中心主题：安全性。

一个对象，它可以通过所加载内容的代码进行设置以公开可以由 Loader 对象的沙箱中的代码访问的属性和方法。此沙箱桥使来自非应用程序域的内容对应用程序沙箱中的脚本具有受控访问权限，反之亦然。沙箱桥充当沙箱之间的通道，在应用程序安全沙箱和非应用程序安全沙箱之间提供显式交互。

相关 API 元素

与此 LoaderInfo 对象关联的已加载对象。

被加载文件的 MIME 类型。如果所加载的文件内容不足以确定类型，则该值为 null。以下列表给出了可能的值：

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

被加载的 SWF 文件的标示的帧速率，以每秒帧数为单位。此数字通常是整数，但并不需要是整数。

此值可能与使用时的实际帧速率不同。Flash Player 或 Adobe AIR 在任何时候为所有加载的 SWF 文件只使用单个帧速率，此帧速率由主 SWF 文件的标称帧速率确定。此外，根据硬件、声音同步和其他因素，可能无法达到主帧速率。

加载文件的标示的高度。此值可能与所显示内容的实际高度不同，因为被加载的内容或其父显示对象可能被缩放。

表示 LoaderInfo.url 属性是否已截断。当 isURLInaccessible 值为 true 时，LoaderInfo.url 值只是从中加载内容的最终 URL 的域。例如，如果从 http://www.adobe.com/assets/hello.swf 加载内容，并且 LoaderInfo.url 属性的值为 http://www.adobe.com，则此属性会被截断。仅当下列所有值也全部为 true 时，isURLInaccessible 值才为 true：

• 当加载此内容时，发生 HTTP 重定向。
• 调用 Loader.load() 的 SWF 文件所在域与此内容的最终 URL 所在域不同。
• 调用 Loader.load() 的 SWF 文件不具有访问此内容的权限。授予访问此内容的权限的方式与为 BitmapData.draw() 授予权限的方式相同：调用 Security.allowDomain() 以访问 SWF 文件（或对于非 SWF 文件内容，建立一个策略文件并使用 LoaderContext.checkPolicyFile 属性）。

注意：isURLInaccessible 属性是为 Flash Player 10.1 和 AIR 2.0 添加的。但是，如果 Flash 运行时支持该属性，则该属性适用于所有版本的 SWF 文件。因此，在“严谨模式”下使用某些创作工具会导致出现编译错误。要避免出现此错误，请使用间接语法 myLoaderInfo["isURLInaccessible"]，或禁用严谨模式。如果您使用的是 Flash Professional CS5 或 Flex SDK 4.1，则可以对在 Flash Player 10.1 和 AIR 2 之前发布的运行时使用和编译此 API。

对于 AIR 中的应用程序内容，该属性的值始终为 false。

相关 API 元素

与此 LoaderInfo 对象关联的 Loader 对象。如果此 LoaderInfo 对象是 SWF 文件的主类实例的 loaderInfo 属性，则没有关联的 Loader 对象。

SWF 文件的 URL，该 SWF 文件启动对此 LoaderInfo 对象所描述的媒体的加载。对于 SWF 文件的主类的实例，此 URL 与 SWF 文件自己的 URL 相同。

包含名称-值对的对象，表示为被加载的 SWF 文件提供的参数。

可以使用 for-in 循环来提取 parameters 对象中的所有名称和值。

参数的两个源为：主 SWF 文件的 URL 中的查询字符串和 FlashVars HTML 参数（这只影响主 SWF 文件）的值。

parameters 属性替换了 ActionScript 1.0 和 2.0 提供 SWF 文件参数作为主时间轴的技术。

Loader 对象（该对象包含使用 ActionScript 1.0 或 2.0 的 SWF 文件）的 parameters 属性的值为 null。只有对于包含使用 ActionScript 3.0 的 SWF 文件的 Loader 对象，该值才非 null。

表示加载者（父级）对内容（子级）的信任关系。如果父项允许子项访问，则为 true；否则为 false。如果父对象调用了 allowDomain() 方法向子域授予权限，或者在父域中加载了向子域授予权限的 URL 策略文件，则将此属性设置为 true。如果子级和父级在同一域中，则此属性设置为 true。

有关安全性的详细信息，请参阅 Flash Player 开发人员中心主题：安全性。

一个对象，它可以在 Loader 对象的沙箱中通过代码进行设置以公开可以由所加载内容的代码访问的属性和方法。此沙箱桥使来自非应用程序域的内容对应用程序沙箱中的脚本具有受控访问权限，反之亦然。沙箱桥充当沙箱之间的通道，在应用程序安全沙箱和非应用程序安全沙箱之间提供显式交互。

相关 API 元素

表示加载者和内容之间的域关系：如果它们具有相同的原始域，则为 true；否则为 false。

EventDispatcher 实例，可用于跨安全边界交换事件。即使 Loader 对象和加载的内容源于彼此不信任的安全域，两者仍然可以访问 sharedEvents 并通过此对象发送和接收事件。

已加载的 SWF 文件的文件格式版本。使用 SWFVersion 类（如 SWFVersion.FLASH7 和 SWFVersion.FLASH9）中的枚举指定文件格式。

相关 API 元素

一个在此 LoaderInfo 对象的 SWF 文件中的代码中发生无法处理的错误时调度 uncaughtError 事件的对象。当任何 try..catch 块引发错误时，或调度的 ErrorEvent 对象没有注册的侦听器时，会发生未被捕获的错误。

例如，如果在 try 块中具有调用其事件处理函数的事件调度函数，则 catch 块不会捕获在事件处理函数中引发的错误。随后引发的任何错误可以通过侦听 LoaderInfo.uncaughtErrorEvents 来捕获。

当与此 LoaderInfo 关联的 SWF 完成加载时，会创建此属性。在此之前，uncaughtErrorEvents 属性保持为 null。在只包含 ActionScript 的项目中，可以在 SWF 文件主类的构造函数执行期间或执行后访问此属性。对于 Flex 项目，uncaughtErrorEvents 属性在调度 applicationComplete 事件之后可用。

相关 API 元素

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

所加载媒体的 URL。

在此 LoaderInfo 对象的对应 Loader 对象调度第一个 progress 事件之前，url 属性的值可能只反映在对 Loader 对象的 load() 方法的调用中指定的初始 URL。在第一个 progress 事件之后，url 属性将在解析了任何重定向和相对 URL 后反映媒体的最终 URL。

在某些情况下，url 属性的值会被截断；有关详细信息，请参阅 isURLInaccessible 属性。

相关 API 元素

被加载内容的标示的宽度。此值可能与所显示内容的实际宽度不同，因为被加载的内容或其父显示对象可能被缩放。

返回与定义为对象的 SWF 文件相关联的 LoaderInfo 对象。

参数

成功加载数据后调度。也就是说，当已下载所有内容并且已完成加载过程时调度它。complete 事件始终在 init 事件之后调度。当该对象已做好访问准备（尽管可能仍在下载内容）时，将调度 init 事件。

此事件具有以下属性：

相关 API 元素

在通过 HTTP 发出网络请求并且可以检测到 HTTP 状态代码时调度。

此事件具有以下属性：

相关 API 元素

当已加载的 SWF 文件的属性和方法可供访问并做好使用准备时进行调度。不过，内容可能仍在下载之中。如果存在以下条件，则 LoaderInfo 对象将调度 init 事件：

• 可以访问与加载的对象关联的所有属性和方法以及与 LoaderInfo 对象关联的属性和方法。
• 所有子对象的构造函数已完成。
• 已执行所加载的 SWF 主时间轴的第一帧中的所有 ActionScript 代码。

例如，在加载影片或动画的第一帧时将调度 Event.INIT。然后，影片将可供访问并可添加到显示列表中。不过，下载完整的影片可能需要花更长的时间。只有在加载了完整的影片之后才会调度 Event.COMPLETE。

init 事件始终在 complete 事件之前。

此事件具有以下属性：

相关 API 元素

在发生导致加载操作失败的输入或输出错误时调度。

此事件具有以下属性：

相关 API 元素

在加载操作开始时调度。

此事件具有以下属性：

相关 API 元素

在下载操作过程中收到数据时调度。

此事件具有以下属性：

相关 API 元素

当使用 Loader 对象的 unload() 方法删除已加载对象时，或者当同一 Loader 对象执行第二次加载并且在加载开始之前删除了原始内容时，由 LoaderInfo 对象调度。

此事件具有以下属性：

相关 API 元素

1. 属性 url被创建，该属性是图像的位置和名称。
2. 类构造函数创建一个名为 loader 的 Loader 对象。
3. loader 对象将事件侦听器进行实例化，以确保图像正确加载。
4. 构造函数创建一个 URLRequest 对象的新实例 request，该实例带有传递的 url，这样，就可以知道文件的名称和位置。
5. 然后，request 对象被传递给 loader 对象的 load() 方法，该方法会将图像加载到显示列表上。

重要提示：该示例要求您在编译的 SWF 文件所在的目录中添加一个名为 Image.gif 的文件。使用具有一个适合主 SWF 文件尺寸的区域的图像。

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}