File  - AS3

Den mapp som innehåller installerade filer för programmet.

Egenskapen url för det här objektet använder URL-schemat app (inte URL-schemat file). Det innebär att strängen url anges att börja med "app:" (inte ”file:”). Om du skapar ett File-objekt som är relativt till katalogen File.applicationDirectory (med metoden resolvePath()) använder url-egenskapen för File-objektet också URL-schemat app.

Obs! Det går inte att skriva till filer eller kataloger med sökvägar som använder URL-schemat app:. Du kan inte heller ta bort eller skapa filer eller mappar med sökvägar som använder URL-schemat app:. Av säkerhetsskäl bör du aldrig ändra innehåll i programkatalogen och detta tillåts därför inte heller av operativsystemet på vissa plattformar. Om du vill spara programspecifika data bör du använda programlagringskatalogen (File.applicationStorageDirectory). Om du vill att något av innehållet (i programlagringskatalogen) ska ha tillgång till funktioner (AIR-API:er) som är reserverade för programmet, kan du visa de funktionerna med hjälp av en sandlådebrygga.

Med egenskapen applicationDirectory kan du referera till programkatalogen på ett sätt som fungerar på alla plattformar. Om du ställer in ett File-objekt till att referera till programkatalogen med hjälp av egenskapen nativePath eller url, fungerar den bara på plattformen som sökvägen gäller för.

På Android är nativePath-egenskapen för ett File-objekt som pekar på programkatalogen en tom sträng. Använd egenskapen url för att komma åt programfiler.

Relaterade API-element

Programmets privata lagringskatalog.

Varje AIR-program har en unik, permanent programlagringskatalog, som skapas första gången du använder File.applicationStorageDirectory. Den här katalogen är unik för varje program och användare. Den här katalogen är praktisk för lagring av användar- och programspecifika data.

När du avinstallerar ett AIR-program beror det på plattformen om avinstallationsprogrammet tar bort programkatalogen och dess filer.

Egenskapen url för det här objektet använder URL-schemat app-storage (inte URL-schemat file). Det innebär att strängen url anges att börja med "app-storage:" (inte ”file:”). Om du skapar ett File-objekt som är relativt till katalogen File.applicationStoreDirectory (med metoden resolvePath()) använder url för File-objektet också URL-schemat app-storage (som i exemplet).

Med egenskapen applicationStorageDirectory kan du referera till programlagringskatalogen på ett sätt som fungerar på alla plattformar. Om du ställer in ett File-objekt till att referera till programlagringskatalogen med hjälp av egenskapen nativePath eller url, fungerar den bara på plattformen som sökvägen gäller för.

Obs! (endast Mac OS): För att uppfylla villkoren för Mac App Store ändrades den fysiska platsen för den här katalogen mellan AIR 3.2 och AIR 3.3:

• 3.2-namnutrymme och tidigare: ~/Library/Preferences/appid/Local Store/
• 3.3-namnutrymme och senare: path/Library/Application Support/appid/Local Store, där path är antingen ~/Library/Containers/bundle-id/Data (sandlådemiljö) eller ~ (vid körning utanför sandlådemiljö)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Programmets cachekatalog.

Med egenskapen cacheDirectory kan du referera till cachekatalogen. Programmet bör använda cachekatalogen för att lagra filer som hämtas från en server eller som kan återskapas på något annat sätt. Exempel på filer som du bör placera i cachekatalogen är cachefiler för databaser och nedladdningsbart innehåll, till exempel sådant som används av tidningar och kartprogram.

Om du ställer in ett File-objekt till att referera till cachekatalogen med hjälp av egenskapen nativePath eller url fungerar det bara på plattformar där sökvägen är giltig.

Om operativsystemet inte har stöd för en cachekatalog är cacheDirectory null.

Användarens skrivbordskatalog.

Med egenskapen desktopDirectory kan du referera till skrivbordskatalogen på ett sätt som fungerar på alla plattformar. Om du ställer in ett File-objekt till att referera till skrivbordskatalogen med hjälp av egenskapen nativePath eller url, fungerar den bara på plattformen som sökvägen gäller för.

Om ett operativsystem saknar stöd för en skrivbordskatalog används en lämplig katalog på filsystemet i stället.

Enheter med AIR for TV saknar funktioner för skrivbordskataloger för användare. Egenskapen desktopDirectory refererar därför till samma katalogplats som egenskapen File.userDirectory. Användarkatalogen är unik för programmet.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Användarens dokumentkatalog.

