Loader  - AS3

Innehåller rotvisningsobjektet i SWF-filen eller bildfilen (JPG, PNG eller GIF) som lästes in med metoden load() eller loadBytes().

Relaterade API-element

Returnerar ett LoaderInfo-objekt som motsvarar objektet som läses in. LoaderInfo-objekt delas mellan Loader-objektet och det inlästa innehållsobjektet. LoaderInfo-objektet tillhandahåller förloppsinformation om inläsningen och statistik om den inlästa filen.

Händelser som är relaterade till inläsningen skickas av det LoaderInfo-objekt som refereras av egenskapen contentLoaderInfo hos Loader-objektet. Egenskap contentLoaderInfo sätts till ett giltigt LoaderInfo-objekt, också innan innehållet har lästs in, så att du kan lägga till händelseavlyssnare till objektet före inläsningen.

Om du vill identifiera ohanterade fel i en inläst SWF-fil använder du egenskapen Loader.uncaughtErrorEvents, inte egenskapen Loader.contentLoaderInfo.uncaughtErrorEvents.

Relaterade API-element

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Ett objekt som skickar en uncaughtError-händelse när ett ohanterat fel inträffar i den SWF-fil som har lästs in av det här Loader-objektet. Ett ohanterat fel inträffar när ett fel genereras utanför try..catch-block eller när ett ErrorEvent-objekt skickas utan några registrerade avlyssnare.

Tänk på att egenskapen uncaughtErrorEvents för ett Loader-objekt skickar händelser som bubblar genom den, inte händelser som skickas direkt. En uncaughtErrorEvent skickas aldrig i målfasen. Händelsen skickas bara i hämtnings- och bubblingsfaserna. Om du vill identifiera ett ohanterat fel i den aktuella SWF-filen (den SWF-fil i vilken Loader-objektet definieras) använder du egenskapen LoaderInfo.uncaughtErrorEvents i stället.

Om det innehåll som läses in av Loader-objektet är en AVM1 (ActionScript 2) SWF-fil ger ohanterade fel i AVM1 SWF-filen inte upphov till någon uncaughtError-händelse.

Relaterade API-element

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

Skapar ett Loader-objekt som du kan använda för att läsa in filer, till exempel SWF-, JPEG-, GIF- och PNG-filer. Använd metod load() för att läsa in tillgången som underordnad till Loader-instansen. Du kan sedan lägga till Loader-objektet till visningslistan (exempelvis med metod addChild() för en DisplayObjectContainer-instans). Tillgången visas på scenen när den läses in.

Du kan också använda en Loader-instans "offlist", det vill säga utan att lägga in den i en visningsobjektsbehållare på visningslistan. I det här läget kan Loader-instansen användas för att läsa in en SWF-fil som består av ett programs ytterligare moduler.

Du kan se att inläsningen av SWF-filen är klar genom att använda de händelser hos LoaderInfo-objektet som sammanhänger med egenskap contentLoaderInfo-hos Loader-objektet. I det skedet kan koden i modulens SWF-fil köras för att initiera och starta modulen. I offlistläget kan en Loader-instans också användas för att läsa in en SWF-fil som innehåller komponenter eller mediaresurser. Du kan alltså använda LoaderInfo-objektets händelsemeddelanden för att se när inläsningen av komponenterna är klar. I det skedet kan programmet börja använda komponenterna och medieresurserna i SWF-filens bibliotek genom att instansiera de ActionScript 3.0-klasser som representerar dessa komponenter och resurser.

Ta reda på ett Loader-objekts status genom att övervaka följande händelser som LoaderInfo-objektet associerade med egenskapencontentLoaderInfo hos Loader-objektet:

• Händelse open skickas när inläsningen börjar.
• Händelse ioError eller securityError skickas om filen inte kan läsas in eller om ett fel uppstod under inläsningsprocessen.
• Händelse progress aktiveras kontinuerligt när filen läses in.
• Händelse complete skickas när en fil har laddats ned klart, men innan det inlästa filmklippets metoder och egenskaper blir tillgängliga.
• Händelse init skickas efter det att den inlästa SWF-filens egenskaper och metoder är tillgängliga, så att du kan börja arbeta med den inlästa SWF-filen. Denna händelse skickas före hanterare complete. Vid direktuppspelning av SWF-filer kan händelse init uppträda betydligt tidigare än händelse complete. Använd init i de flesta fall.

Obs! (endast iOS) I AIR-program på iOS kan du bara läsa in en SWF-fil som innehåller ActionScript från programpaketet. Den här begränsningen omfattar all ActionScript-kod, som resurser med klassnamn som exporterats för ActionScript. Om du vill läsa in en SWF-fil måste den läsas in med samma programdomän som den överordnade SWF-filen.

I tidigare versioner än AIR 3.6 kan bara SWF-filer som inte innehåller ActionScript-bytekod läsas in, oavsett om de läses från programpaketet eller via ett nätverk. Ett alternativ till att använda en extern SWF-fil med ActionScript är att skapa ett SWC-bibliotek och länka det till SWF-huvudfilen.

