ProgressEvent  - AS3

Antalet objekt eller byte som har lästs in när avlyssnaren behandlar händelsen.

Det totala antalet objekt eller byte som har lästs in när inläsningen är klar. Om progress-händelsen skickas till ett Socket-objekt kommer bytesTotal alltid att vara 0 om inte ett värde specificeras i bytesTotal-parametern i konstruktorn. Antal byte som skickas fram eller tillbaka är inte inställt och bestäms av programutvecklaren.

Skapar ett nytt Event-objekt som innehåller information om förloppshändelser. Event-objekt skickas som parametrar till händelseavlyssnare.

Skapar en kopia av ProgressEvent-objektet och ställer in värdet för alla egenskaper så att de matchar originalets egenskaper.

Returnerar en sträng som innehåller alla egenskaper i ProgressEvent-objektet. Strängen är i följande format:

[ProgressEvent type=värde bubbles=värde cancelable=värde bytesLoaded=värde bytesTotal=värde]

Definierar värdet för ett progress-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett socketData-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett standardErrorData-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett standardInputProgress-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet på type-egenskapen i ett standardOutputData-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

1. Egenskaperna downloadURL och fileName skapas, vilket anger plats och namn på filen som laddats ned.
2. I konstruktorn ProgressEventExample skapas ett nytt FileReference-objekt med namnet file som sedan skickas till configureListeners()-metoden.
3. Egenskaperna downloadURL och fileName skickas sedan till file.download(), vilket anger var filen ska laddas ned.
4. Metoden configureListeners() lägger till sju händelseavlyssnare och de mottagarmetoder som är kopplade till dem:
   1. cancel/cancelHandler() skickas om filnedladdningen avbryts.
   2. complete/complereHandler() skickas när filnedladdningen är avslutad.
   3. ioError/ioErrorHandler() skickas om den laddade ned filen inte går att komma åt.
   4. open/openHandler() skickas när nedladdningen har startat.
   5. progress/progressHandler() skickas när nedladdningsprocessen startas samt när den avslutas.
   6. securityError/securityErrorHandler skickas om den lokala säkerhetsinställningen för uppspelning inte matchar den laddade ned filens typ av dataåtkomst (lokal kontra nätverk); se anteckningarna nedan.
   7. select/selectHandler() skickas när nedladdningsobjektet har valts.

Obs!

• Du måste kompilera SWF-filen med Lokal uppspelningssäkerhet inställd på Använd bara nätverksfiler.
• Exemplet kräver en fil med namnet SomeFile.pdf.
• Även om det här exemplet använder alla händelser som är tillgängliga för FileReference-objektet kräver de flesta situationer bara en delmängd.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}