URLLoader  - AS3

Anger antalet byte som har hämtats hittills under inläsningen.

Anger det totala antalet databyte som laddas ned. Den här egenskapen innehåller 0 under pågående inläsning och fylls i när åtgärden är slutförd. Om Content-Length-rubriken saknas gör det att bytesTotal inte kan bestämmas.

De data som tas emot från inläsningen. Den här egenskapen fylls i endast när inläsningen är slutförd. Dataformatet beror på vilken inställning för egenskapen dataFormat som används:

Om egenskapen dataFormat anges som URLLoaderDataFormat.TEXT blir mottagna data en textsträng.

Om egenskapen dataFormat anges som URLLoaderDataFormat.BINARY blir mottagna data ett ByteArray-objekt med binära rådata.

Om egenskapen dataFormat anges som URLLoaderDataFormat.VARIABLES blir mottagna data ett URLVariables-objekt med URL-kodade variabler.

Relaterade API-element

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Anger om laddade ned data tas emot som text (URLLoaderDataFormat.TEXT), binära rådata (URLLoaderDataFormat.BINARY) eller URL-kodade variabler (URLLoaderDataFormat.VARIABLES).

Om värdet för egenskapen dataFormat är URLLoaderDataFormat.TEXT blir mottagna data en textsträng.

Om värdet för egenskapen dataFormat är URLLoaderDataFormat.BINARY blir mottagna data ett ByteArray-objekt med binära rådata.

Om värdet för egenskapen dataFormat är URLLoaderDataFormat.VARIABLES blir mottagna data ett URLVariables-objekt med URL-kodade variabler.

Standardvärdet är URLLoaderDataFormat.TEXT.

Relaterade API-element

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Skapar ett URLLoader-objekt.

Relaterade API-element

Registrerar ett händelseavlyssnarobjekt för ett EventDispatcher-objekt så att avlyssnaren får meddelanden om händelser. Du kan registrera händelseavlyssnare på alla noder i visningslistan efter en särskild typ av händelse, fas och prioritet.

När du har registrerat en händelseavlyssnare går det inte att ändra dess prioritet genom ytterligare anrop till addEventListener(). För att kunna ändra avlyssnarens prioritet måste du först anropa removeListener(). Sedan går det att registrera avlyssnaren på nytt med den nya prioritetsnivån.

Kom ihåg att när avlyssnaren har registrerats så skapar anrop till addEventListener() med annan type eller useCapture-värde en separat avlyssnarregistrering. Om du till exempel först registrerar en avlyssnare med useCapture inställt på true, avlyssnar den bara under hämtningsfasen. Om du anropar addEventListener() igen med samma avlyssningsobjekt men med useCapture inställt på false, får du två separata avlyssnare: en som avlyssnar under hämtningsfasen och en som avlyssnar under både mål- och bubblingsfasen.

Det går inte att registrera en händelseavlyssnare endast för målfasen eller bubblingsfasen. De faserna är sammankopplade vid registreringen eftersom bubblande bara tillämpas på de som är överordnade målnoden.

Om du inte längre behöver en händelseavlyssnare tar du bort den genom att anropa removeEventListener(). Annars finns risk för minnesproblem. Händelseavlyssnare tas inte automatiskt bort från minnet, eftersom skräpinsamlaren inte tar bort avlyssnaren så länge det skickande objektet finns (om inte parametern useWeakReference är true).

Kopiering av en EventDispatcher-instans innebär inte att de händelseavlyssnare som är kopplade till den kopieras. (Om en nod som du nyss skapat behöver en händelseavlyssnare måste du koppla avlyssnaren efter att du skapat noden.) Om du däremot flyttar en EventDispatcher-instans flyttas den kopplade händelseavlyssnaren med.

Om händelseavlyssnaren är registrerad på en nod samtidigt som en händelse bearbetas på den noden aktiveras inte händelseavlyssnaren under den aktuella fasen, men den kan aktiveras under en senare fas i händelseflödet, t.ex. bubblingsfasen.

Om en händelseavlyssnare tas bort från en nod samtidigt som en händelse bearbetas på den noden, aktiveras den ändå av de aktuella åtgärderna. När händelseavlyssnaren tagits bort anropas den aldrig mer (om den inte registreras på nytt för framtida bearbetning).

Parametrar

function(evt:Event):void

Stänger den pågående inläsningen. Eventuell pågående inläsning avslutas omedelbart. Om det inte finns någon URL för direktuppspelning utlöser ett fel för ogiltig dataström.

Skickar och läser in data från den angivna URL:en. Alla data kan tas emot som text, binära rådata eller URL-kodade variabler beroende på värdet du anger för egenskapen dataFormat. Observera att standardvärdet för egenskapen dataFormat är text. Om du vill skicka data till angiven URL kan du använda egenskapen data i objektet URLRequest.

