FileReference  - AS3

Det datum filen skapades på den lokala disken. Om objektet inte har fyllts i returneras null vid anropet som hämtar egenskapens värde.

Obs! Om ett operativsystem saknar egenskapen creationDate är CreationDate lika med lastModifiedDate.

Relaterade API-element

Macintosh-skapartypen för filen, som endast används i Mac OS-versioner tidigare än Mac OS X. I Windows och Linux är den här egenskapen null. Om FileReference-objektets egenskaper inte har fyllts i returneras null vid anropet som hämtar egenskapens värde.

Relaterade API-element

ByteArray-objektet som representerar data från den inlästa filen efter ett lyckat anrop till metoden load().

Relaterade API-element

Filnamnstillägget.

Ett filnamnstillägg är den del av namnet som följer efter den sista punkten ("."). (Själva punkten är inte en del av tillägget.) Om det inte finns någon punkt i filnamnet är tillägget null.

Obs! Du ska använda egenskapen extension för att bestämma filens typ. Använd inte egenskaperna creator eller type. Egenskaperna creator och type bör inte användas längre. De används i äldre versioner av Mac OS.

Hämtar det datum filen på den lokala disken ändrades senast. Om FileReference-objektets egenskaper inte har fyllts i returneras null vid anropet som hämtar egenskapens värde.

Relaterade API-element

Filens namn på den lokala disken. Om FileReference-objektet inte har fyllts i (av ett giltigt anrop till FileReference.download() eller FileReference.browse()) genererar Flash Player ett fel när du försöker hämta värdet för den här egenskapen.

Alla egenskaper i ett FileReference-objekt fylls i med anrop till metoden browse(). Till skillnad mot övriga FileReference-egenskaper så är egenskapen name ifylld när händelsen select skickas vid anrop av metoden download().

Relaterade API-element

Avgör om programmet har beviljats åtkomst till filsystemet.

Relaterade API-element

Filens storlek på den lokala disken, i byte.

Obs! I den första versionen av ActionScript 3.0 definierades egenskapen size som ett uint-objekt, med stöd för filer med en storlek på upp till cirka 4 GB. Den har nu implementerats som ett Number-objekt med stöd för större filer.

Relaterade API-element

Filtypen.

I Windows och Linux är den här egenskapen filtillägget. I Macintosh är den här egenskapen filtypen med fyra tecken, som bara används i tidigare Mac OS-versioner än Mac OS X. Om FileReference-objektet inte har fyllts i returnerar anrop efter den här egenskapens värde null.

I Windows, Linux och Mac OS X är detta filtillägg den del av egenskapen name som följer efter den sista förekomsten av tecknet (.) tecknet – identifierar filtypen.

Relaterade API-element

Skapar ett nytt FileReference-objekt. FileReference representerar en fil på användarens lokala hårddisk när dess egenskaper har fyllts i.

Relaterade API-element

Visar en dialogruta för filbläddring där användaren kan markera en fil att överföra. Dialogrutan tillhör användarens operativsystem. Användaren kan välja en fil på den lokala datorn eller från andra system, till exempel via en UNC-sökväg i Windows.

Obs! Klassen File, som finns i Adobe AIR, innehåller metoder för att komma åt fler särskilda systemdialogrutor för filval. De här metoderna är File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() och File.browseForSave().

När du anropar den här metoden och användaren väljer en fil fylls egenskaperna i FileReference-objektet i med den valda filens egenskaper. Varje gång metoden FileReference.browse() anropas återställs FileReference-objektets egenskaper till den fil som valts av användaren i dialogrutan. Endast en browse()- eller download()-session kan utföras i taget (eftersom endast en dialogruta kan anropas i taget).

Med parametern typeFilter kan du avgöra vilka filer som visas i dialogrutan.

I Flash Player 10 och Flash Player 9 uppdatering 5 kan du endast anropa den här metoden som ett svar på en användarhändelse (i till exempel en händelsehanterare för en musklickning eller en tangentbordstryckningshändelse). Annars resulterar ett anrop till den här metoden i att ett Error-undantag genereras.

