int  - AS3

Konstruktor, skapar ett nytt int-objekt. Du måste använda konstruktorn int när du använder int.toString() och int.valueOf(). Du använder ingen konstruktor när du använder egenskaperna i ett int-objekt. Konstruktorn new int används huvudsakligen som platshållare. Ett int-objekt är inte samma sak som int()-funktionen som konverterar en parameter till ett primitivt värde.

Relaterade API-element

	 var n1:int = new int(3.4);
	 var n2:int = new int(-10);
	 

Returnerar en strängbeteckning för talet med exponentiell notation. Strängen innehåller en siffra före decimalkommat och upp till 20 siffror efter decimalkommat enligt parametern fractionDigits.

Parametrar

var num:Number = 315003;
trace(num.toExponential(2)); // 3.15e+5

Returnerar en strängbeteckning för talet med fast punktnotation. Fast punktnotation betyder att strängen kommer att innehålla ett visst antal siffror efter decimalkommat, enligt parametern fractionDigits. Det giltiga intervallet för parametern fractionDigits är mellan 0 och 20. Om du anger ett värde utanför det här intervallet genereras ett undantag.

Parametrar

var num:Number = 7.31343;
trace(num.toFixed(3)); // 7.313

var num:Number = 4;
trace(num.toFixed(2)); // 4.00

Returnerar en strängbeteckning för talet med antingen exponentiell notation eller fast punktnotation. Strängen innehåller antal siffror som anges i parametern precision.

Parametrar

var num:Number = 31.570;
trace(num.toPrecision(3)); // 31.6

var num:Number = 4000;
trace(num.toPrecision(3)); // 4.00e+3

Returnerar strängbeteckningen för ett int-objekt.

Parametrar

	 var myint:int = new int(9);
	 trace(myint.toString(2)); // 1001
	 trace(myint.toString(8)); // 11
	 

I följande exempel ges ett hexadecimalt värde.

	 var r:int = new int(250);
	 var g:int = new int(128);
	 var b:int = new int(114);
	 var rgb:String = "0x"+ r.toString(16)+g.toString(16)+b.toString(16);
	 trace(rgb); // 0xfa8072
	 

Returnerar det angivna int-objektets primitiva värde.

	 var numSocks:int = new int(2);
	 trace(numSocks.valueOf()); // 2
	 

Det största 32-bitars heltal med tecken som kan betecknas, vilket är 2 147 483 647.

	trace("int.MIN_VALUE = "+int.MIN_VALUE);
	trace("int.MAX_VALUE = "+int.MAX_VALUE);
	

Koden visar följande värden:

	int.MIN_VALUE = -2147483648
	int.MAX_VALUE = 2147483647
	

Det minsta 32-bitars heltal med tecken som kan betecknas, vilket är -2 147 483 648.

     trace("int.MIN_VALUE = "+int.MIN_VALUE);
     trace("int.MAX_VALUE = "+int.MAX_VALUE);
     

Koden visar följande värden:

	int.MIN_VALUE = -2147483648
	int.MAX_VALUE = 2147483647
     

1. Två variabler av datatypen int, a och b deklareras i konstruktorn.
2. De två variablerna läggs ihop med metoden addIntegers().
3. En tredje variabel av datatypen int, c, tilldelas resultatet av parseInteger(), som kontrollerar giltigheten på de strängar som skickas till den för att säkerställa att heltalsvärdet ligger i det tillåtna intervallet för datatypen int. Ett helt som är lika med heltalsvärdet av strängen returneras, om heltalet är giltigt.
4. Variablerna a och c läggs ihop med addIntegers().

package {
    import flash.display.Sprite;

    public class IntExample extends Sprite {    
        public function IntExample() {
            var a:int = 512;
            var b:int = -128;
            
            trace(addIntegers(a, b)); // 384

            var c:int = parseInteger("32");
            
            trace(addIntegers(a, c)); // 544
        }
            
        public function addIntegers(a:int, b:int):int {
            return a + b;
        }
        
        public function parseInteger(str:String):int {
            var num:Number = parseInt(str);
            if(!isNaN(num) && num <= int.MAX_VALUE && num >= int.MIN_VALUE) {
                return int(num);
            }
            
            return 0;
        }
        
    }
}