Obs!Om en fil som läses in innehåller andra tecken än ASCII-tecken (finns i många icke-engelska språk) rekommenderas att du sparar filen med UTF-8 eller UTF-16-kodning i stället för ett icke-Unicode-format som ASCII.

En SWF-fil i sandlådan lokal-med-filsystem kan inte hämta data från, eller leverera data till, en resurs som finns i nätverkssandlådan.

Den anropade SWF-filen och URL:en som du läser in, måste som standard finnas i exakt samma domän. En SWF-fil på www.adobe.com kan till exempel bara läsa in data från källor som också finns på www.adobe.com. Om du vill läsa in data från en annan domän sparar du en URL-principfil på servern där data finns.

Du kan inte ansluta till vanligtvis reserverade portar. Du hittar en fullständig lista över spärrade portar i avsnittet ”Begränsa nätverks-API:er” i Utvecklarhandbok för Adobe ActionScript 3.0.

Om du i Flash Player 10 eller senare använder en multipart-innehållstyp (till exempel ”multipart/form-data”) som innehåller en överföring (vilket indikeras av en ”filename”-parameter i ett ”content-disposition”-huvud inuti POST), gäller de säkerhetsregler som används för överföringar också för POST-åtgärden.

• POST-åtgärden måste utföras som ett svar på en användarinitierad åtgärd som exempelvis en musklickning eller en tangenttryckning.
• Om POST-åtgärden är för korsdomän (POST-målet ligger inte på samma server som SWF-filen som skickar POST-begäran), måste målservern ha en URL-policyfil som tillåter korsdomänåtkomst.

För en multipart-innehållstyp måste också syntaxen vara giltig (enligt RFC2046-standarderna). Om syntaxen verkar vara ogiltig, gäller samma regler för POST-åtgärden som för överföringar.

Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Skickas när alla mottagna data har avkodats och placerats i egenskapen data i URLLoader-objektet. Alla mottagna data är tillgängliga efter att denna händelse har skickats.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas om ett anrop till metoden load() försöker få tillgång till data via HTTP och Adobe AIR kan identifiera och returnera statuskoden för begäran.

HTTPStatusEvent.HTTP_RESPONSE_STATUS-konstanten definierar värdet på type-egenskapen i ett httpResponseStatus-händelseobjekt.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när ett anrop till URLLoader.load() försöker komma åt data via HTTP. Den här händelsen skickas endast för innehåll som körs i Flash Player om den aktuella Flash Player-miljön upptäcker och returnerar statuskoden för begäran. (I vissa webbläsarmiljöer kanske den här informationen inte kan returneras.) Observera att eventuell httpStatus-händelse skickas före (och utöver) händelserna complete och error.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas om ett anrop till URLLoader.load() resulterar i ett allvarligt fel som gör att nedladdningen avbryts.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när nedladdningen påbörjas efter anropet till metoden URLLoader.load().

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när data tas emot under nedladdningsförloppet.

Observera att med objektet URLLoader går det inte att få åtkomst till data förrän allt har tagits emot. Händelseförloppet fungerar som en avisering om hur nedladdningen genomförs. Använd objektet URLStream om du behöver få åtkomst till data innan nedladdningen är slutförd.

Den här händelsen har följande egenskaper:

Relaterade API-element

Skickas när ett anrop till URLLoader.load() försöker läsa in data från en server utanför säkerhetssandlådan. Skickas också om ett anrop till URLLoader.load() försöker att läsa in en SWZ-fil och certifikatet är ogiltigt eller sammanfattningsfilen inte matchar komponenten.

Den här händelsen har följande egenskaper:

Relaterade API-element

Obs! För att köra exemplet placerar du en fil med namnet urlLoaderExample.txt i samma katalog som SWF-filen. Filen ska endast innehålla följande textrad: answer=42&question=unknown

Detta kodexempel fungerar på följande sätt:

1. Konstruktorfunktionen skapar instansen URLLoader med namnet loader och instansen URLRequest med namnet request, som innehåller plats och namn på filen som ska läsas in.
2. Objektet loader skickas till metoden configureListeners(), vilket lägger till avlyssnare för respektive URLLoader-händelse som används.
3. Objektet request skickas därefter till loader.load() som läser in textfilen.
4. När URLLoader har läst in textfilen aktiveras händelsen Event.COMPLETE som utlöser metoden completeHandler(). Metoden completeHandler() skapar objektet URLVariables från texten som lästes in från filen. Objektet URLVariables konverterar URL-kodade par med namn/värde till ActionScript-egenskaper så att det blir enklare att ändra inlästa data.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}