LoaderInfo  - AS3

ActionScript-versionen av den inlästa SWF-filen. Språkversionen specificeras med listningarna i ActionScriptVersion-klassen, såsom ActionScriptVersion.ACTIONSCRIPT2 och ActionScriptVersion.ACTIONSCRIPT3.

Obs: Denna egenskap har alltid antingen värdet ActionScriptVersion.ACTIONSCRIPT2 eller värdet ActionScriptVersion.ACTIONSCRIPT3. Både ActionScript 1.0 och 2.0 rapporteras som ActionScriptVersion.ACTIONSCRIPT2 (version 2.0). Denna egenskap skiljer bara ActionScript 1.0 och 2.0 från ActionScript 3.0.

Relaterade API-element

När en extern SWF-fil läses in, sparas alla ActionScript 3.0-definitioner som finns i den inlästa klassen i egenskapen applicationDomain.

All kod i en SWF-fil är definierad för att finnas i en programdomän. Den aktuella programdomänen är där huvudprogrammet körs. Systemdomänen innehåller alla programdomäner, inklusive den aktuella domänen och alla klasser som används av Flash Player eller Adobe AIR.

Alla programdomäner utom systemdomänen har en överordnad domän. Den överordnade domänen för ditt huvudprograms applicationDomain är systemdomänen. Inlästa klasser definieras bara om de inte redan är definierade av sina överordnade klasser. Du kan inte åsidosätta en inläst klassdefinition med en nyare definition.

Exempel på användning av programdomäner finns i kapitlet ”Klientsystemmiljö” i Utvecklarhandbok för Adobe ActionScript 3.0.

Relaterade API-element

De byte som är associerade med ett LoaderInfo-objekt.

Antalet byte som är inlästa för mediet. Om det här antalet är lika med värdet för bytesTotal läses alla byte in.

Det totala antalet komprimerade byte i hela mediefilen.

Innan den första progress-händelsen skickas av detta LoaderInfo-objekts motsvarande Loader-objekt är bytesTotal 0. Efter den första progress-händelsen från Loader-objektet återspeglarbytesTotal det faktiska antalet byte som laddas ned.

Obs! (endast iOS) När du kör ett program i iOS är det returnerade värdet inte detsamma som på andra plattformar.

Relaterade API-element

Uttrycker tillförlitlighetsförhållandet mellan innehållet (underordnat) och Loader-objektet (överordnat): True om den underordnade tillåtit den överordnade åtkomst, annars false. Denna egenskap sätts till true om det underordnade objektet har anropat metoden allowDomain() för att ge den överordnade domänen tillstånd, eller om en URL-princip läses in vid den underordnade domänen, som ger den överordnade domänen tillstånd. Om underordnad och överordnad befinner sig i samma domän sätts denna egenskap till true.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

Ett objekt som kan ställas in med det inlästa innehållets kod för att exponera egenskaper och metoder som kan kommas åt av kod i Loader-objektets sandlåda. Denna sandbox bridge gör att innehåll från en icke-programdomän har begränsad tillgång till skript i programsandlådan och omvänt. Denna sandbox bridge fungerar som en brygga mellan sandlådorna och ger explicit interaktion mellan programsandlådor och icke-programsandlådor.

Relaterade API-element

Det inlästa objekt som är associerat med LoaderInfo-objektet.

Den inlästa filens MIME-typ. Värdet är null om inte tillräckligt av filen har lästs in för att typen ska kunna bestämmas. Giltiga värden visas i följande tabell:

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

Den nominella bildrutehastighet (i bildrutor per sekund) i den inlästa SWF-filen. Detta värde är för det mesta ett heltal, men det behöver inte vara det.

Detta värde kan skilja sig från den faktiska bildrutehastighet som används. Flash Player eller Adobe AIR använder bara en bildrutehastighet för alla inlästa SWF-filer vid ett och samma tillfälle, och den bildrutehastigheten bestäms av SWF-filens nominella bildrutehastighet. Dessutom kanske inte huvudbildrutehastigheten kan uppnås beroende på maskinvara, ljudsynkronisering och andra faktorer.

Det inlästa innehållets nominella höjd. Detta värde kan skilja sig från den faktiska höjd vid vilken innehållet visas eftersom det inlästa innehållet eller dess överordnade visningsobjekt kan skalförändras.