Dessa begränsningar gäller inte när ett program körs i iOS-simulatorn (ipa-test-interpreter-simulator eller ipa-debug-interpreter-simulator) eller i tolkläget (ipa-test-interpreter eller ipa-debug-interpreter.)

Relaterade API-element

Avbryter en load()-metodåtgärd som pågår för Loader-instansen.

Relaterade API-element

Läser in en fil av typ SWF, JPEG, progressiv JPEG, oanimerad GIF eller PNG i ett objekt som är underordnat detta Loader-objekt. När du läser in en animerad GIF-fil visas bara den första bildrutan. Eftersom Loader-objektet bara kan innehålla en enda underordnad avslutar utställandet av ytterligare en load()-begäran den föregående begäran, om den fortfarande är oavslutad, och inleder en ny inläsning.

Obs! I AIR 1.5 och Flash Player 10 är maxstorleken för en inläst bild 8 191 pixlar i bredd och höjd, och det totala antalet pixlar får inte överskrida 16 777 215 pixlar. (Om en inläst bild är 8 191 pixlar bred kan den därför bara vara 2 048 pixlar hög.) I Flash Player 9 och tidigare och i AIR 1.1 och tidigare är begränsningen 2 880 pixlar i höjd och 2 880 pixlar i bredd.

En SWF-fil eller bild som lästs in i ett Loader-objekt ärver positionen, rotationen och skalegenskaperna för Loader-objektets överordnade visningsobjekt.

Använd metoden unload() om du vill ta bort filmer och bilder som lästs in med den här metoden eller avbryta en pågående inläsning.

Du kan förhindra att metoden används av en SWF-fil genom att ställa in parametern allowNetworking i object- och embed-taggarna på den HTML-sida där SWF-innehållet finns.

iOS-information

I AIR-program på iOS kan du bara läsa in en SWF-fil som innehåller ActionScript från programpaketet. Den här begränsningen omfattar all ActionScript-kod, som resurser med klassnamn som exporterats för ActionScript. Om du vill läsa in en SWF-fil måste den läsas in med samma programdomän som den överordnade SWF-filen, enligt följande exempel:

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

Dessutom går det inte på en iOS-dator att läsa in en SWF-fil som innehåller någon ActionScript ByteCode (ABC), och sedan ta bort och läsa in den på nytt. Om du försöker göra detta genereras felet 3764 i miljön.

I tidigare versioner än AIR 3.6 kan bara SWF-filer som inte innehåller ActionScript-bytekod läsas in, oavsett om de läses från programpaketet eller via ett nätverk. Ett alternativ till att använda en extern SWF-fil med ActionScript är att skapa ett SWC-bibliotek och länka det till SWF-huvudfilen.

Dessa begränsningar gäller inte när ett program körs i iOS-simulatorn (ipa-test-interpreter-simulator eller ipa-debug-interpreter-simulator) eller i tolkläget (ipa-test-interpreter eller ipa-debug-interpreter.)

Säkerhet för Loader

När du använder den här metoden bör du överväga Flash Player-säkerhetsmodellen, som behandlas i beskrivningen av klassen Loader.

Om du i Flash Player 10 eller senare använder en multipart-innehållstyp (till exempel ”multipart/form-data”) som innehåller en överföring (vilket indikeras av en ”filename”-parameter i ett ”content-disposition”-huvud inuti POST), gäller de säkerhetsregler som används för överföringar också för POST-åtgärden.

• POST-åtgärden måste utföras som ett svar på en användarinitierad åtgärd som exempelvis en musklickning eller en tangenttryckning.
• Om POST-åtgärden är för korsdomän (POST-målet ligger inte på samma server som SWF-filen som skickar POST-begäran), måste målservern ha en URL-policyfil som tillåter korsdomänåtkomst.

För en multipart-innehållstyp måste också syntaxen vara giltig (enligt standarden RFC2046). Om syntaxen verkar vara ogiltig, gäller samma regler för POST-åtgärden som för överföringar.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

Parametrar

Relaterade API-element

Läser in från binära data i ett ByteArray-objekt.

Metoden loadBytes() är asynkron. Du måste vänta på "init"-händelsen innan du kan komma åt egenskaperna för ett inläst objekt.

När du använder den här metoden bör du överväga Flash Player-säkerhetsmodellen, som behandlas i beskrivningen av klassen Loader.

Obs! (endast iOS) I AIR-program på iOS kan du bara läsa in en SWF-fil som innehåller ActionScript från programpaketet. Den här begränsningen omfattar all ActionScript-kod, som resurser med klassnamn som exporterats för ActionScript. Om du vill läsa in en SWF-fil måste den läsas in med samma programdomän som den överordnade SWF-filen.

I tidigare versioner än AIR 3.6 har anrop till den här metoden ingen effekt på iOS.

Parametrar

Relaterade API-element

Läser in en IFilePromise-instans.

Metoden loadFilePromise tar ett IFilePromise-objekt och läser in de binära data. Om dessa data är en progressiv ström, t.ex. en videoväntan på "init"-händelsen eller progress-händelser innan det inlästa objektets egenskaper hämtas. Annars väntar du på complete-händelsen för att försäkra dig om att alla data har lästs in.

