DisplayObjectContainer  - AS3

Avgör om objektets underordnade objekt är aktiverade för en mus eller annan användarindataenhet (eller inte). Om ett objekt är aktiverat kan användaren interagera med det via en mus eller annan användarindataenhet. Standardvärdet är true.

Denna egenskap är användbar när du skapar en knapp med en Sprite-klassinstans (i stället för att använda SimpleButton-klassen). När du använder en Sprite-instans för att skapa en knapp kan du välja att dekorera knappen genom att använda addChild()-metoden för att lägga till ytterligare Sprite-instanser. Denna process kan leda till oväntat beteende med mushändelser eftersom de Sprite-instanser du lägger till som underordnade kan bli målobjektet för en mushändelse när du förväntar dig att den överordnade instansen ska vara målobjektet. För att säkerställa att den överordnade instansen används som målobjekt för mushändelser kan du sätta mouseChildren-egenskapen för den överordnade instansen till false.

Ingen händelse skickas när denna egenskap sätts. Du måste använda addEventListener()-metoden för att skapa interaktiv funktionalitet.

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Returnerar antalet underordnade objekt det här objektet har.

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Avgör om objektets underordnade objekt är tabbaktiverade. Aktiverar eller inaktiverar tabbar för objektets underordnade. Standardvärdet är true.

Obs! Använd inte egenskapen tabChildren med Flex. Använd egenskapen mx.core.UIComponent.hasFocusableChildren i stället.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Returnerar ett TextSnapshot-objekt för den här DisplayObjectContainer-instansen.

Relaterade API-element

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

Anrop till konstruktorn new DisplayObjectContainer() ger ett ArgumentError-undantag. Du kan emellertid anropa konstruktorer för följande underklasser till DisplayObjectContainer:

• new Loader()
• new Sprite()
• new MovieClip()

Lägger till en underordnad DisplayObject-instans i den här DisplayObjectContainer-instansen. Den underordnade läggs till framför (över) alla andra underordnade i denna DisplayObjectContainer-instans. (För att lägga till en underordnad till en specifik indexposition använder man addChildAt()-metoden.)

Om du lägger till ett underordnat objekt som redan har en annan visningsobjektbehållare som överordnad tas objektet bort från det andra visningsobjektets lista med underordnade.

Obs! Kommandot stage.addChild() kan orsaka problem med en publicerad SWF-fil, bl.a. säkerhetsproblem och konflikter med andra inlästa SWF-filer. Det finns bara en scen i en Flash-miljöinstans, oavsett hur många SWF-filer som läses in till miljön. Objekt bör därför egentligen aldrig läggas till direkt på scenen. Det enda objekt som bör finnas på scenen är rotobjektet. Skapa ett DisplayObjectContainer-objekt som ska innehålla alla objekt i visningslistan. Om det behövs lägger du därefter till den DisplayObjectContainer-instansen på scenen.

Parametrar

Relaterade API-element

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Lägger till en underordnad DisplayObject-instans i den här DisplayObjectContainer-instansen. Den underordnade läggs till i den specificerade indexpositionen. Ett indexvärde på 0 står för visningslistans baksida (botten) för detta DisplayObjectContainer-objekt.

I följande exempel visas tre visningsobjekt, betecknade a, b och c, i indexpositionerna 0, 2 och 1:

Om du lägger till ett underordnat objekt som redan har en annan visningsobjektbehållare som överordnad tas objektet bort från det andra visningsobjektets lista med underordnade.

Parametrar

Relaterade API-element

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Anger om säkerhetsrestriktionerna kan göra att visningsobjekt utelämnas från listan som returneras när DisplayObjectContainer.getObjectsUnderPoint()-metoden anropas med den angivna point-punkten. Normalt kan innehåll från en domän inte komma åt objekt från en annan domän, om de inte får tillstånd att göra det via ett anrop till metoden Security.allowDomain(). Mer information om säkerhet finns i avsnittet Security på Flash Player Developer Center.

point-parametern återfinns i scenens koordinatområde, som kan skilja sig från visningsobjektbehållarens koordinatområde (om visningsobjektbehållaren inte är scenen). Du kan använda globalToLocal()- och localToGlobal()-metoderna för att konvertera punkter mellan dessa koordinatområden.

Parametrar

Relaterade API-element

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Avgör om det angivna visningsobjektet är underordnat DisplayObjectContainer-instansen eller själva instansen. Sökningen omfattar hela visningslistan, inklusive denna DisplayObjectContainer-instans. Indirekta underordnade, indirekt indirekt underordnade, och så vidare, returnerar alla true.

Parametrar

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Returnerar den underordnade visningsobjektsinstansen som finns vid det angivna indexvärdet.

Parametrar

Relaterade API-element

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Returnerar det underordnade visningsobjektet som har ett visst namn. Om mer än ett underordnat objekt har det angivna namnet returnerar metoden det första objektet i listan med underordnade.

getChildAt()-metoden är snabbare än getChildByName()-metoden. getChildAt()-metoden hittar en underordnad i en cache-lagrad array, under det att getChildByName()-metoden måste gå igenom en länkad lista för att hitta en underordnad.

Parametrar