I Windows är detta katalogen "Mina dokument" (till exempel C:\Documents and Settings\användarnamn\Mina dokument). I Mac OS är standardplatsen /Användare/användarnamn/Dokument. I Linux är standardplatsen /home/användarnamn/Documents (i ett engelskt system) och egenskapen tar hänsyn till inställningen xdg-user-dirs.

Med egenskapen documentsDirectory kan du referera till dokumentkatalogen på ett sätt som fungerar på alla plattformar. Om du ställer in ett File-objekt till att referera till dokumentkatalogen med hjälp av egenskapen nativePath eller url, fungerar den bara på plattformen som sökvägen gäller för.

Om ett operativsystem saknar stöd för en dokumentkatalog används en lämplig katalog på filsystemet i stället.

Enheter med AIR for TV saknar funktioner för dokumentkataloger för användare. Egenskapen documentsDirectory refererar därför till samma katalogplats som egenskapen File.userDirectory. Användarkatalogen är unik för programmet.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Anger om den fil eller katalog som referensen gäller har hämtats (från Internet) eller inte.

Den här egenskapen har endast betydelse i operativsystem där hämtade filer kan flaggas:

• Windows XP Service Pack 2 och senare och på Windows Vista
• Mac OS 10.5 och senare

I system där hämtade filer inte flaggas, t.ex. Linux, saknar egenskapen betydelse (och den ställs in på false).

Relaterade API-element

Anger om den fil eller katalog som refereras finns. Värdet är true om File-objektet pekar på en befintlig fil eller katalog och false i annat fall.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Ett Icon-objekt som innehåller de ikoner som har definierats för filen. Ett Icon-objekt är en array med BitmapData-objekt som motsvarar de olika ikonstatusarna. I Linux innehåller Icon-objektet inga ikoner. På Android har egenskapen icon värdet null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Anger om referensen är en katalog. Värdet är true om File-objektet pekar på en katalog och false i annat fall.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Anger om den fil eller katalog som refereras är ”dold”. Värdet är true om den fil eller katalog som refereras är dold och false i annat fall.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Anger om den katalog som refereras är ett paket.

Värdet är true om den katalog som refereras är ett paket och false i annat fall. Observera att File-klassen inte tillåter att du skapar paket direkt.

• I Mac OS kan kataloger anges som paket och visas då som en fil i Finder i stället för som en katalog. Den här är true om den katalog som refereras är ett paket och false om filen inte är en katalog, inte finns eller inte är ett paket.
• I andra operativsystem är den här egenskapen alltid false.

Anger om referensen är en symbolisk länk.

Värdet är true om File-objektet är en symbolisk länk och false i annat fall. Observera att File-klassen inte tillåter att du skapar symboliska länkar direkt.

Med hjälp av symboliska länkar kan en fil peka på en annan fil eller katalog på disken. Symboliska länkar påminner om alias i Mac OS och genvägar i Windows, men är inte riktigt samma sak. Ett alias eller en genväg rapporteras alltid som en fil (i stället för som en katalog), och om du läser eller skriver till aliaset eller genvägen påverkar detta inte den ursprungliga fil eller katalog som dessa pekar på. En symbolisk länk fungerar däremot i allmänhet som den fil eller katalog den pekar på. Den kan rapporteras som en fil eller katalog, och om du läser eller skriver till en symbolisk länk påverkar detta den fil eller katalog som länken pekar på, inte den symboliska länken. Om du tar bort en symbolisk länk, tas emellertid länken och inte målet för länken bort.

Mac^® OS^®, Linux och Windows ^® Vista ^® har stöd för symboliska länkar. I Windows är dessutom egenskapen isSymbolicLink för ett File-objekt som refererar till en knutpunkt (används i NTFS-filsystemet) angiven som true.

Den teckensekvens för radslut som används av värdoperativsystemet.

I Mac OS och Linux är detta radmatningstecknet (teckenkod 0x0A hexadecimal). I Windows är det vagnreturtecknet (teckenkod 0x0D hexadecimal) följt av radmatningstecknet (teckenkod 0x0A hexadecimal).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Den fullständiga sökvägen i värdoperativsystemets representation. I Mac OS och Linux används snedstreck (/) som sökvägsavgränsare. I Windows kan du däremot ställa in egenskapen nativePath genom att använda snedstreck (/) eller omvänt snedstreck (\) som sökvägsavgränsare. AIR ersätter automatiskt snedstreck med korrekt omvänt snedstreck (\).

