Socket  - AS3

Antalet databyte som kan läsas i indatabufferten.

Koden måste ha åtkomst till bytesAvailable för att kontrollera att det finns tillräckligt med data innan läsningen med någon av read-metoderna.

Anger antalet byte som är kvar i skrivbufferten.

Använd den här egenskapen tillsammans med OutputProgressEvent. En OutputProgressEvent genereras när data skrivs från skrivbufferten till nätverket. Du kan kontrollera bytesPending i händelsehanteraren för att se hur mycket data som fortfarande finns kvar i bufferten och väntar på att skrivas. När bytesPending returnerar 0 betyder det att alla data har överförts från skrivbufferten till nätverket, och det är säkert att till exempel ta bort händelsehanterare, rensa socketreferenser eller starta nästa överföring i en kö.

Relaterade API-element

Anger om det här Socket-objektet är anslutet. Ett anrop till den här egenskapen returnerar värdet true om socketen är ansluten, annars returneras false.

Anger byteordningen för data. Möjliga värden är konstanter från klassen flash.utils.Endian, Endian.BIG_ENDIAN eller Endian.LITTLE_ENDIAN.

Standardvärdet är Endian.BIG_ENDIAN.

Relaterade API-element

Den IP-adress som den här socketen är bunden till på den lokala datorn.

Relaterade API-element

Den port som den här socketen är bunden till på den lokala datorn.

Relaterade API-element

Styr vilken version av AMF som används när ett objekt skrivs eller läses.

Relaterade API-element

IP-adressen för den fjärrdator till vilken den här socketen är ansluten.

Du kan använda den här egenskapen för att fastställa IP-adressen för en klientsocket som skickas i en ServerSocketConnectEvent av ett ServerSocket-objekt. Om du vill kan du använda klassen DNSResolver för att konvertera en IP-adress till ett domännamn.

Relaterade API-element

Porten på den fjärrdator till vilken den här socketen är ansluten.

Du kan använda den här egenskapen för att fastställa portnumret för en klientsocket som skickas i en ServerSocketConnectEvent av ett ServerSocket-objekt.

Relaterade API-element

Indikerar antal millisekunder som du behöver vänta för en anslutning.

Om anslutningen inte lyckas inom specificerad tid, avbryts anslutningarna. Standardvärdet är 20 000 (tjugo sekunder).

Skapar ett nytt Socket-objekt. Om inga parametrar anges skapas en socket som är frånkopplad. Om parametrarna anges görs ett försök att ansluta till angiven värdenhet och port.

Obs! Du bör absolut använda konstruktorformen utan parametrar, sedan lägga till händelseavlyssnare och anropa metoden connect med parametrarna host och port. Denna sekvens garanterar att alla händelseavlyssnare fungerar ordentligt.

Stänger socketen. Du kan inte göra någon läsning eller skrivning av data efter att metoden close() har anropats.

Händelsen close skickas endast om servern stänger anslutningen; den skickas inte när du anropar metoden close().

Du kan återanvända Socket-objektet genom att anropa metoden connect() igen.

Ansluter socketen till den angivna värden och porten.

Om anslutningen misslyckas omedelbart skickas antingen en händelse eller så uppstår ett undantag: om det finns en angiven värdenhet skickas en felhändelse och om det inte finns någon angiven värdenhet uppstår ett undantag. I annat fall rapporteras anslutningsstatus av en händelse. Om socketen redan är ansluten stängs den befintliga anslutningen först.

Parametrar

Tömmer alla ackumulerade data i socketens utdatabuffert.

På vissa operativsystem anropas flush() automatiskt mellan körningsbildrutor, men på andra operativsystem (t.ex. Windows) skickas data aldrig om inte flush() anropas uttryckligen. Om du vill vara säker på att ditt program fungerar korrekt på alla operativsystem bör metoden flush() anropas efter att varje meddelande (eller relaterade data) har skrivits till socketen.

Läser ett booleskt värde från socketen. Efter läsning av enkelbyte returneras true om databyten inte är noll, i annat fall false.

Läser en byte med tecken från socketen.

Läser så många databyte som anges av parametern length från socketen. Databyten läses till angiven bytearray, med början vid angiven position i offset.

Parametrar

Läser ett IEEE 754-flyttal med dubbel precision från socketen.

Läser ett IEEE 754-flyttal med enkel precision från socketen.

Läser ett 32-bitars heltal med tecken från socketen.

Läser en flerbytesträng från byteflödet med den angivna teckenuppsättningen.

Parametrar

Läser ett objekt från socketen, kodat i serialiserat AMF-format.

Relaterade API-element

Läser ett 16-bitars heltal med tecken från socketen.

Läser en byte utan tecken från socketen.

Läser ett 32-bitars heltal utan tecken från socketen.

Läser ett 16-bitars heltal utan tecken från socketen.

Läser en UTF-8-sträng från socketen. Strängen antas ha ett prefix med ett osignerat kort heltal som anger längden i byte.

Läser antalet UTF-8-databyte som anges av parametern length från socketen och returnerar sedan en sträng.

Parametrar

Skriver ett booleskt värde till socketen. Med den här metoden skrivs en enkelbyte, med antingen värdet 1 (true) eller 0 (false).