Relaterade API-element

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Returnerar indexpositionen för en child-DisplayObject-instans.

Parametrar

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Returnerar en array med objekt som ligger under den angivna punkten och är underordnade (eller indirekt underordnade) den här DisplayObjectContainer-instansen. Eventuella underordnade objekt som inte går att nå av säkerhetsskäl är inte med i den returnerade arrayen. Anropa areInaccessibleObjectsUnderPoint()-metoden för att ta reda på om denna säkerhetsbegränsning påverkar den returnerade arrayen.

point-parametern återfinns i scenens koordinatområde, som kan skilja sig från visningsobjektbehållarens koordinatområde (om visningsobjektbehållaren inte är scenen). Du kan använda globalToLocal()- och localToGlobal()-metoderna för att konvertera punkter mellan dessa koordinatområden.

Parametrar

Relaterade API-element

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Tar bort den angivna child-DisplayObject-instansen från listan med underordnade för DisplayObjectContainer-instansen. Den borttagna underordnades parent-egenskap sätts till null och objektet skräpsamlas om det inte finns några andra referenser till den underordnade. Indexpositionerna för eventuella visningsobjekt över det det underordnade i DisplayObjectContainer stegas ner med 1.

Skräpinsamlaren allokerar om oanvänt minnesutrymme. När en variabel eller ett objekt inte längre aktivt refereras till, eller sparas någonstans, sveper skräpinsamlaren igenom och torkar bort det minnesutrymme som den/det förut använde, om det inte finns någon referens till den/det.

Parametrar

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Tar bort ett underordnat DisplayObject från den angivna index-positionen i den underordnade listan i DisplayObjectContainer. Den borttagna underordnades parent-egenskap sätts till null och objektet skräpsamlas om det inte finns några andra referenser till den underordnade. Indexpositionerna för eventuella visningsobjekt över det det underordnade i DisplayObjectContainer stegas ner med 1.

Skräpinsamlaren allokerar om oanvänt minnesutrymme. När en variabel eller ett objekt inte längre aktivt refereras till, eller sparas någonstans, sveper skräpinsamlaren igenom och torkar bort det minnesutrymme som den/det förut använde, om det inte finns någon referens till den/det.

Parametrar

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Tar bort alla child-DisplayObject-instanser från listan med den underordnade DisplayObjectContainer-instansen. Den borttagna underordnades parent-egenskap sätts till null och objektet skräpsamlas om det inte finns några andra referenser till den underordnade.

Skräpinsamlaren allokerar om oanvänt minnesutrymme. När en variabel eller ett objekt inte längre aktivt refereras till, eller sparas någonstans, sveper skräpinsamlaren igenom och torkar bort det minnesutrymme som den/det förut använde, om det inte finns någon referens till den/det.

Parametrar

Ändrar positionen för ett befintligt underordnat objekt i behållaren för visningsobjekt. Detta påverkar skiktningen av underordnade objekt. I följande exempel visas tre visningsobjekt, betecknade a, b och c, i indexpositionerna 0, 1 och 2:

När du använder setChildIndex()-metoden och anger en index-position som redan är upptagen, är de enda positioner som kan ändras de som ligger mellan visningsobjektets tidigare och nya position. Alla andra förblir desamma. Om en underordnad flyttas till ett index som är LÄGRE än dess nuvarande index kommer alla underordnade emellan att ÖKA med 1 i sin indexreferens. Om en underordnad flyttas till ett index som är HÖGRE än dess nuvarande index kommer alla underordnade emellan att MINSKA med 1 i sin indexreferens. Om visningsobjektbehållaren i föregående exempel exempelvis har namnet container så kan du växla positionerna för de visningsobjekt som är betecknade a och b genom att anropa följande kod:

container.setChildIndex(container.getChildAt(1), 0);

Denna kod leder till följande objektordning:

Parametrar

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Stoppar rekursivt tidslinjekörning av alla filmklipp vars rot är detta objekt.

Underordnade visningsobjekt som tillhör en sandlåda som körningskoden inte har tillgång till ignoreras.

Obs! Direktuppspelande media som styrs via ett NetStream-objekt stoppas inte.

Byter z-ordningen (framifrån och bakåt-ordning) för de två underordnade objekten. Samtliga övriga underordnade objekt i visningsobjektbehållaren blir kvar i samma indexpositioner.

Parametrar

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Byter z-ordningen (framifrån och bakåt-ordning) för underordnade objekt vid de två angivna indexpositionerna i listan med underordnade objekt. Samtliga övriga underordnade objekt i visningsobjektbehållaren blir kvar i samma indexpositioner.

Parametrar

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. Konstruktorn anropar configureAssets()-metoden.
2. configureAssets()-metoden skapar child- och lastChild-Sprite-objekt.
3. En for-slinga skapar de fem fyrkanterna och placerar dem efter varandra.
4. Varje gång ett CustomSprite-objekt skapas anropar dess konstruktor draw()-metoden för CustomSprite-objektet, vilket skapar en ruta på 50 x 50 pixlar genom att anropa beginFill()-, drawRect()- och endFill()-metoderna för Graphics-klassen. addChild()-metoden lägger till varje fyrkant till visningslistan.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}