Anger om egenskapen LoaderInfo.url har trunkerats. När värdet isURLInaccessible är true är värdet LoaderInfo.url bara domänen för den slutliga webbadress varifrån innehållet lästes in. Egenskapen är till exempel trunkerad om innehållet läses in från http://www.adobe.com/assets/hello.swf och egenskapen LoaderInfo.url har värdet http://www.adobe.com. Värdet för isURLInaccessible är bara true om alla följande påståenden stämmer:

• En HTTP-omdirigering inträffade när innehållet lästes in.
• Den SWF-fil som anropar Loader.load() är från en annan domän än innehållets slutliga webbadress.
• Den SWF-fil som anropar Loader.load() har inte behörighet att komma åt innehållet. Behörighet för innehållet ges på samma sätt som för BitmapData.draw(): anropa Security.allowDomain() för att komma åt en SWF-fil (eller, för innehåll som inte finns i SWF-filer, skapa en principfil och använd egenskapen LoaderContext.checkPolicyFile).

Obs! Egenskapen isURLInaccessible har lagts till i Flash Player 10.1 och AIR 2.0, men den här egenskapen är tillgänglig för alla SWF-filer oavsett version när Flash-miljön stöder den. Om du använder vissa utvecklingsverktyg i s.k. strikt läge kan det därför orsaka ett kompileringsfel. Du kan undvika felet genom att använda den indirekta syntaxen myLoaderInfo["isURLInaccessible"] eller inaktivera strikt läge. Om du använder Flash Professional CS5 eller Flex SDK 4.1 kan du använda och kompilera detta API för körningsmiljöer som släpptes före Flash Player 10.1 och AIR 2.

För programinnehåll i AIR är värdet på den här egenskapen alltid false.

Relaterade API-element

Det Loader-objekt som är associerat med LoaderInfo-objektet. Om detta LoaderInfo-objekt är loaderInfo-egenskapen för instansen av SWF-filens huvudklass associeras inget Loader-objekt.

URL:en för SWF-filen som startade inläsningen av media beskrivs av det här LoaderInfo-objektet. För instansen av SWF-filens huvudklass är denna URL samma som SWF-filens egna URL.

Ett objekt som innehåller namnvärdespar som betecknar parametrarna som skickas till den inlästa SWF-filen.

Du kan använda en for-in-slinga för att hämta alla namnen och värdena från parameterobjektet.

De två parameterkällorna är: frågesträngen i huvud-SWF-filens URL och värdet på FlashVars-HTML-parametern (påverkar bara huvud-SWF-filen).

Parameteregenskapen ersätter tekniken med ActionScript 1.0 och 2.0 för att tillhandahålla SWF-filparametrar som huvudtidslinjeegenskaper.

Värdet på parameteregenskapen är null för Loader-objekt som innehåller SWF-filer som använder ActionScript 1.0 eller 2.0. Det är bara Loader-objekt som inte är null som innehåller SWF-filer som använder ActionScript 3.0.

Uttrycker tillförlitlighetsförhållandet mellan Loader-objektet (överordnat) och innehållet (underordnat): True om den överordnade tillåtit den underordnade åtkomst, annars false. Denna egenskap sätts till true om det överordnade objektet har anropat metoden allowDomain() för att ge den underordnade domänen tillstånd, eller om en URL-policyfil läses in vid den överordnade domänen, som ger den underordnade domänen tillstånd. Om underordnad och överordnad befinner sig i samma domän sätts denna egenskap till true.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

Ett objekt som kan ställas in med kod i Loader-objektets sandlåda för att exponera egenskaper och metoder som kan kommas åt av det inlästa innehållets kod. Denna sandbox bridge gör att innehåll från en icke-programdomän har begränsad tillgång till skript i programsandlådan och omvänt. Denna sandbox bridge fungerar som en brygga mellan sandlådorna och ger explicit interaktion mellan programsandlådor och icke-programsandlådor.

Relaterade API-element

Uttrycker domänförhållandena mellan inläsaren och innehållet: true om de har samma ursprungsdomän, annars false.

En EventDispatcher-instans som kan användas för att utväxla händelser över säkerhetsgränser. Även när Loader-objektet och det inlästa innehållet kommer från säkerhetsdomäner som inte litar på varandra, kan båda komma åt sharedEvents och skicka och ta emot händelser via detta objekt.

Filformatsversionen av den inlästa SWF-filen. Filformatet specificeras med listning i SWFVersion-klassen, såsom SWFVersion.FLASH7 och SWFVersion.FLASH9.

Relaterade API-element