När du använder den här metoden bör du överväga Flash Player-säkerhetsmodellen, som behandlas i beskrivningen av klassen Loader.

Parametrar

Relaterade API-element

Tar bort ett underordnat objekt från Loader-objektet som lästes in med metoden load(). property för det associerade LoaderInfo-objektet återställs till null. Det underordnade objektet förstörs inte nödvändigtvis eftersom andra objekt kan ha referenser till det. Det är emellertid inte längre underordnat Loader-objektet.

När du anropar metoden unload() anges Loader-objektets contentLoaderInfo-egenskap till null. Alla visuella resurser som lästes in med SWF-filen tas bort, även från minnet. ActionScript-klassdefinitioner i den inlästa SWF-filen finns kvar i minnet, och kod i samma programdomän som den inlästa SWF-filen kan komma åt instanser av dessa klasser och skapa nya instanser.

Obs! (endast iOS) I tidigare versioner än AIR 3.6 har den här metoden ingen effekt på iOS.

Bästa praxis är att du, innan du avladdar en underordnad SWF-fil, uttryckligen stänger eventuella streamer i den underordnade SWF-filens objekt, såsom LocalConnection-, NetConnection-, NetStream- och Sound-objekt. I annat fall kan ljudet i den underordnade SWF-filen fortsätta att spelas upp, trots att den underordnade SWF-filen har avladdats. För att stänga streams i den underordnade SWF-filen lägger man till en händelseavlyssnare till den underordnade som lyssnar efter händelse unload. När den överordnade anropar Loader.unload() skickas händelse unload till den underordnade. Den kod som följer visar hur detta kan göras:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Relaterade API-element

Försöker ta bort innehåll i underordnade SWF-filer och stoppar körningen av kommandon från inlästa SWF-filer. Den här metoden försöker ta bort SWF-filer som har lästs in med Loader.load() eller Loader.loadBytes() genom att ta bort referenser till EventDispatcher, NetConnection, Timer, Sound och Video-objekt i den underordnade SWF-filen. Det resulterar i följande för den underordnade SWF-filen och den underordnade SWF-filens visningslista:

• Ljud stoppas.
• Scenhändelseavlyssnare tas bort.
• Händelseavlyssnare för enterFrame, frameConstructed, exitFrame, activate och deactivate tas bort.
• Timerfunktioner stoppas.
• Kamera- och mikrofoninstanser frigörs.
• Filmklipp stoppas.

När du anropar metoden unloadAndStop() anges Loader-objektets contentLoaderInfo-egenskap till null. Alla visuella resurser som lästes in med SWF-filen tas bort, även från minnet. ActionScript-klassdefinitioner i den inlästa SWF-filen finns kvar i minnet, och kod i samma programdomän som den inlästa SWF-filen kan komma åt instanser av dessa klasser och skapa nya instanser.

Obs! (endast iOS) I tidigare versioner än AIR 3.6 har den här metoden ingen effekt på iOS.

Parametrar

Relaterade API-element

1. En url-egenskap skapas bestående av bildfilens plats och namn
2. I konstruktor LoaderExample skapas ett nytt Loader-objekt med namnet loader, som sedan skickas till configureListeners()-metoden, enligt beskrivningen i steg 3.
3. Konstruktorn skapar en ny instans av ett URLRequest-objekt, request, med en överförd url så att filnamnet och platsen blir kända.
4. request-objektet skickas till loader-objektets load()-metod, som läser in bilden till visningslistan.
5. En clickHandler-händelseavlyssnare registreras för händelse click på inläsaren. Efter en musklickning avladdas den inlästa bilden.
6. Metod configureListeners() lägger till sju händelseavlyssnare med följande metoder:
   • Metod completeHandler() körs när inläsningen av bilden är klar.
   • Metod httpStatusHandler() körs om bilden inte läses in lokalt, och bara om nätverksbegäran görs tillgänglig och kan identifiera den.
   • Metod initHandler() körs före metod completeHandler() och efter metod progressHandler(). Normalt är händelse init mer användbar vid inläsning av SWF-filer.
   • Metod ioErrorHandler() körs om bildfilen inte finns tillgänglig eller inte är åtkomlig.
   • Metod openHandler() körs när bildfilen öppnas för första gången.
   • Metod progressHandler() körs när bildfilen börjar läsas in och sedan på nytt när inläsningen av bilden är klar.
   • Metod unLoadHandler() körs när bilden avladdas med metod unload() när användaren klickar på bilden.

Tänk på följande krav:

• Detta exempel kräver att du placerar en fil med namnet Image.gif i samma katalog som den kompilerade SWF-filen. Använd en bild med ett område som passar in i huvud-SWF-filens mått.
• Det här exemplet använder alla händelser som finns tillgängliga för LoaderInfo-objektet, men de flesta situationer kräver bara en delmängd. Speciellt gäller att vid laddning av en bildfil så räcker händelse complete (och kanske händelse ioError) vid inläsning av en lokal bild.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}