Tänk på att de nya funktionerna i Flash Player innebär att bara en av följande åtgärder kan vara aktiv åt gången när du publicerar till Flash Player 10: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Annars genererar Flash Player ett körningsfel (kod 2174). Använd FileReference.cancel() för att avbryta en pågående åtgärd. Den här begränsningen gäller endast Flash Player 10. Tidigare versioner av Flash Player påverkas inte av den här begränsningen av flera samtidiga åtgärder.

I Adobe AIR visas inte alltid dialogrutan för filblädddring framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Parametrar

Relaterade API-element

Avbryter en pågående överföring eller nedladdning för FileReference-objektet. Vid anrop av den här metoden skickas inte händelsen cancel. Händelsen skickas endast om användaren avbryter åtgärden genom att stänga dialogrutan för filöverföring eller -nedladdning.

Öppnar en dialogruta som användaren kan använda för att ladda ned en fil från en fjärrserver. Det finns ingen storleksbegränsning för filer som du överför eller laddar ned i Flash Player, men spelaren stöder officiellt nedladdning och överföring upp till 100 MB.

Med metoden download() öppnas först en dialogruta som tillhör operativsystemet. Där uppmanas användaren att ange ett filnamn och välja en plats att spara filen på på den lokala datorn. När användaren väljer en plats och bekräftar nedladdningen (till exempel genom att klicka på Spara) startar nedladdningen från fjärrservern. Avlyssnare tar emot händelser som visar nedladdningens förlopp och om den slutförs eller misslyckas. Status för dialogrutan och nedladdningsåtgärden efter anropet till download() kontrolleras genom att koden lyssnar efter händelser som t.ex. cancel, open, progress och complete.

Funktionerna FileReference.upload() och FileReference.download() är inte blockerande Funktionerna returnerar efter att de har anropats, innan filöverföringen är slutförd. Dessutom avbryts överföringar och nedladdningar som inte har slutförts för objektet om FileReference-objektet kommer utanför omfånget. Se därför till att FileReference-objektet är inom omfånget under tiden som överföringen eller nedladdningen förväntas ta.

När filen har laddats ned fylls egenskaperna i FileReference-objektet i med egenskaperna för den lokala filen. Händelsen complete skickas när nedladdningen är slutförd.

Endast en browse()- eller download()-session kan utföras i taget (eftersom endast en dialogruta kan anropas i taget).

Den här metoden stöder nedladdning av alla filtyper med antingen HTTP eller HTTPS.

Du kan inte ansluta till vanligtvis reserverade portar. Du hittar en fullständig lista över spärrade portar i avsnittet ”Begränsa nätverks-API:er” i Utvecklarhandbok för Adobe ActionScript 3.0.

Obs: Om servern kräver användarverifiering kan bara SWF-filer som körs i en webbläsare (det vill säga med webbläsarplugin eller ActiveX-kontroll) öppna en dialogruta där användaren anger användarnamn och lösenord för verifiering, och bara vid nedladdning. För överföringar med pluginen eller med ActiveX-kontrollen och för överföringar och nedladdningar med fristående eller extern spelare misslyckas filöverföringen.

Tänk på Flash Players säkerhetsmodell när du använder den här metoden:

• Inläsning är inte tillåtet om den anropande SWF-filen körs i en otillförlitlig lokal sandlåda.
• Standardinställningen är att inte tillåta åtkomst mellan sandlådor. På en webbplats kan åtkomst till en resurs aktiveras genom att en URL-principfil läggs till.
• Du kan förhindra att metoden används av en SWF-fil genom att ställa in parametern allowNetworking i object- och embed-taggarna på den HTML-sida där SWF-innehållet finns.
• I Flash Player 10 och Flash Player 9 uppdatering 5 kan du endast anropa den här metoden som ett svar på en användarhändelse (i till exempel en händelsehanterare för en musklickning eller en tangentbordstryckningshändelse). Annars resulterar ett anrop till den här metoden i att ett Error-undantag genereras.

I Adobe AIR begränsas emellertid inte innehåll i säkerhetssandlådan application (innehåll som installeras med AIR-programmet) av de här säkerhetsbegränsningarna.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

När du hämtar en fil med den här metoden flaggas den som hämtad på operativsystem som flaggar hämtade filer:

• Windows XP Service Pack 2 och senare och på Windows Vista
• Mac OS 10.5 och senare