Innan du skriver kod för att ställa in egenskapen nativePath direkt, bör du vara medveten om att detta kan skapa plattformsspecifik kod. Den inbyggda sökvägen "C:\\Documents and Settings\\bob\\Desktop" kan till exempel bara användas i Windows. Det är mycket bättre att använda följande statiska egenskaper, som representerar vanligt förekommande kataloger och som kan användas på alla plattformar:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Med metoden resolvePath() kan du skapa en sökväg som är relativ till dessa kataloger.

Vissa Flex API:er, t.ex. source-egenskapen i SWFLoader-klassen, använder ett URL (url-egenskapen för ett File-objekt), inte en inbyggd sökväg (egenskapen nativePath).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Den katalog som innehåller filen eller katalogen som refereras av det här File-objektet.

Om filen eller katalogen inte finns returnerar egenskapen parent ändå det File-objekt som pekar på den överordnade katalogen (även om den katalogen inte finns).

Den här egenskapen är identisk med returvärdet för resolvePath(".."), med undantag för att den överordnade katalogen till en rotkatalog är null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Avgör om programmet har beviljats åtkomst till filsystemet.

Relaterade API-element

Anger huruvida miljön förhindrar det här File-objektet från att säkerhetskopieras tillbaka till molnet.

Om den här egenskapen är true säkerhetskopieras det inte automatiskt till molnet på plattformar som erbjuder den här tjänsten. Standardvärdet för den här egenskapen är false.

Värdoperativsystemets sökvägsavgränsare.

I Mac OS och Linux är detta ett snedstreck (/). I Windows är det ett omvänt snedstreck (\).

Obs! När du använder omvänt snedstreck i en strängkonstant måste du skriva tecknet två gånger (som i "katalog\\fil.txt"). Varje par av omvända snedstreck i en strängkonstant representerar ett omvänt snedstreck i själva strängen.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Det tillgängliga utrymmet för användning vid denna File-plats, i byte.

Om filobjektet refererar till en katalog, visar spaceAvailable utrymmet i den katalog som filen kan använda. Om filobjektet refererar till en fil, visar spaceAvailable utrymmet som filen kan växa till. Om filplatsen inte existerar, är spaceAvailable inställd på 0. Om filobjektet refererar till en symbolisk länk, visar spaceAvailable det tillgängliga utrymme som den symboliska länken pekar ut.

Vanligtvis är det tillgängliga utrymmet för en katalog eller fil samma som det tillgängliga utrymmet i volymen som innehåller katalogen eller filen. Kvoter och kataloggränser räknas dock med i tillgängligt utrymme.

Lägga till en fil eller en katalog till en volym kräver generellt mer utrymme än den befintliga storleken på filen eller på innehållet i katalogen. Operativsystemet kan till exempel kräva mer utrymme för att lagra indexinformation. Eller också kan disksektorerna kräva mer utrymme. Tillgängligt utrymme ändras dynamsikt. Du kan alltså inte förvänta dig att tilldelas hela det rapporterade utrymmet för fillagring.

Den standardkodning som används av värdoperativsystemet.

Möjliga värden är bland annat "windows-1252" "shift-jis", "cn-gb" och "iso-8859-1". En fullständig lista finns i Teckenuppsättningar som stöds.

Du kan använda det här värdet när du använder metoderna readMultiByte() och writeMultiByte() i klassen FileStream.

Relaterade API-element

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

URL för den här filsökvägen.

Om detta är en referens till en sökväg i programmets lagringskatalog är URL-schemat "app-storage". Om det är en referens till en sökväg i programkatalogen är URL-schemat "app". I annat fall är schemat "file".

Du kan använda blanksteg (i stället för "%20") när du tilldelar ett värde till egenskapen url, och strängarna kodas då automatiskt i AIR (till exempel konverteras blanksteg till "%20").

Relaterade API-element

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Användarens katalog.

I Windows är detta den överordnade katalogen till katalogen ”Mina dokument” (till exempel C:\Documents and Settings\användarnamn). I Mac OS är det /Användare/användarnamn. I Linux är det /home/användarnamn.

Med egenskapen userDirectory kan du referera till användarkatalogen på ett sätt som fungerar på alla plattformar. Om du ställer in egenskapen nativePath eller url för ett File-objekt direkt, fungerar den bara på plattformen som sökvägen gäller för.

