Date  - AS3

Den dag i månaden (ett heltal mellan 1 och 31) som anges av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Dag i månaden (ett heltal mellan 1 och 31) för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Den veckodag (0 för söndag, 1 för måndag och så vidare) som anges av det här Date-objektet enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Veckodag (0 för söndag, 1 för måndag och så vidare) för det här Date-objektet enligt universaltid (UTC).

Relaterade API-element

Det fullständiga året (med fyra siffror, till exempel 2000) för ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Det fyrsiffriga året för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Timmen (ett heltal mellan 0 och 23) på dygnet för ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Timmen (ett heltal mellan 0 och 23) på dygnet för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Millisekunddelen (ett heltal mellan 0 och 999) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Millisekunddelen (ett heltal mellan 0 och 999) av ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Minutdelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Minutdelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Månadsdelen (0 för januari, 1 för februari och så vidare) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Månadsdelen (0 [januari] till 11 [december]) för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Sekunddelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

Sekunddelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

Antalet millisekunder sedan midnatt 1 januari 1970, universal tid, för ett Date-objekt. Använd den här metoden för att representera ett specifikt ögonblick när två eller flera Date-objekt ska jämföras.

Relaterade API-element

Skillnaden i minuter mellan universaltid (UTC) och datorns lokala tid. Värdet är antal minuter som du måste lägga till i datorns lokala tidsvärde för att komma upp i UTC. Om datorns tid är senare än UTC, kommer värdet vara negativt.

Relaterade API-element

Skapar ett nytt Date-objekt som innehåller angivet datum och angiven tid.

Konstruktorn Date() tar upp till sju parametrar (year, month, …, millisecond), som anger datum och tid på millisekunden. Datumet som det nykonstruerade Date-objektet innehåller beror på antalet och datatypen på de argument som skickas.

• Om du inte skickar några argument, tilldelas Date-objektet aktuellt datum och tid.
• Om du skickar ett argument av datatypen Number, tilldelas Date-objektet ett tidsvärde baserat på antal millisekunder sedan 1 januari 1970 0:00:000 GMT, enligt argumentet lone.
• Om du skickar ett argument av datatypen String och strängen innehåller ett giltigt datum, innehåller Date-objektet en tid baserat på det datumet.
• Om du skickar två eller flera argument tilldelas Date-objektet ett tidsvärde baserat på argumentvärdena som skickades, vilka representerar datumets år, månad, dag, timme, minut, sekund och millisekund.

Om du skickar en sträng till konstruktorn för Date-klassen kan datumet vara på flera olika format men måste minst innehålla månad, dag och år. Feb 1 2005 är till exempel giltigt men Feb 2005 är inte giltigt. I följande lista visas några giltiga format:

• Dag månad datum timmar:minuter:sekunder GMT år (till exempel "Tue Feb 1 00:00:00 GMT-0800 2005", som matchar toString())
• Dag månad datum år timmar:minuter:sekunder AM/PM (till exempel "Tue Feb 1 2005 12:00:00 AM", som matchar toLocaleString())
• Dag månad datum år (till exempel "Tue Feb 1 2005", som matchar toDateString())
• Månad/dag/år (till exempel 02/01/2005)
• Månad/år (till exempel 02/2005)

Relaterade API-element

Returnerar dag i månaden (ett heltal mellan 1 och 31) som anges av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Relaterade API-element

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

Returnerar den veckodag (0 för söndag, 1 för måndag och så vidare) som anges av det här Date-objektet enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

Returnerar det fullständiga året (med fyra siffror, till exempel 2000) för ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

Returnerar timmen (ett heltal mellan 0 och 23) på dygnet för ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

Returnerar millisekunddelen (ett heltal mellan 0 och 999) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var now:Date = new Date();
trace(now.getMilliseconds());

Returnerar minutdelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

Returnerar månadsdelen (0 för januari, 1 för februari och så vidare) för det här Date-objektet enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

Returnerar sekunddelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

var now:Date = new Date();
trace(now.getSeconds());

