URLRequest  - AS3

Anger huruvida autentiseringsbegäranden ska hanteras (true) eller inte (false) för den här begäran. Om värdet är false returnerar autentiseringskrav ett HTTP-fel.

De autentiseringsmetoder som stöds är:

• Windows – HTTP Basic/Digest, Windows-integrerad autentisering (inklusive NTLM och Kerberos), SSL-certifikatautentisering.
• Mac – HTTP Basic/Digest, NTLM, SSL-certifikatautentisering.

Obs: metoderna FileReference.upload(), FileReference.download() och HTMLLoader.load() stöder inte egenskapen URLRequest.authenticate.

Standardvärdet är true.

Relaterade API-element

Anger huruvida data för lyckade svar ska cachelagras för den här begäran. När värdet är true använder AIR-programmet operativsystemets HTTP-cache.

Obs: Metoden HTMLLoader.load() stöder inte egenskapen URLRequest.cacheResponse.

Standardvärdet är true.

Relaterade API-element

MIME-innehållstypen för innehållet i egenskapen data.

Standardvärdet är application/x-www-form-urlencoded.

Obs! Metoderna FileReference.upload(), FileReference.download() och HTMLLoader.load() stöder inte egenskapen URLRequest.contentType.

När en POST-begäran skickas måste värdena för contentType- och data-egenskaperna motsvara varandra korrekt. Värdet för contentType-egenskapen instruerar servrar hur värdet för data-egenskapen ska tolkas.

• Om värdet på egenskapen data är ett URLVariables-objekt måste värdet på contentType vara application/x-www-form-urlencoded.
• Om värdet på egenskapen data är av någon annan typ bör värdet på contentType visa vilken typ av POST-data som kommer att skickas (alltså de binära data eller strängdata som finns i värdet för egenskapen data).
• För FileReference.upload() ställs Content-Type i begäran automatiskt in på multipart/form-data och värdet för contentType-egenskapen ignoreras.

Om du i Flash Player 10 eller senare använder en multipart-innehållstyp (till exempel ”multipart/form-data”) som innehåller en överföring (vilket indikeras av en ”filename”-parameter i ett ”content-disposition”-huvud inuti POST), gäller de säkerhetsregler som används för överföringar också för POST-åtgärden.

• POST-åtgärden måste utföras som ett svar på en användarinitierad åtgärd som exempelvis en musklickning eller en tangenttryckning.
• Om POST-åtgärden är för korsdomän (POST-målet ligger inte på samma server som SWF-filen som skickar POST-begäran), måste målservern ha en URL-policyfil som tillåter korsdomänåtkomst.

För en multipart-innehållstyp måste också syntaxen vara giltig (enligt RFC2046-standarderna). Om syntaxen verkar vara ogiltig, gäller samma regler för POST-åtgärden som för överföringar.

Relaterade API-element

Ett objekt som innehåller data som ska överföras med URL-begäran.

Den här egenskapen används med egenskapen method. När värdet för method är GET läggs värdet för data till värdet för URLRequest.url med hjälp av HTTP-frågesträngssyntax. När värdet för method är POST (eller något annat värde utom GET) överförs data-värdet i HTTP-begäran.

I URLRequest API används binärkodad POST och URL-kodade variabler, samt även strängar. Dataobjektet kan vara ett ByteArray-, URLVariables- eller String-objekt.

Det sättet som data används på beror på vilken typ av objekt som används:

• Om objektet är ett ByteArray-objekt används alla binära data i objektet som POST-data. Data av typen ByteArray används inte med GET. Data av typen ByteArray används inte heller med FileReference.upload() och FileReference.download().
• Om objektet är ett URLVariables-objekt och metoden är POST kodas variablerna med formatet x-www-form-urlencoded. Resultatsträngen används som POST-data. Undantaget är ett anrop till FileReference.upload() där variablerna skickas som separata fält i posten multipart/form-data.
• Om objektet är ett URLVariables-objekt och metoden GET används anger objektet de variabler som ska skickas med URLRequest-objektet.
• I annat fall konverteras objektet till en sträng som används som POST- eller GET-data.

Dessa data skickas inte förrän URLRequest-objektet används av en metod, t.ex. navigateToURL() eller FileReference.upload().

Obs! Värdet på contentType måste motsvara datatypen i egenskapen data. Mer information finns i beskrivningen av contentType-egenskapen.

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