Vissa operativsystem, som Linux, flaggar inte hämtade filer.

Tänk på att de nya funktionerna i Flash Player innebär att bara en av följande åtgärder kan vara aktiv åt gången när du publicerar till Flash Player 10: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Annars genererar Flash Player ett körningsfel (kod 2174). Använd FileReference.cancel() för att avbryta en pågående åtgärd. Den här begränsningen gäller endast Flash Player 10. Tidigare versioner av Flash Player påverkas inte av den här begränsningen av flera samtidiga åtgärder.

I Adobe AIR visas inte alltid dialogrutan för hämtning framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Börjar ladda ned en lokal som har markerats av en användare. Det finns ingen storleksbegränsning för filer som du överför, läser in eller sparar i Flash Player, men programmet stöder officiellt storlekar upp till 100 MB. När det gäller innehåll som körs i Flash Player måste du anropa metoden FileReference.browse() eller FileReferenceList.browse() innan du kan anropa metoden load(). Innehåll som körs i AIR i programsandlådan kan emellertid anropa metoden load() för ett File-objekt utan att först anropa metoden browse(). (Klassen File i AIR utökar klassen FileReference.)

Avlyssnare tar emot händelser som visar överföringens förlopp och om den slutförs eller misslyckas. Du kan använda FilreReferenceList-objekt för att låta användaren välja flera filer att läsa in, men du måste läsa in en fil i taget. Du läser in en fil i taget genom att iterera genom FileReferenceList.fileList-arrayen med FileReference-objekt.

Adobe AIR innehåller även klassen FileStream, som har fler alternativ för att läsa filer.

Funktionerna FileReference.upload(), FileReference.download(), FileReference.load() och FileReference.save() är inte blockerande. Funktionerna returnerar efter att de har anropats, innan filöverföringen är slutförd. Dessutom avbryts transaktioner som inte har slutförts för objektet om FileReference-objektet kommer utanför omfånget. Se därför till att FileReference-objektet är inom omfånget den tid som överföringen, nedladdningen, hämtningen eller sparandet förväntas ta.

Om filen läses in som den ska lagras innehållet som en bytearray i data-egenskapen för FileReference-objektet.

Följande säkerhetsaspekter gäller:

• Inläsning är inte tillåtet om den anropande SWF-filen körs i en otillförlitlig lokal sandlåda.
• Standardinställningen är att inte tillåta åtkomst mellan sandlådor. På en webbplats kan åtkomst till en resurs aktiveras genom att en korsdomänprincipfil läggs till.
• Du kan förhindra att metoden används av en fil genom att ange parametern allowNetworking i object- och embed-taggarna på den HTML-sida där SWF-innehållet finns.

Dessa aspekter gäller emellertid inte för AIR-innehåll i programsandlådan.

När du publicerar till Flash Player 10 eller AIR 1.5 kan bara en av följande åtgärder vara aktiv åt gången: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Annars genererar programmet ett körningsfel (kod 2174). Använd FileReference.cancel() för att avbryta en pågående åtgärd. Den här begränsningen gäller endast Flash Player 10 och AIR 1.5. Tidigare versioner av Flash Player eller AIR påverkas inte av den här begränsningen av flera samtidiga åtgärder.

I Adobe AIR visas inte alltid dialogrutan för filblädddring framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Relaterade API-element

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Begär åtkomst till filsystemet.

Öppnar en dialogruta som kan användas för att spara en fil på en lokal dator. Det finns ingen storleksbegränsning för filer som du överför eller hämtar i Flash Player, men spelaren stöder officiellt storlekar upp till 100 MB.

Med metoden save() öppnas först en dialogruta som tillhör operativsystemet. Där uppmanas användaren att ange ett filnamn och välja var filen ska sparas på den lokala datorn. När användaren väljer en plats och bekräftar sparandet (t.ex. genom att klicka på Spara) startar sparandet. Avlyssnare tar emot händelser som visar sparandets förlopp och huruvida det slutförs eller misslyckas. För att kontrollera statusen för dialogrutan och spara-åtgärden efter anropet till save() måste koden lyssna efter händelser som cancel, open, progress och complete.

Adobe AIR innehåller även klassen FileStream, som har fler alternativ för att spara filer lokalt.