Returnerar antalet millisekunder sedan midnatt 1 januari 1970, universal tid, för ett Date-objekt. Använd den här metoden för att representera ett specifikt ögonblick när två eller flera Date-objekt ska jämföras.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }
 

Returnerar skillnaden i minuter mellan universaltid (UTC) och datorns lokala tid.

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

Returnerar dag i månaden (ett heltal mellan 1 och 31) för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

Returnerar veckodag (0 för söndag, 1 för måndag och så vidare) för det här Date-objektet enligt universaltid (UTC).

Relaterade API-element

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

Returnerar det fyrsiffriga året för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

Returnerar timmen (ett heltal mellan 0 och 23) på dygnet för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Returnerar millisekunddelen (ett heltal mellan 0 och 999) av ett Date-objekt enligt universaltid (UTC).

var now:Date = new Date();
trace(now.getUTCMilliseconds());

Returnerar minutdelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt universaltid (UTC).

var now:Date = new Date();
trace(now.getUTCMinutes());

Returnerar månadsdelen (0 [januari] till 11 [december]) för ett Date-objekt enligt universaltid (UTC).

Relaterade API-element

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

Returnerar sekunddelen (ett heltal mellan 0 och 59) av ett Date-objekt enligt universaltid (UTC).

var now:Date = new Date();
trace(now.getUTCSeconds());

Konverterar en sträng som representerar ett datum till ett tal som är lika med antalet millisekunder som gått sedan 1 januari 1970, UTC.

Parametrar

     Day Mon DD HH:MM:SS TZD YYYY
     

     Wed Apr 12 15:30:17 GMT-0700 2006
     

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD
     

Relaterade API-element

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

Anger dagen i månaden enligt lokal tid och returnerar den nya tiden i millisekunder. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Parametrar

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

Anger året enligt lokal tid och returnerar den nya tiden i millisekunder. Om parametrarna month och day anges är de inställda på lokal tid. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Andra fält i det angivna Date-objektet påverkas inte när den här metoden anropas, men Date.getUTCDay() och Date.getDay() kan rapportera ett nytt värde om veckodagen ändras på grund av att metoden anropas.

Parametrar

Relaterade API-element

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

Anger timmen enligt lokal tid och returnerar den nya tiden i millisekunder. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Parametrar

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

Anger millisekunder enligt lokal tid och returnerar den nya tiden i millisekunder. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Parametrar

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

Anger minuter enligt lokal tid och returnerar den nya tiden i millisekunder. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Parametrar

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

Anger månaden och eventuellt dagen i månaden enligt lokal tid och returnerar den nya tiden i millisekunder. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Parametrar

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

Anger sekunder enligt lokal tid och returnerar den nya tiden i millisekunder. Lokal tid avgörs av det operativsystem som Flash-miljöerna körs på.

Parametrar

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

Anger datum i millisekunder sedan midnatt 1 januari 1970 och returnerar den nya tiden i millisekunder.

Parametrar

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

Anger dagen i månaden enligt universaltid (UTC) och returnerar den nya tiden i millisekunder. Andra fält i det angivna Date-objektet påverkas inte när den här metoden anropas men Date.getUTCDay() och Date.getDay() kan rapportera ett nytt värde om veckodagen ändras på grund av att metoden anropas.

Parametrar

Relaterade API-element

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

Anger året enligt universaltid (UTC) och returnerar den nya tiden i millisekunder.

Du kan också använda metoden för att ställa in månaden och dagen i månaden. Andra fält påverkas inte när den här metoden anropas men Date.getUTCDay() och Date.getDay() kan rapportera ett nytt värde om veckodagen ändras på grund av att metoden anropas.

Parametrar

Relaterade API-element

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

Anger timmen enligt universaltid (UTC) och returnerar den nya tiden i millisekunder. Minuterna, sekunderna och millisekunderna kan också anges.

Parametrar

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

Anger millisekunder enligt universaltid (UTC) och returnerar den nya tiden i millisekunder.

Parametrar

var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