Om ett operativsystem saknar stöd för en användarkatalog används en lämplig katalog på filsystemet i stället.

På enheter med AIR for TV refererar egenskapen userDirectory till en användarkatalog som är unik för programmet.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Konstruktorfunktionen för File-klassen.

Om du skickar ett path-argument pekar File-objektet på den angivna sökvägen. Egenskapen nativePath och egenskapen url speglar då den sökvägen.

Även om du kan skicka ett path-argument för att ange en filsökväg, bör du vara medveten om att detta kan skapa plattformsspecifik kod. Den inbyggda sökvägen "C:\\Documents and Settings\\bob\\Desktop" eller en URL som "file:///C:/Documents%20and%20Settings/bob/Desktop" kan till exempel bara användas i Windows. Det är mycket bättre att använda följande statiska egenskaper, som representerar vanligt förekommande kataloger och som kan användas på alla plattformar:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Med metoden resolvePath() kan du hämta en sökväg som är relativ till dessa kataloger. Följande kod ställer in ett File-objekt till att peka mot filen settings.xml i programlagringskatalogen:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Viktigt! Om du skickar en URL-sträng i parametern path, kommer URL:n att avkodas för att matcha filsökvägen. Satsen new File("file:///c:/test/demo%20file%201%2e0.txt") skapar till exempel ett File-objekt med den inbyggda sökvägen "c:\test\demo file 1.0.txt". (En URL använder schemaprefixen file:, app:, eller app-storage:.) Om emellertid de giltiga URL-prefixen utelämnas hanteras söksträngen som en inbyggd sökväg och ingen avkodning kommer att äga rum. Du måste tänka på detta beteende när du validerar sökvägar härledda från källor som kan vara opålitliga. Om du bara validerar indatasträngen kan URL-avkodningen tillåta att någon utomstående går förbi dina valideringskontroller. Validera alltid den slutliga sökvägen för det instansierade File-objektet:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Relaterade API-element

Visar en dialogruta för katalogval, där användaren kan välja en katalog. När användaren väljer katalogen skickas händelsen select. Egenskapen target för select-händelsen är det File-objekt som pekar på den valda katalogen.

Dialogrutan för val av katalog visas inte alltid framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Obs! På Android-enheter stöds inte browseForDirectory(). File-objektet skickar omedelbart en cancel-händelse.

Parametrar

Relaterade API-element

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Visar dialogrutan Öppna fil, där användaren kan välja vilken fil som ska öppnas.

När användaren väljer filen skickas händelsen select. Egenskapen target för select-händelsen är det File-objekt som pekar på den valda filen.

Dialogrutan Öppna fil visas inte alltid framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Obs! På Android-enheter går det inte att ange titel för fildialogrutan. Parametern title ignoreras.

Parametrar

Relaterade API-element

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Visar dialogrutan Öppna fil, där användaren kan välja en eller flera filer som ska öppnas.

När användaren väljer filerna skickas händelsen selectMultiple. Egenskapen target för select-händelsen är det här File-objektet. Till skillnad från browseForOpen(), med metoden browseForOpenMultiple(), uppdateras inte det här File-objektet så att det refererar till de valda filerna. selectMultiple-händelsen som genereras innehåller istället en array över de valda filerna.

Dialogrutan Öppna fil visas inte alltid framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Obs! På Android-enheter går det inte att ange titel för fildialogrutan. Parametern title ignoreras.

Parametrar

Relaterade API-element

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Visar dialogrutan Spara fil, där användaren kan välja en målposition för filen.

När användaren väljer filen skickas händelsen select. Egenskapen target för select-händelsen är det File-objekt som pekar på den valda Spara-platsen.

Dialogrutan Spara fil visas inte alltid framför fönster som tillhör ett annat fönster (fönster där egenskapen owner är något annat än null). Undvik problem med fönsterordning genom att dölja ägda fönster innan den här metoden anropas.

Obs! På Android-enheter går det inte att ange titel för fildialogrutan. Parametern title ignoreras.

Parametrar

Relaterade API-element

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Avbryter alla väntande asynkrona åtgärder.

Kanoniserar filsökvägen.