En sträng som ger en unik identifiering av den signerade Adobe-plattformskomponent som ska lagras i (eller hämtas från) Flash Player-cache. En Adobe-plattformskomponent är en signerad fil (en SWZ-fil) som innehåller SWF-innehåll som cachelagras beständigt på användarens dator. Alla SWZ-filer är signerade av Adobe. En sammanfattning motsvarar en enskild cachelagrad fil. Om du ändrar filen ändras dess sammanfattning på ett oförutsägbart sätt. Genom att använda en sammanfattning kan du kontrollera den cachelagrade filen över flera domäner. Två filer med samma sammanfattning är samma fil och två filer med olika sammanfattningar är inte samma fil. Det är inte praktiskt möjligt att skapa en fil för att simulera en sammanfattning så att den framstår som en annan sammanfattning.

Sammanfattningen baseras på en SHA-256-algoritm för meddelandesammanfattning (64 teckens längd i hexadecimalt format).

Flex SDK innehåller till exempel en SWZ för Flex-ramverket (och tillhandahåller också sammanfattningssträngen för SWZ-filen). Du kan posta denna SWZ på webbservern och läsa in den i SWF-filen (med hjälp av metoden load() i ett URLLoader-objekt). Om slutanvändarens dator redan har cachelagrat den matchande SWZ-filen, använder programmet den lagrade filen. (En SWZ-fil matchar om dess sammanfattning matchar den som du anger.) Annars läser programmet in SWZ-filen från den URL som du anger.

Ange endast digest-parametern i ett URLRequest-objekt som används för att anropa metoden URLLoader.load() för att läsa in en SWZ-fil. Om digest-egenskapen för ett URLRequest-objekt är angiven när objektet används i andra metoder, genereras ett IOError-undantag.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Anger huruvida omdirigeringar ska följas (true) eller inte (false).

Obs: metoderna FileReference.upload(), FileReference.download() och HTMLLoader.load() stöder inte egenskapen URLRequest.followRedirects.

Standardvärdet är true.

Relaterade API-element

Anger tidsgränsen för inaktivitet (i millisekunder) för den här begäran.

Tidsgränsen för inaktivitet är den tid som klienten väntar på ett svar från servern, efter att anslutningen har skapats, innan den överger begäran.

Obs! Metoden HTMLLoader.load() stöder inte egenskapen URLRequest.idleTimeout. Klassen HTMLLoader definierar en egen idleTimeout-egenskap.

Standardvärdet är initialized from the URLRequestDefaults.idleTimeout property.

Relaterade API-element

Anger huruvida HTTP-protokollstacken ska hantera cookies för den här begäran. När värdet är true läggs cookies till i begäran och cookies i svar registreras. När värdet är false läggs cookies inte till i begäran och cookies i svar registreras inte, men användarna kan själva hantera cookies genom att redigera rubrikerna direkt. Obs! På Windows kan du inte manuellt lägga till cookies i en URL-begäran när manageCookies är inställt på true. På andra operativsystem är det tillåtet att lägga till cookies i en begäran oavsett om manageCookies är inställt på true eller false. När det är tillåtet kan du manuellt lägga till cookies i en begäran genom att lägga till ett URLRequestHeader-objekt med cookiedata i requestHeaders-arrayen.

I Mac OS delas cookies med Safari. Så här raderar du cookies i Mac OS:

1. Öppna Safari.
2. Välj Safari > Inställningar och klicka på panelen Säkerhet.
3. Klicka på knappen Visa cookies.
4. Klicka på knappen Ta bort alla.

Så här raderar du cookies i Windows:

1. Öppna Internetalternativ på Kontrollpanelen och klicka på fliken Allmänt.
2. Klicka på knappen Ta bort cookies.

Standardvärdet är true.

Relaterade API-element

Styr metoden för att skicka HTTP-formulär.

När det gäller SWF-innehåll som körs i Flash Player (i webbläsaren) begränsas den här egenskapen till åtgärden GET eller POST, och giltiga värden är URLRequestMethod.GET eller URLRequestMethod.POST.

För innehåll som körs i Adobe AIR kan du använda vilket strängvärde som helst om innehållet finns i programmets säkerhetssandlåda. Annars, som med innehåll som körs i Flash Player, är du begränsad till att använda åtgärderna GET eller POST.

För innehåll som körs i Adobe AIR, och när du använder navigateToURL()-funktionen, behandlar miljön en URLRequest som använder metoden POST (en som har method-egenskapen inställd på URLRequestMethod.POST) som GET-metod.

Obs! Om det körs i Flash Player och det aktuella formuläret saknar brödtext använder Flash Player automatiskt en GET-åtgärd, även om metoden är inställd på URLRequestMethod.POST. Därför bör alltid en ”dummy”-brödtext inkluderas för att säkerställa att korrekt metod används.

Standardvärdet är URLRequestMethod.GET.

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