Funktionerna FileReference.upload(), FileReference.download(), FileReference.load() och FileReference.save() är inte blockerande. Funktionerna returnerar efter att de har anropats, innan filöverföringen är slutförd. Dessutom avbryts transaktioner som inte har slutförts för objektet om FileReference-objektet kommer utanför omfånget. Se därför till att FileReference-objektet är inom omfånget den tid som överföringen, nedladdningen, hämtningen eller sparandet förväntas ta.

När filen har sparats fylls egenskaperna i FileReference-objektet i med egenskaperna för den lokala filen. Händelsen complete skickas när sparandet är slutfört.

Endast en browse()- eller save()-session i taget kan utföras (eftersom endast en dialogruta i taget kan anropas).

I Flash Player kan du bara anropa den här metoden som ett svar på en användarhändelse (i till exempel en händelsehanterare för en musklickning eller en tangentbordstryckningshändelse). Annars resulterar ett anrop till den här metoden i att ett Error-undantag genereras. Den här begränsningen gäller inte för AIR-innehåll i programsandlådan.

I Adobe AIR visas inte alltid dialogrutan för att spara framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Parametrar

Relaterade API-element

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Startar överföringen av filen till en fjärrserver. Det finns ingen storleksbegränsning för filer du överför eller laddar ned i Flash Player, men spelaren stöder officiellt nedladdning och överföring upp till 100 MB.Innan du anropar den här metoden måste du anropa metoden FileReference.browse() eller FileReferenceList.browse().

För File-klassen i Adobe AIR, som utökar klassen FileReference, kan du använda metoden upload() för att överföra filer. För klassen FileReference (används i Flash Player) måste användaren först välja en fil.

Avlyssnare tar emot händelser som visar överföringens förlopp och om den slutförs eller misslyckas. Trots att du kan använda objektet FileReferenceList så att användare kan välja flera filer för överföring måste du överföra filer en i taget. Detta gör du genom att iterera igenom arrayen FileReferenceList.fileList med FileReference-objekt.

Funktionerna FileReference.upload() och FileReference.download() är inte blockerande Funktionerna returnerar efter att de har anropats, innan filöverföringen är slutförd. Dessutom avbryts överföringar och nedladdningar som inte har slutförts för objektet om FileReference-objektet kommer utanför omfånget. Se därför till att FileReference-objektet är inom omfånget under tiden som överföringen eller nedladdningen förväntas ta.

Filen överförs till den URL som anges i parametern url. URL:en måste vara ett serverskript som är konfigurerat för att ta emot överföringar. I Flash Player överförs filer med HTTP-metoden POST. I serverskriptet som hanterar överföringen bör en POST-begäran ingå med följande element:

• Content-Type i multipart/form-data
• Content-Disposition med attributet name angivet med "Filedata" som standardvärde och attributet filename angivet med namnet på originalfilen
• filens binära innehåll.

Du kan inte ansluta till vanligtvis reserverade portar. Du hittar en fullständig lista över spärrade portar i avsnittet ”Begränsa nätverks-API:er” i Utvecklarhandbok för Adobe ActionScript 3.0.

Ett exempel med begäran POST finns i beskrivningen för parametern uploadDataFieldName. Du kan skicka parametrarna POST eller GET till servern med metoden upload(). Se beskrivningen för parametern request.

Om parametern testUpload är true och filen som ska överföras är större än ca 10 kB skickas (med Flash Player i Windows) först en testöverföring med POST utan innehåll för att kontrollera att överföringen fungerar. Därefter skickas en andra åtgärd med POST som innehåller den faktiska filen. Vid filer som är mindre än 10 kB utförs POST-överföringen med den faktiska filen på en gång, utan något testförsök. Med Flash Player på Macintosh görs inga testöverföringar med POST.

Obs: Om servern kräver användarverifiering kan bara SWF-filer som körs i en webbläsare (det vill säga med webbläsarplugin eller ActiveX-kontroll) öppna en dialogruta där användaren anger användarnamn och lösenord för verifiering, och bara vid nedladdning. För överföringar med pluginen eller med ActiveX-kontrollen och för överföringar och nedladdningar med fristående eller extern spelare misslyckas filöverföringen.