Om File-objektet representerar en befintlig fil eller katalog justerar kanoniseringen sökvägen så att den matchar den verkliga filens eller katalogens namn (med avseende på skiftläge). Om File-objektet är en symbolisk länk justerar kanoniseringen sökvägen så att den matchar den fil eller katalog som länken pekar på, vare sig den filen eller katalogen finns eller inte. I skiftlägeskänsliga filsystem (till exempel Linux), och när det finns flera filer med namn där bara skiftläget skiljer, justerar metoden canonicalize() sökvägen så att den matchar den första filen som hittas (i en ordning som fastställs av filsystemet).

Dessutom konverterar kanoniseringen korta filnamn till långa filnamn i Windows.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Returnerar en kopia av det här File-objektet. Händelseregistreringar kopieras inte.

Obs! Den här metoden kopierar inte själva filen. Det skapas bara en kopia av instansen av File-objektet i ActionScript. Om du vill kopiera en fil använder du metoden copyTo().

Kopierar filen eller katalogen på den plats som anges av det här File-objektet till den plats som anges av parametern newLocation. Kopieringen skapar alla nödvändiga överordnade kataloger (om möjligt). När du skriver över filer med copyTo() skrivs även filattributen över.

Parametrar

Relaterade API-element

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Startar kopiering av filen eller katalogen på den plats som anges av det här File-objektet, till den plats som anges av destination-parametern.

När åtgärden är slutförd skickas antingen en complete-händelse (lyckades) eller en ioError-händelse (misslyckades). Kopieringen skapar alla nödvändiga överordnade kataloger (om möjligt).

Parametrar

Relaterade API-element

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Skapar den angivna katalogen och alla nödvändiga överordnade kataloger. Om katalogen redan finns utförs inget.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Returnerar en referens till en ny tillfällig katalog. Detta är en ny katalog i sökvägen till systemets tillfälliga katalog.

Med den här metoden kan du identifiera en ny, unik katalog och slipper köra en systemkontroll för att se om katalogen är ny och unik.

Du kanske vill ta bort den tillfälliga katalogen innan du stänger programmet, eftersom den inte tas bort automatiskt på vissa enheter.

Relaterade API-element

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Returnerar en referens till en ny tillfällig fil. Detta är en ny fil i sökvägen till systemets tillfälliga katalog.

Med den här metoden kan du identifiera en ny, unik fil och slipper köra en systemkontroll för att se om filen är ny och unik.

Du kan ta bort den tillfälliga filen innan du avslutar programmet, eftersom den inte tas bort automatiskt.

Relaterade API-element

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Tar bort katalogen. Om den här filen är en symbolisk länk till en katalog, tas länken och inte katalogen bort.

Parametrar

Relaterade API-element

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Tar bort katalogen asynkront. Om den här filen är en symbolisk länk till en katalog, tas länken och inte katalogen bort.

Parametrar

Relaterade API-element

Tar bort filen. Om den här filen är en symbolisk länk, tas länken och inte målfilen bort.

Relaterade API-element

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Tar bort filen asynkront. Om den här filen är en symbolisk länk, tas länken och inte målfilen bort.

Relaterade API-element

Returnerar en array med File-objekt, som motsvarar filer och kataloger i den katalog som representeras av det här File-objektet. Den här metoden utforskar inte innehållet i underkataloger.

Relaterade API-element

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Hämtar asynkront en array med File-objekt, som motsvarar innehållet i den katalog som representeras av det här File-objektet.

Relaterade API-element

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Hittar den relativa sökvägen mellan två File-sökvägar.

Den relativa sökvägen är den lista över komponenter som kan läggas till (lösas mot) den här referensen för att den andra referensen (parameter) ska hittas. Den relativa sökvägen returneras med avgränsaren "/".

Relativa sökvägar kan också innehålla ".." -referenser, men sådana sökvägar korsar inte tydliga volymgränser.

Parametrar

Returnerar en array med File-objekt, som listar filsystemets rotkataloger.

I Windows är det till exempel en lista med volymer som C-enheten och D-enheten. En tom enhet, t.ex. en cd- eller dvd-enhet utan skiva, ingår inte i den här arrayen. I Mac OS och Linux returnerar alltid den här metoden den unika rotkatalogen för datorn (katalogen ”/”).

På filsystem där rotkatalogen inte är läsbar, t.ex. Android-filsystemet, speglar egenskaperna för det returnerade File-objektet inte alltid det verkliga värdet. På Android rapporterar till exempel egenskapen spaceAvailable värdet 0.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Flyttar filen eller katalogen på den plats som anges av det här File-objektet till den plats som anges av destination-parametern.

