Bitmap  - AS3

BitmapData-objektet som refereras.

Avgör om Bitmap-objektet ska fästas mot närmsta pixel eller inte. PixelSnapping-klassen innefattar möjliga värden:

• PixelSnapping.NEVER – Ingen pixelfästning sker.
• PixelSnapping.ALWAYS – Bilden fästs alltid vid närmaste pixel, oavsett omformning.
• PixelSnapping.AUTO – Bilden fästs vid närmaste pixel om den har ritats utan rotation eller skevning och med en skalfaktor på 99,9 till 100,1 %. Om dessa villkor är uppfyllda ritas bitmappsbilden i skalan 100 % och fästs vid närmaste pixel. Internt gör detta värde det möjligt att rita bilden så snabbt som möjligt med hjälp av vektorrenderaren.

Avgör om bitmappsbilden ska utjämnas när den skalas. Om true utjämnas bitmappsbilden när den skalas. Om false utjämnas bitmappsbilden inte när den skalas.

Initierar ett Bitmap-objekt som refererar till det angivna BitmapData-objektet.

	bitmapData:BitmapData (default = null) — BitmapData-objektet som refereras.
	pixelSnapping:String (default = "auto") — Om Bitmap-objektet ska fästas mot närmsta pixel eller inte.
	smoothing:Boolean (default = false) — Om bitmappsbilden ska utjämnas när den skalas. De exempel som följer visar exempelvis samma bitmapp skalad med en faktor 3, med utjämning satt till false (vänster) respektive true (höger):

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. En url-egenskap skapas bestående av bildfilens plats och namn
2. Klasskonstruktorn anropar configureAssets()-metoden, som i sin tur anropar completeHandler()-metoden.
3. configureAssets() skapar ett inläsningsobjekt, som instansierar en händelseavlyssnare som skickas när completeHandler() slutför bildmanipuleringen.
4. Sedan skapar buildChild() en ny instans av ett URLRequest-objekt, request, med en överförd url så att filnamnet och platsen blir kända.
5. Begäranobjektet skickas till loader.load()-metoden, som läser in bilden i minnet via ett visningsobjekt.
6. Bilden läggs därefter in i visningslistan, som omedelbart visar bilden på skärmen i koordinaterna x = 0, y = 0.
7. Sedan gör completeHandler()-metoden följande:
   1. Skapar ett andra Loader-objekt, tillsammans med ett Bitmap-objekt, som initieras med Loader-objektet.
   2. Skapar ett andra Bitmap-objekt, dublett, som i sin tur anropar duplicateImage()-metoden, som skapar en dubblett av originalbilden.
   3. Skapar ett BitmapData-objekt som tilldelas till duplicate-objektets BitmapData-objekt.
   4. Skapar ett nytt Rectangle-objekt, som initieras med samma koordinater, bredd och höjd som originalbilden.
   5. Skapar ett nytt Point-objekt, som har standardvärdena x = 0, y = 0.
   6. Skapar följande variabler:
      • operation: applicerar den nya färgen när tröskelvärdet är >= ursprungsvärdet.
      • threshold: det värde varje pixel jämförs med är satt till ljusgrått med ett alfavärde på 0xCC.
      • color: den färg de pixlar som klarar tröskeltestet ställts in på – i det här fallet kraftigt gult.
      • mask: satt till raka motsatsen till färg (genomskinligt blått).
      • copySource: satt till false, vilket anger att pixelvärdena inte kopieras om tröskelvärdet inte godkänns. Detta värde är betydelselöst eftersom bilden är dubblerad och endast de pixlar som klarar tröskeln ändras.
   7. Anropar threshold()-metoden med de föregående variablerna. Den resulterande tröskelekvationen ser ut så här: om (aktuellt pixelvärde & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) sätts pixeln till 0xFFFFFF00.

Anteckningar:

• Du måste kompilera SWF-filen med "Lokal uppspelningssäkerhet" inställt på "Använd bara lokala filer".
• I det här exemplet måste en fil med namnet Image.gif placeras i samma katalog som din SWF-fil.
• Vi rekommenderar att du använder en bild med en bredd på upp till 80 pixlar.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}