Ett objekt som skickar en uncaughtError-händelse när ett ohanterat fel inträffar i koden i det här LoaderInfo-objektets SWF-fil. Ett ohanterat fel inträffar när ett fel genereras utanför try..catch-block eller när ett ErrorEvent-objekt skickas utan några registrerade avlyssnare.

Om det till exempel finns ett EventDispatcher-objekt som anropar sin händelsehanterare i ett try-block fångar catch-blocket inte felet om det genereras i händelsehanteraren. Alla fel som genereras efter detta kan fångas genom att LoaderInfo.uncaughtErrorEvents avlyssnas.

Den här egenskapen skapas när den SWF-fil som är associerad med det här LoaderInfo-objektet har lästs in helt. Tills dess är egenskapen uncaughtErrorEvents null. I ett projekt med endast ActionScript får du åtkomst till den här egenskapen under eller efter det att konstruktorfunktionen körts i huvudklassen för SWF-filen. För Flex-projekt är egenskapen uncaughtErrorEvents tillgänglig när händelsen applicationComplete har skickats.

Relaterade API-element

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

URL:en för de media som läses in.

Innan den första progress-händelsen skickas av detta LoaderInfo-objekts motsvarande Loader-objekt återspeglar värdet för url-egenskapen eventuellt bara den initiala URL som specificeras i anropet till Loader-objektets load()-metod. Efter den första progress-händelsen återspeglar url-egenskapen mediets slutgiltiga URL, efter lösning av eventuella omdirigeringar och relativa URL:er.

I vissa fall trunkeras värdet på egenskapen url. Läs mer om detta i avsnittet om egenskapen isURLInaccessible.

Relaterade API-element

Det inlästa innehållets nominella bredd. Detta värde kan skilja sig från den faktiska bredd vid vilken innehållet visas eftersom det inlästa innehållet eller dess överordnade visningsobjekt kan skalförändras.

Returnerar det LoaderInfo-objekt som är kopplat till en SWF-fil som är definierad som ett objekt.

Parametrar

Skickas när alla data är inlästa. Den skickas med andra ord när allt innehåll hämtats och inläsningen avslutats. Händelsen complete skickas alltid efter init-händelsen. init-händelsen skickas när objektet finns tillgängligt, även om innehållet fortfarande håller på att hämtas.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när en nätverksbegäran görs över HTTP, och HTTP-statuskoden kan kännas av.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när egenskaperna och metoderna för en inläst SWF-fil är tillgängliga och klara att användas. Innehållet kan däremot fortfarande hålla på att hämtas. Ett LoaderInfo-objekt skickar init-händelsen när följande förutsättningar föreligger:

• Samtliga egenskaper och metoder som hör till det inlästa objektet och till LoaderInfo-objektet är tillgängliga.
• Konstruktorerna för alla underordnade objekt har slutförts.
• All ActionScript-kod i den inlästa SWF-filens huvudtidslinjes första bildruta har körts.

En Event.INIT skickas till exempel när den första bildrutan i en film eller animering har lästs in. Filmen blir då tillgänglig och kan läggas till i visningslistan. Hela filmen kan dock ta längre tid att hämta. Event.COMPLETE skickas först när hela filmen lästs in.

init-händelsen föregår alltid complete-händelsen.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när ett indata- eller utdatafel uppkommer och får en inläsningsoperation att misslyckas.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när en inläsning initieras.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när data tas emot under nedladdningsförloppet.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas av ett LoaderInfo-objekt när ett inläst objekt tas bort med Loader-objektets unload()-metod, eller när en andra inläsning görs av samma Loader-objekt och det ursprungliga innehållet tas bort innan inläsningen börjar.

Den här händelsen har följande egenskaper:

Relaterade API-element

1. En egenskaps-url skapas bestående av bildfilens plats och namn
2. Klasskonstruktorn skapar ett inläsningsobjekt med namnet loader.
3. loader-objektet instansierar en händelseavlyssnare som säkerställer att bilden läses in korrekt.
4. Konstruktorn skapar en ny instans av ett URLRequest-objekt, request, med en överförd url så att filnamnet och platsen blir kända.
5. Sedan överförs request-objektet till load()-metoden för loader-objektet, som läser in bilden till visningslistan.

Viktigt: Detta exempel kräver att du lägger in en fil med namnet Image.gif i samma katalog som den kompilerade SWF-filen. Använd en bild med ett område som passar in i huvud-SWF-filens mått.

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}