Parametrar

Relaterade API-element

Skriver en byte till socketen.

Parametrar

Relaterade API-element

Skriver en sekvens med byte från den angivna bytearrayen. Skrivningen börjar vid angiven position i offset.

Om du utelämnar parametern length gör standardlängden 0 att hela bufferten skrivs med början vid offset.

Hela bufferten skrivs också om du utelämnar parametern offset.

Parametrar

Relaterade API-element

Skriver ett IEEE 754-flyttal med dubbel precision till socketen.

Parametrar

Relaterade API-element

Skriver ett IEEE 754-flyttal med enkel precision till socketen.

Parametrar

Relaterade API-element

Skriver ett 32-bitars heltal med tecken till socketen.

Parametrar

Relaterade API-element

Skriver en flerbytesträng från byteflödet med den angivna teckenuppsättningen.

Parametrar

Relaterade API-element

Skriver ett objekt till socketen i serialiserat AMF-format.

Parametrar

Relaterade API-element

Skriver ett 16-bitars heltal till socketen. Följande byte skrivs:

(v >> 8) & 0xff v & 0xff

De första 16 bitarna i parametern används, de övre 16 bitarna ignoreras.

Parametrar

Relaterade API-element

Skriver ett 32-bitars heltal utan tecken till socketen.

Parametrar

Relaterade API-element

Skriver följande data till socketen: ett 16-bitars heltal utan tecken, som anger den angivna UTF-8-strängen i byte, följt av själva strängen.

Innan strängen skrivs beräknas antalet databyte som behövs för att representera alla tecken i strängen.

Parametrar

Relaterade API-element

Skriver en UTF-8-sträng till socketen.

Parametrar

Relaterade API-element

Skickas när servern stänger socketanslutningen.

Händelsen close skickas endast om servern stänger anslutningen; den skickas inte när du anropar metoden Socket.close().

Den här händelsen har följande egenskaper:

Skickas när en nätverksanslutning har upprättats.

Den här händelsen har följande egenskaper:

Skickas om ett in-/utdatafel orsakar en misslyckad åtgärd för att skicka eller läsa in data.

Den här händelsen har följande egenskaper:

Skickas när en socket flyttar data för dess skrivbuffert till nätverkets transportlager.

Skickas om ett anrop till Socket.connect() försöker ansluta till en server som inte tillåts av anroparens säkerhetssandlåda, eller till en port lägre än 1024, och det inte finns någon socketprincipfil som kan tillåta en sådan anslutning.

Obs! I ett AIR-program tillåts innehåll som körs i programmets säkerhetssandlåda att ansluta till alla servrar och portnummer utan någon socketprincipfil.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när en socket har tagit emot data.

Data som tas emot av socketen stannar kvar i socketen tills de läses. Du behöver inte läsa alla tillgängliga data under hanteringen av den här händelsen.

Händelser av typen socketData används inte med egenskapen ProgressEvent.bytesTotal.

Den här händelsen har följande egenskaper:

1. Konstruktorn skapar en CustomSocket-instans med namnet socket och skickar värdnamnet localhost och port 80 som argument. Eftersom CustomSocket utökar Socket, innebär ett anrop till super() ett anrop till Socket-konstruktorn.
2. Exempelkoden anropar sedan metoden configureListeners() som lägger till avlyssnare för sockethändelser.
3. Slutligen anropas socket connect()-metoden med localhost som värdnamn och 80 som portnummer.

Obs! För att kunna köra exemplet behöver du en server som körs på samma domän som SWF-filen finns (localhost i exemplet) och avlyssning på port 80.

package {
    import flash.display.Sprite;

    public class SocketExample extends Sprite {
        private var socket:CustomSocket;
        
        public function SocketExample() {
            socket = new CustomSocket("localhost", 80);
        }
    }
}

import flash.errors.*;
import flash.events.*;
import flash.net.Socket;

class CustomSocket extends Socket {
    private var response:String;

    public function CustomSocket(host:String = null, port:uint = 0) {
        super();
        configureListeners();
        if (host && port)  {
            super.connect(host, port);
        }
    }

    private function configureListeners():void {
        addEventListener(Event.CLOSE, closeHandler);
        addEventListener(Event.CONNECT, connectHandler);
        addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);
    }

    private function writeln(str:String):void {
        str += "\n";
        try {
            writeUTFBytes(str);
        }
        catch(e:IOError) {
            trace(e);
        }
    }

    private function sendRequest():void {
        trace("sendRequest");
        response = "";
        writeln("GET /");
        flush();
    }

    private function readResponse():void {
        var str:String = readUTFBytes(bytesAvailable);
        response += str;
    }

    private function closeHandler(event:Event):void {
        trace("closeHandler: " + event);
        trace(response.toString());
    }

    private function connectHandler(event:Event):void {
        trace("connectHandler: " + event);
        sendRequest();
    }

    private function ioErrorHandler(event:IOErrorEvent):void {
        trace("ioErrorHandler: " + event);
    }

    private function securityErrorHandler(event:SecurityErrorEvent):void {
        trace("securityErrorHandler: " + event);
    }

    private function socketDataHandler(event:ProgressEvent):void {
        trace("socketDataHandler: " + event);
        readResponse();
    }
}