| Paket | flash.display |
| Klass | public final class CapsStyle |
| Arv | CapsStyle  Object |
| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | AIR 1.0, Flash Player 9 |
caps-parametern för flash.display.Graphics.lineStyle()-metoden. Du kan specificera följande tre typer av versalstilar:
Relaterade API-element
Publika egenskaper
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaper
Publika metoder
Publika konstanter
| Konstant | Definieras med | ||
|---|---|---|---|
| NONE : String = "none" [statisk]
Används för att ange att inga ändar ska användas i parametern caps i metoden flash.display.Graphics.lineStyle(). | CapsStyle | ||
| ROUND : String = "round" [statisk]
Används för att ange runda ändar i parametern caps i metoden flash.display.Graphics.lineStyle(). | CapsStyle | ||
| SQUARE : String = "square" [statisk]
Används för att ange fyrkantiga ändar i parametern caps i metoden flash.display.Graphics.lineStyle(). | CapsStyle | ||
Konstantdetaljer
NONE | Konstant |
public static const NONE:String = "none"| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | AIR 1.0, Flash Player 9 |
Används för att ange inga ändar i parametern caps i metoden flash.display.Graphics.lineStyle().
ROUND | Konstant |
public static const ROUND:String = "round"| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | AIR 1.0, Flash Player 9 |
Används för att ange runda ändar i parametern caps i metoden flash.display.Graphics.lineStyle().
SQUARE | Konstant |
public static const SQUARE:String = "square"| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | AIR 1.0, Flash Player 9 |
Används för att ange fyrkantiga ändar i parametern caps i metoden flash.display.Graphics.lineStyle().
Exempel Så här använder du exemplet
CapsStyleExample.as
Det exempel som följer använder klass
CapsStyleExample för att rita tre parallella linjer, var och en med en egen linjeversalstil.
- De olika linjernas egenskaper bestäms på följande sätt:
- Linjelängden sätts till 80 pixlar.
- Ramfärgen sätts till orange.
- Ramstorleken sätts till 30 pixlar.
- Markeringsfärgen sätts till grå.
- Markeringsstorleken sätts till 0 pixlar.
- Alfavärdet sätts till 1, vilket gör den massiv.
- Pixelutjämningen sätts till false (linjer jämnas inte ut till hela pixlar).
- Linjeskalläget sätts till normalt, vilket skalar tjockleken.
- Kantändarnas gemensamma stil sätts till
MITER. - Foglängden sätts till 1, vilket anger att spetsen klipps av nära linjen.
- Klasskonstruktorn skapar tre lodräta linjer med början vid x = 0, y = 0 genom att anropa
drawLine()-metoden tre gånger med tre olika linjeversalstilar (ingen, rund och fyrkantig). Vart och ett av de tre anropen tilldrawLine()-metoden använder den versalstil och de egenskaper som förtecknats tidigare för att rita ett lodrätt streck och tillhörande linjemarkering. Anropen skapar först ett nyttchild-Shape-objekt och använder sedan Graphics-klassens metoder för att bestämma linjestilarna och rita linjerna och markeringarna. Varje instans avchildläggs till i visningslistan och ritas på scenen. - De anslutna linjesegmenten ritas om med
refreshLayout()-metoden vid y = 80 pixlar med början vid x = 80 pixlar, och med ett mellanrum på 25 pixlar mellan linjesegmenten.
package {
import flash.display.CapsStyle;
import flash.display.DisplayObject;
import flash.display.Graphics;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Shape;
import flash.display.Sprite;
public class CapsStyleExample extends Sprite {
private var lineLength:uint = 80;
private var borderColor:uint = 0xFFCC00;
private var borderSize:uint = 30;
private var highlightColor:uint = 0x666666;
private var highlightSize:uint = 0;
private var gutter:uint = 25;
private var borderAlpha:uint = 1;
private var borderPixelHinting:Boolean = false;
private var borderScaleMode:String = LineScaleMode.NORMAL;
private var borderJointStyle:String = JointStyle.MITER;
private var borderMiterLimit:uint = 1;
public function CapsStyleExample() {
drawLine(CapsStyle.NONE);
drawLine(CapsStyle.ROUND);
drawLine(CapsStyle.SQUARE);
refreshLayout();
}
private function drawLine(capsStyle:String):void {
var child:Shape = new Shape();
child.graphics.lineStyle(borderSize,
borderColor,
borderAlpha,
borderPixelHinting,
borderScaleMode,
capsStyle,
borderJointStyle,
borderMiterLimit);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(0, lineLength);
child.graphics.endFill();
child.graphics.moveTo(0, 0);
child.graphics.lineStyle(highlightSize, highlightColor);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(0, lineLength);
addChild(child);
}
private function refreshLayout():void {
var ln:uint = numChildren;
var child:DisplayObject;
var lastChild:DisplayObject = getChildAt(0);
lastChild.x = lineLength;
lastChild.y = lineLength;
for (var i:uint = 1; i < ln; i++) {
child = getChildAt(i);
child.x = gutter + lastChild.x + lastChild.width;
child.y = lineLength;
lastChild = child;
}
}
}
}
Tue Jun 12 2018, 01:40 PM Z