Om du vill byta namn på en fil anger du parametern destination så att den pekar på en sökväg i filens katalog, men med ett annat filnamn.

Flyttningen skapar alla nödvändiga överordnade kataloger (om möjligt).

Parametrar

Relaterade API-element

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Startar flyttning av filen eller katalogen på den plats som anges av det här File-objektet, till den plats som anges av newLocation-parametern.

Om du vill byta namn på en fil anger du parametern destination så att den pekar på en sökväg i filens katalog, men med ett annat filnamn.

Flyttningen skapar alla nödvändiga överordnade kataloger (om möjligt).

Parametrar

Relaterade API-element

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Flyttar filen eller katalogen till papperskorgen.

Obs! På operativsystem som saknar stöd för en återställningsbar papperskorg tas filerna bort direkt.

Relaterade API-element

Flyttar filen eller katalogen till papperskorgen asynkront.

Obs! På operativsystem som saknar stöd för en återställningsbar papperskorg tas filerna bort direkt.

Relaterade API-element

Öppnar filen med det program som har registrerats i operativsystemet för den här filtypen.

AIR förhindrar att vissa filer öppnas med metoden File.openWithDefaultApplication(). I Windows förhindrar AIR att du öppnar vissa typer av filer (filer med specifika filtillägg, se nedan). I Mac OS och Linux kan du inte öppna filer som startar i ett visst program med AIR, vilket anges nedan. Ett undantag genereras om du försöker öppna en sådan fil med openWithDefaultApplication()-metoden. AIR-program som installerats med ett inbyggt installationsprogram (program med utökad skrivbordsprofil) underkastas inte sådana begränsningar, de kan öppna alla filtyper.

Du kan inte öppna dokument från programkatalogen.

Tabellen nedan anger filtilläggen som inte tillåts i Windows samt programmen som inte tillåts i Mac OS och Linux:

Relaterade API-element

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Begär åtkomst till filsystemet.

Skapar ett nytt File-objekt med en sökväg som är relativ till sökvägen för det här File-objektet, baserat på path-parametern (en sträng).

Du kan använda en relativ sökväg eller en absolut sökväg med path-parametern.

Om du specificerar en relativ sökväg, läggs path till filobjektets sökväg. Men om ”..” används i path kan detta returnera en slutlig sökväg, som inte är underordnad File-objektet. Den slutliga referensen behöver inte referera till en faktisk plats i filsystemet.

Om du specificerar en absolut filreferens returnerar metoden det filobjekt som pekar på sökvägen. Den absoluta filreferensen ska använda en giltig inbyggd sökvägssyntax för användarens operativsystem (till exempel "C:\\test" i Windows). Använd inte en URL (till exempel "file:///c:/test") som path-parameter.

Alla slutliga sökvägar normaliseras enligt följande:

• Alla "." -element ignoreras.
• Alla ".." -element inkluderar den överordnade posten.
• Inga ".." -referenser som når filsystemets rot eller den permanenta programlagringsroten passerar noden; de ignoreras.

Du bör alltid använda vanligt snedstreck (/) som sökvägsavgränsare. I Windows kan du även använda ett bakåtlutande snedstreck (\), men du bör inte göra det. Om du använder ett bakåtlutande snedstreck kan det göra att programmen inte fungerar på andra plattformar.

Filnamn och katalognamn är skiftlägeskänsliga i Linux.

Parametrar

Skickas när en väntande asynkron åtgärd avbryts.

Den här händelsen har följande egenskaper:

Skickas när en asynkron åtgärd har slutförts.

Den här händelsen har följande egenskaper:

Skickas när det finns en kataloglista som resultat av ett anrop till metoden getDirectoryListingAsync().

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när ett fel inträffar under en asynkron filåtgärd.

Den här händelsen har följande egenskaper:

Skickas när programmet begär åtkomst till filsystemet. Kontrollera värdet för egenskapen status för att avgöra om behörighet beviljades eller nekades

Relaterade API-element

Skickas när en åtgärd strider mot en säkerhetsbegränsning.

Den här händelsen har följande egenskaper:

Skickas när användaren väljer en fil eller katalog i en dialogruta för fil- eller katalogbläddring.

Den här händelsen har följande egenskaper:

Skickas när användaren väljer filer i dialogrutan som öppnas av ett anrop till browseForOpenMultiple()-metoden.

Relaterade API-element