Anger minuter enligt universaltid (UTC) och returnerar den nya tiden i millisekunder. Du kan också ange sekunder och millisekunder.

Parametrar

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

Anger månaden och eventuellt dagen enligt universaltid (UTC) och returnerar den nya tiden i millisekunder. Andra fält påverkas inte när den här metoden anropas men Date.getUTCDay() och Date.getDay() kan rapportera ett nytt värde om veckodagen ändras på grund av att metoden anropas.

Parametrar

Relaterade API-element

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

Anger sekunder och eventuellt millisekunder enligt universaltid (UTC) och returnerar den nya tiden i millisekunder.

Parametrar

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

Returnerar en strängbeteckning för enbart dag och datum. Tid och tidszon ingår inte. Skiljer sig från följande metoder:

• Date.toTimeString() som endast returnerar tid och tidszon
• Date.toString() som inte endast returnerar dag och datum utan även tid och tidszon.

Relaterade API-element

var now:Date = new Date();
trace(now);
trace(now.toDateString());

Erbjuder en åsidosättningsbar metod för att anpassa JSON-kodning av värden i ett Date-objekt.

I metoden JSON.stringify() eftersöks en toJSON()-metod för varje objekt som flyttas. Om metoden toJSON() hittas, anropar JSON.stringify() den för varje värde som upptäcks och anger nyckeln som är kopplad till värdet.

Date erbjuder en standardimplementering av toJSON() som returnerar utdata för Date.toString(). Klienter som vill exportera Date-objekt till JSON i något annat format kan använda egna implementeringar. Du kan göra detta genom att omdefiniera metoden toJSON() på klassprototypen.

Metoden toJSON() kan returnera alla typer av värden. Om ett objekt returneras kommer stringify() att repeteras i objektet. Om toJSON() returnerar en sträng, kommer stringify() inte att repeteras och genomgången fortsätter.

Parametrar

Relaterade API-element

Returnerar en strängbeteckning för enbart dag och datum. Tid och tidszon ingår inte. Den här metoden returnerar samma värde som Date.toDateString. Skiljer sig från följande metoder:

• Date.toTimeString() som endast returnerar tid och tidszon
• Date.toString() som inte endast returnerar dag och datum utan även tid och tidszon.

Relaterade API-element

Returnerar en strängbeteckning för dag, datum och tid i lokal tid. Skiljer sig från metoden Date.toString() som returnerar samma information (plus tidszon) med året i slutet av strängen.

Returnerar en strängbeteckning för enbart tid. Dag, datum, år och tidszon ingår inte. Skiljer sig från metoden Date.toTimeString() som returnerar tid och tidszon.

Relaterade API-element

Returnerar en strängbeteckning för dag, datum, tid och tidszon. Datumformatet för utdata är:

     Day Mon Date HH:MM:SS TZD YYYY
     

Till exempel:

     Wed Apr 12 15:30:17 GMT-0700 2006
     

var now:Date = new Date();
trace(now);

Returnerar en strängbeteckning för enbart tid och tidszon. Dag och datum ingår inte. Skiljer sig från metoden Date.toDateString() som endast returnerar dag och datum.

Relaterade API-element

Returnerar en strängbeteckning för dag, datum och tid i universaltid (UTC). Datumet 1 februari 2005 returneras som Tue Feb 1 00:00:00 2005 UTC.

Relaterade API-element

Returnerar antalet millisekunder mellan midnatt 1 januari 1970 universal tid och den tid som anges i parametrarna. Metoden använder universaltid där konstruktorn Date använder lokal tid.

Metoden är användbar om du vill skicka ett universaldatum till konstruktorn för Date-klassen. Eftersom konstruktorn för Date-klassen accepterar millisekundsförskjutningen som ett argument kan du använda metoden Date.UTC() när du konverterar UTC-datum till motsvarande millisekundsförskjutning och skicka förskjutningen som ett argument till konstruktorn för Date-klassen:

Parametrar

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

Returnerar antalet millisekunder sedan midnatt 1 januari 1970, universal tid, för ett Date-objekt.