Arrayen med rubriker för HTTP-begäran som ska läggas till i HTTP-begäran. Arrayen består av URLRequestHeader-objekt. Varje objekt i arrayen måste vara ett URLRequestHeader-objekt som innehåller en namnsträng och en värdesträng enligt följande:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

Flash Player och AIR-körningen anger vissa begränsningar för begäranrubriker. Mer information finns i beskrivningen av klassen URLRequestHeader.

Inte alla metoder som accepterar URLRequest-parametrar stödjer requestHeaders-egenskapen. Mer information finns i dokumentationen om den metod som du anropar. I metoderna FileReference.upload() och FileReference.download() används inte parametern URLRequest.requestHeaders.

På grund av webbläsarbegränsningar stöder anpassade HTTP-begäransrubriker endast POST-begäran, inte GET-begäran.

Relaterade API-element

Den URL som ska begäras.

Var noga med att koda alla tecken som antingen beskrivs som osäkra i Uniform Resource Locator-specifikationen (se http://www.faqs.org/rfcs/rfc1738.html) eller som är reserverade i URLRequest-objektets URL-schema (när de inte används i omvänt syfte). Använd exempelvis "%25" för procentsymbolen (%) och "%23" för nummertecknet (#), som i "http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25".

Som standard måste URL:en finnas i samma domän som den anropande filen, om inte innehållet körs i Adobe AIR-programmets säkerhetssandlåda. Om du vill läsa in data från en annan domän sparar du en URL-principfil på den server där data finns. Mer information finns i beskrivningen av klassen URLRequest.

När det gäller innehåll som körs i Adobe AIR kan filer i säkerhetssandlådan application – filer som installeras med AIR-programmet – komma åt URL:er med hjälp av något av följande URL-scheman:

• http och https
• file
• app-storage
• app

Obs! IPv6 (Internet Protocol version 6) stöds i AIR och i Flash Player 9.0.115.0 och senare versioner. IPv6 är en version av Internetprotokollet med stöd för adresser med 128-bitar (en förbättring från den tidigare versionen IPv4 som har stöd för 32-bitar). Du kanske måste aktivera IPv6 i dina nätverksgränssnitt. Mer information finns i hjälpen för operativsystemet som dina data finns på. Om IPv6 stöds på värdsystemet kan du ange numeriska IPv6-adresser uttryckligen i URL:er inom hakparenteser ([]) på följande sätt.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Anger huruvida den lokala cachen ska genomsökas innan det här URLRequest-objektet hämtar data.

Obs: Metoden HTMLLoader.load() stöder inte egenskapen URLRequest.useCache.

Standardvärdet är true.

Relaterade API-element

Anger den användaragentsträng som ska användas i HTTP-begäran.

Standardvärdet är samma användaragentsträng som används av Flash Player och är olika i Macintosh, Linux och Windows.

Obs! Den här egenskapen påverkar inte användaragentsträngen när URLRequest-objektet används med metoden load() för ett HTMLLoader-objekt. När du vill ange användaragentsträngen för ett HTMLLoader-objekt anger du egenskapen userAgent för HTMLLoader-objektet eller den statiska egenskapen URLRequestDefaults.userAgent.

Relaterade API-element

Skapar ett URLRequest-objekt. Om System.useCodePage har värdet true kodas begäran med systemets teckentabell, istället för Unicode. Om System.useCodePage har värdet false kodas begäran med Unicode, istället för systemets teckentabell.

Relaterade API-element

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

Tillåter att en omdirigerad URL från en URLRequest-källa ersätter en del av ett URL i en ny URLRequest. När en inledande begäran har omdirigerats, gör detta att efterföljande begäranden skickas direkt till den omdirigerade serverplatsen.

När den inledande URLRequest har slutförts och HTTPStatusEvent.redirected är sant, kan den här metoden anropas med den inledande begäran som sourceRequest. Som standard kommer domänen för den omdirigerade URL-adressen att användas i stället för domänen i URL-adressen för denna URLRequest. URLRequest.url måste anges innan du anropar den här metoden. Metoden måste anropas innan denna URLRequest läses in. Alternativt, om parametern wholeURL är sann kommer hela URL-adressen från URLRequest-källan minus filnamnet att användas för hela URL-adressen minus det slutgiltiga filnamnet i denna URLRequest. Dessutom kan anroparen valfritt ange en sträng eller ett reguljärt uttryck i parametern pattern. Mönstret används för sökning och ersätts med strängen i parametern replace. Sökningen och ersättning sker efter det att URL-adressen ersatts.

Parametrar

Relaterade API-element

För att köra exemplet sparar du en fil med namnet XMLFile.xml i samma katalog som SWF-filen.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}