SimpleButton  - AS3

Anger ett visningsobjekt som används som visuellt objekt för knappens nedläge – det läge knappen är i när användaren markerar hitTestState-objektet.

Relaterade API-element

Ett booleskt värde som anger om en knapp är aktiverad. När en knapp är inaktiverad (egenskapen aktiverad är inställd på false) är knappen synlig, men det går inte att klicka på den. Standardvärdet är true. Den här egenskapen är praktisk om du vill inaktivera en del av navigeringsfunktionen. Du kanske till exempel vill inaktivera en knapp på den sida som visas så att det inte går att klicka på den och sidan inte kan läsas in på nytt.

Obs!Du kan förhindra mouseClicks på en knapp genom att ställa in egenskaperna för både enabled och mouseEnabled på false.

Anger ett visningsobjekt som används som träfftestobjekt för knappen. För en basknapp sätter man egenskapen hitTestState till samma visningsobjekt som egenskapen overState. Om du inte ställer in egenskapen hitTestState blir SimpleButton inaktiv – den svarar då inte på användarindatahändelser.

Relaterade API-element

Anger ett visningsobjekt som används som visuellt objekt för knappens överläge – det läge knappen är i när pekaren är placerad över knappen.

Relaterade API-element

Det SoundTransform-objekt som är tilldelat knappen. Ett SoundTransform-objekt innehåller egenskaper för inställning av volym, panorering och vänstra och högra högtalaren. Detta SoundTransform-objekt gäller för alla knappens tillstånd. Detta SoundTransform-objekt påverkar bara inbäddade ljud.

Relaterade API-element

Anger om andra visningsobjekt som är SimpleButton-objekt eller MovieClip-objekt kan ta emot släppningshändelser från användarindata. Med egenskapen trackAsMenu kan du skapa menyer. Du kan sätta egenskapen trackAsMenu på valfritt SimpleButton- eller MovieClip-objekt. Om egenskapen trackAsMenu inte finns är standardbeteendet false.

Du kan ändra egenskapen trackAsMenu när som helst. Den ändrade knappen får automatiskt det nya beteendet.

Anger ett visningsobjekt som används som visuellt objekt för knappens uppläge – det läge knappen är i när pekaren inte är placerad över knappen.

Relaterade API-element

Ett booleskt värde som, när det är true, anger om handpekaren visas när pekaren passerar över en knapp. Om egenskapen är inställd på false används i stället en pilmarkör. Standardvärdet är true.

Du kan ändra egenskapen useHandCursor när som helst. Den knappen får det nya markörbeteendet direkt.

Skapar en ny SimpleButton-instans. Något av eller samtliga de visningsobjekt som representerar de olika knapptillstånden kan sättas som parametrar i konstruktorn

1. I konstruktor SimpleButtonExample() skapas ett nytt CustomSimpleButton-objekt av typ SimpleButton, med namnet button, som anropar konstruktormetodCustomSimpleButton. Sedan läggs objekt button till i visningslistan. Knappens form och storlek bestäms i de steg som följer.
2. I klass CustomSimpleButton deklareras instansegenskaper som sedan används för att bestämma storleken på och bakgrundsfärgen för button, på basis av dess tillstånd (orange i normaltillståndet, mörkgrön i musövertillståndet och ljusblå i musnertillståndet). I samtliga tillstånden för button sätts storleken på fyrkanten till 80 pixlar med hjälp av egenskapen size.
3. Konstruktorfunktionen för klass CustomSimpleButton sätter egenskaperna downState, overState, upState, hitTestState och useHandCursor med fyra instanser av klass ButtonDisplayState.
4. I klass ButtonDisplayState sätter konstruktorn värdet för fyrkantens storlek och bakgrundsfärg och anropar metoden draw().
5. Metod draw() ritar om fyrkanten med den storlek och bakgrundsfärg som bestämdes i konstruktorn på basis av knappens tillstånd.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}