Tänk på Flash Players säkerhetsmodell när du använder den här metoden:

• Inläsning är inte tillåtet om den anropande SWF-filen körs i en otillförlitlig lokal sandlåda.
• Standardinställningen är att inte tillåta åtkomst mellan sandlådor. På en webbplats kan åtkomst till en resurs aktiveras genom att en URL-principfil läggs till.
• Du kan förhindra att metoden används av en SWF-fil genom att ställa in parametern allowNetworking i object- och embed-taggarna på den HTML-sida där SWF-innehållet finns.

I Adobe AIR begränsas emellertid inte innehåll i säkerhetssandlådan application (innehåll som installeras med AIR-programmet) av de här säkerhetsbegränsningarna.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

Tänk på att de nya funktionerna i Flash Player innebär att bara en av följande åtgärder kan vara aktiv åt gången när du publicerar till Flash Player 10: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Annars genererar Flash Player ett körningsfel (kod 2174). Använd FileReference.cancel() för att avbryta en pågående åtgärd. Den här begränsningen gäller endast Flash Player 10. Tidigare versioner av Flash Player påverkas inte av den här begränsningen av flera samtidiga åtgärder.

Parametrar

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Relaterade API-element

Initiera överföring av en fil till en URL utan kodning. Medan metoden upload() kodar filen i ett formulärdataomslag, skickar metoden uploadUnencoded() filinnehållet som det är i HTTP-begäranstexten. Använd metoden uploadUnencoded() om de data du vill skicka redan har kodats i ett format som den mottagande servern kan hantera. Oftast ska du använda metoden uploadeUnencoded() med metoden HTTP/WebDAV PUT.

Parametrar

Relaterade API-element

Skickas när användaren för över eller laddar ned en fil genom dialogrutan för filbläddring. Flash Player skickar inte den här händelsen om användaren avbryter en överföring eller nedladdning på andra sätt (stänger webbläsaren eller avslutar det aktuella programmet).

Den här händelsen har följande egenskaper:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Skickas när nedladdningen är slutförd eller när överföringen genererar HTTP-statuskoden 200. Vid filnedladdning skickas händelsen när Flash Player eller Adobe AIR har laddat ned hela filen till disken. Vid filöverföring skickas händelsen när Flash Player eller Adobe AIR har tagit emot HTTP-statuskod 200 från servern som tar emot överföringen.

Den här händelsen har följande egenskaper:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Relaterade API-element

Skickas om ett anrop till metoden upload() eller uploadUnencoded() försöker få åtkomst till data via HTTP, och Adobe AIR upptäcker och returnerar statuskoden för begäran.

HTTPStatusEvent.HTTP_RESPONSE_STATUS-konstanten definierar värdet på type-egenskapen i ett httpResponseStatus-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas om en överföring misslyckas och det finns en HTTP-statuskod som beskriver felet. Händelsen httpStatus skickas, följt av händelsen ioError.

Händelsen httpStatus skickas endast vid överföringsfel. Den här händelsen kan inte användas vid nedladdningsfel för innehåll som körs i Flash Player. Om en nedladdning misslyckas på grund av ett HTTP-fel rapporteras felet som ett I/O-fel.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas om överföringen eller nedladdningen misslyckas. En filöverföring kan misslyckas på grund av någon av följande orsaker:

• Ett in-/utdatafel inträffar när spelaren läser från, skriver i eller sänder filen.
• SWF-filen försöker överföra en fil till en server som kräver verifiering (t.ex. användarnamn och lösenord). Under överföring kan användaren inte ange lösenord i Flash Player eller Adobe AIR. Om en SWF-fil försöker överföra en fil till en server som kräver verifiering misslyckas överföringen.
• SWF-filen försöker ladda ned en fil från en server som kräver verifiering i den fristående eller externa spelaren. Under nedladdning kan användaren inte ange lösenord i den fristående eller externa spelaren. Om en SWF-fil i dessa spelare försöker ladda ned en fil från en server som kräver verifiering misslyckas nedladdningen. Filnedladdning kan bara göras i ActiveX-kontrollen, pluginspelare i webbläsare och Adobe AIR-körningen.
• Värdet som skickas till parametern url i metoden upload() innehåller ett ogiltigt protokoll. Protokollet måste vara HTTP eller HTTPS.

