Sprite  - AS3

Anger knappläge för den här spriten. Om true uppför sig denna sprite som en knapp, vilket betyder att den utlöser visningen av handmarkören när pekaren passerar över spriten och kan ta emot en click-händelse om enter eller mellanslag trycks ner när spriten är i fokus. Du kan undertrycka visningen av handmarkören genom att sätta useHandCursor-egenskapen till false, vilket medför att pekaren visas.

Det är bättre att använda klass SimpleButton för att skapa knappar, men du kan använda buttonMode-egenskapen för att ge en sprite vissa knappliknande funktioner. För att ta med en sprite i tabbordningen sätter man tabEnabled-egenskapen (som ärvts från klass InteractiveObject och är false som standard) till true. Tänk också på om du vill att din sprites underordnade ska vara aktiverade för användarinmatningar. De flesta knappar aktiverar inte användarindatainteraktivitet för sina underordnade objekt eftersom det stör händelseflödet. För att inaktivera användarindatainteraktivitet för samtliga underordnade objekt måste du sätta mouseChildren-egenskapen (som ärvts från klassen DisplayObjectContainer) till false.

Om du använder buttonMode-egenskapen med klass MovieClip (som är en underklass till klass Sprite) kan din knapp ha vissa ytterligare funktioner. Om du tar tar med bildrutorna labeled _up, _over, och _down tillhandahåller Flash Player automatiska statusändringar (funktioner som liknar dem hos tidigare versioner av ActionScript för filmklipp som används som knappar). Dessa automatiska statusändringar finns inte tillgängliga för spriter, som inte har något tidslinje och därför inga bildrutor att etikettera.

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Anger det visningsobjekt som spriten dras över, eller som spriten släpptes på.

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Anger det Graphics-objekt som tillhör denna sprite där kommandon för vektorritning kan göras.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Utser en annan sprite som ska fungera som träffområde för en sprite. Om hitArea-egenskapen saknas, eller om värdet är null eller odefinierat, används själva spriten som träffområde. Värdet för hitArea-egenskapen kan utgöras av en referens till ett Sprite-objekt.

Du kan ändra egenskapen hitArea när som helst. Den ändrade spriten får omedelbart det nya träffområdesbeteendet. Det sprite som valts som träffområde behöver inte vara synligt. Dess grafiska form fungerar fortfarande som träffområde även om det inte syns.

Obs! Du måste välja false för egenskapen mouseEnabled för den sprite som är träffområdet. I annat fall fungerar spriteknappen eventuellt inte eftersom den sprite som valts som träffområde tar emot användarindatahändelser i stället för din spriteknapp.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Styr ljudet i den här spriten.

Obs! Den här egenskapen påverkar inte HTML-innehåll i ett HTMLControl-objekt (i Adobe AIR).

Relaterade API-element

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Ett booleskt värde som anger om den pekande handen (handpekaren) ska visas när pekaren passerar över en sprite, vars buttonMode-egenskap är true. Standardvärdet för useHandCursor-egenskapen är true. Om useHandCursor sätts till true visas den pekande handen som används för knappar när pekaren passerar över en knappsprite. Om useHandCursor är false används pilmarkören i stället.

Du kan ändra egenskapen useHandCursor när som helst. Den ändrade spriten får automatiskt det nya markörutseendet.

Obs! Om ditt sprite-objekt i Flex eller Flash Builder har underordnade sprite-objekt kan det vara lämpligt att ange egenskapen mouseChildren som false. Om du till exempel vill att en handpekare visas över en Flex <mx:Label>-kontroll, ställer du in useHandCursor- och buttonMode-egenskaperna till true och mouseChildren-egenskapen till false.

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Skapar en ny Sprite-instans. När du har skapat Sprite-instansen ska du anropa DisplayObjectContainer.addChild()- eller DisplayObjectContainer.addChildAt()-metoden för att lägga till denna Sprite till en överordnad DisplayObjectContainer.

Gör att användaren kan dra angiven sprite. Spriten fortsätter att vara dragbar tills den uttryckligen stoppas genom ett anrop till Sprite.stopDrag()-metoden eller tills en annan sprite görs dragbar. Bara en sprite kan vara dragbar åt gången.

Tredimensionella visningsobjekt följer pekaren och Sprite.startDrag() flyttar objektet inuti det tredimensionella planet som definieras av visningsobjektet. Om visningsobjektet är ett tvådimensionellt objekt och dessutom är ett underordnat objekt till ett tredimensionellt objekt, flyttas det tvådimensionella objektet inuti det tredimensionella plan som definieras av det överordnade tredimensionella objektet.

Parametrar

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Låter användaren dra angiven sprite på en beröringsaktiverad enhet. Spriten fortsätter att vara dragbar tills den uttryckligen stoppas genom ett anrop till Sprite.stopTouchDrag()-metoden eller tills en annan sprite görs dragbar. Bara en sprite kan vara dragbar åt gången.

Tredimensionella visningsobjekt följer pekaren och Sprite.startTouchDrag() flyttar objektet inuti det tredimensionella planet som definieras av visningsobjektet. Om visningsobjektet är ett tvådimensionellt objekt och dessutom är ett underordnat objekt till ett tredimensionellt objekt, flyttas det tvådimensionella objektet inuti det tredimensionella plan som definieras av det överordnade tredimensionella objektet.

Parametrar

Relaterade API-element

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Avslutar startDrag()-metoden. En sprite som gjorts dragbart med startDrag()-metoden förblir dragbart tills en stopDrag()-metod läggs till eller tills en annan sprite blir dragbar. Bara en sprite kan vara dragbar åt gången.

Relaterade API-element

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Avslutar metoden startTouchDrag(), som används med beröringsaktiverade enheter. En sprite som gjorts dragbart med metoden startTouchDrag() förblir dragbar tills en stopTouchDrag()-metod läggs till eller tills en annan sprite blir dragbar. Bara en sprite kan vara dragbar åt gången.

Parametrar

Relaterade API-element

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. Deklarera size-egenskapen (100 x 100 pixlar) och bakgrundsfärgen (orange) för senare användning när fyrkanten ritas.
2. Sedan skapar konstruktorn ett nytt underordnat Sprite-objekt och använder det för att lägga till två händelseavlyssnare och deras tillhörande metoder: mouseDownHandler() och mouseUpHandler().
3. Det underordnade Sprite-objektet överförs sedan till draw()-metoden, som ritar den orange fyrkanten.
4. Det underordnade objektet placeras sedan i visningslistan av ett anrop till addChild()-metoden.
5. Händelseavlyssnarna fungerar så här:
   • mouseDownHandler(): när användaren klickar på Sprite-objektet lägger denna metod till en mouseMove-händelseavlyssnaren, mouseMoveHandler()-metoden, som behandlar musrörelserna. startDrag()-metoden anropas så att Sprite-objektet kan dras.
   • mouseUpHandler(): när musknappen släpps upp tas mouseMove-händelseavlyssnaren bort och stopDrag()-metoden anropas och fryser den orange fyrkanten på sin plats.
   • mouseMoveHandler: så länge den vänstra musknappen hålls nedtryckt instruerar denna metod spelaren att kontinuerligt rita om den orange fyrkanten.

Obs: Var och en av händelseavlyssnarmetoderna deklarerar en lokal sprite-variabel, som tilldelas händelsens target-egenskap.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}