Viktigt! Endast med program som körs i en webbläsare – det vill säga med webbläsar-pluginprogrammet eller ActiveX-kontrollen – samt med innehåll som körs i Adobe AIR, kan en dialogruta öppnas där användaren uppmanas att ange användarnamn och lösenord för autentisering, och då endast för nedladdning. Filöverföringen misslyckas vid överföringar med plugin- eller ActiveX-kontrollversionen av Flash Player och vid överföringar eller nedladdningar med antingen fristående eller extern spelare.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när en överföring eller nedladdning startar.

Den här händelsen har följande egenskaper:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Relaterade API-element

Skickas när programmet begär åtkomst till filsystemet. Kontrollera värdet för egenskapen status för att avgöra om behörighet beviljades eller nekades

Relaterade API-element

Skickas periodiskt under filöverföring eller filnedladdning. Händelsen progress skickas medan Flash Player överför databyte till en server och aktiveras periodiskt under överföringen även om överföringen slutligen misslyckas. För att avgöra om och när filöverföringen faktiskt är lyckad och slutförd avlyssnas händelsen complete.

I vissa fall tas inte händelserna progress emot. När t.ex. filen som överförs är mycket liten eller nedladdningen eller överföringen genomförs mycket snabbt kanske händelsen progress inte skickas.

Filöverföringens förlopp kan inte avgöras på Macintosh-plattformar tidigare än OS X 10.3. Händelsen progress anropas vid överföringen, men värdet för egenskapen bytesLoaded i progress-händelsen är -1, vilket anger att förloppet inte kan avgöras.

Den här händelsen har följande egenskaper:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Relaterade API-element

Skickas när ett anrop till metoden FileReference.upload() eller FileReference.download() försöker överföra en fil till en server eller ladda ned en fil från en server som finns utanför anroparens säkerhetssandlåda. Värdet för textegenskapen som beskriver det specifika felet som uppstod är vanligtvis "securitySandboxError". Den anropande SWF-filen kan ha försökt använda en SWF-fil som är utanför dess domän utan att ha behörighet att göra det. Du kan försöka åtgärda felet med en URL-principfil.

I Adobe AIR gäller de här säkerhetsbegränsningarna inte innehåll i säkerhetssandlådan application.

I Adobe AIR gäller de här säkerhetsbegränsningarna inte innehåll i säkerhetssandlådan application.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när användaren markerar en fil för överföring eller nedladdning från dialogrutan för filbläddring. (Den här dialogrutan öppnas vid anrop av metoden FileReference.browse(), FileReferenceList.browse() eller FileReference.download().) När användaren väljer en fil och bekräftar operationen (till exempel genom att klicka på OK) fylls egenskaperna för FileReference-objektet i.

select-händelsen fungerar på något olika sätt beroende på av vilken metod den aktiveras för innehåll som körs i Flash Player eller utanför säkerhetssandlådan application i Adobe AIR-körningen. Om select-händelsen skickas efter ett anrop till browse() kan alla egenskaperna för FileReference-objektet läsas av Flash Player eller AIR-programmet, eftersom filen som användaren har valt finns i det lokala filsystemet. Om select-händelsen inträffar efter ett anrop till download() kan endast egenskapen name läsas av Flash Player eller AIR-programmet, eftersom filen ännu inte har laddats ned till det lokala filsystemet när select-händelsen skickas. När filen har laddats ned och complete-händelsen har skickats kan Flash Player eller AIR-programmet läsa alla egenskaper i FileReference-objektet.

Den här händelsen har följande egenskaper:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Skickas när data har tagits emot från servern efter en slutförd överföring. Händelsen skickas inte om data inte returneras från servern.

Den här händelsen har följande egenskaper:

Obs! För att köra exempelkoden ändrar du egenskapen uploadURL.url så att den pekar på befintlig URL. URL:en måste peka till filen yourUploadHandlerScript.cfm i rotkatalogen för angiven URL. Beroende på den konfigurering som används kanske du även måste kompilera SWF-filen genom att ange Använd bara nätverket för Lokal uppspelningssäkerhet, eller uppdatera Flash Players säkerhetsinställningar så att filen ges nätverksåtkomst.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}