AccessibilityImplementation  - AS3

Anger en felkod. Fel visas vanligtvis som onaturliga värden och inte som returvärden. För att ange ett fel ställer du in egenskapen errno till en av de felkoder som finns dokumenterade i bilagan med AccessibilityImplementation-konstanter. Detta medför att returvärdet ignoreras. Egenskapen errno för AccessibilityImplementation rensas alltid (sätts till noll) av spelaren innan någon AccessibilityImplementation-metod anropas.

Relaterade API-element

Används för att skapa en komponenthjälpmedels-stub. Om en komponent frisläpps utan en ActionScript-hjälpmedelsimplementation, rekommenderar Adobe att du lägger en komponenthjälpmedels-stub. Denna stub får till följd att Flash Player, för att underlätta hjälpmedelshanteringen, behandlar komponenten som enkel grafik i stället för att visa den interna strukturen av bland annat knappar och textfält i komponenten.

Om du vill skapa en komponenthjälpmedels-stub, underklass till aktuell AccImpl-klass, ska stub-egenskapen åsidosättas med värdet true.

Relaterade API-element

Statisk konstruktor. Du ska inte instansiera AccessibilityImplementation direkt genom att anropa dess konstruktor. Skapa i stället nya hjälpmedelsimplementationer genom att utvidga mx.accessibility.Acc-klassen för varje ny komponent.

Relaterade API-element

En IAccessible-metod som utför standardåtgärden som är associerad med komponenten som denna AccessibilityImplementation representerar eller ett av dess underordnade element.

Implementera denna metod endast om AccessibilityImplementation representerar ett gränssnittselement som har en standardåtgärd i MSAA-modellen.

Om du endast implementerar accDoDefaultAction() för själva AccessibilityImplementation eller för dess underordnade element, kommer du i vissa fall att behöva ange att det inte finns någon standardåtgärd för det speciella childID som skickades. Du gör detta genom att ange att egenskapen errno ska vara E_MEMBERNOTFOUND.

Parametrar

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

Metoden MSAA för att returnera ett DisplayObject eller Rectangle som anger begränsningsramen för ett underordnat element i AccessibilityImplementation.

Den här metoden anropas aldrig för ett childID som är noll. Om AccessibilityImplementation aldrig kommer att innehålla underordnade element ska du inte implementera den här metoden. Om AccessibilityImplementation kan innehålla underordnade element är den här metoden obligatorisk.

Du kan vanligtvis uppfylla kraven för den här metoden genom att returnera ett objekt som representerar det underordnade elementet. Detta fungerar så länge som det underordnade elementet är ett DisplayObject-objekt. I dessa fall ska du bara returnera DisplayObject-objektet som motsvarar instansnamnet som är associerat med det relevanta visuella objektet i visningslistan.

Om ett underordnat element inte är kvalificerat för tekniken som beskrivs ovan, måste du själv räkna ut begränsningsramen och returnera en Rectangle med egenskaperna x, y, width och height. Medlemmarna x och y anger det över vänstra hörnet i begränsningsramen och width och height anger storleken. Alla fyra medlemmar ska anges i scenpixlar relativt till origo för komponenten som AccessibilityImplementation representerar. Egenskaperna x och y kan ha negativa värden, eftersom origo för ett DisplayObject-objekt inte behöver ligga i det övre vänstra hörnet.

Om det underordnade elementet som anges med childID inte visas (dvs. get_accState för det underordnade elementet returnerar ett värde som innehåller STATE_SYSTEM_INVISIBLE), kan du returnera null från accLocation. Du kan även returnera en Rectangle som representerar koordinaterna där det underordnade elementet skulle visas om det var synligt.

Parametrar

Lär dig mer

Relaterade API-element

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

Metoden IAccessible för att ändra markeringen i komponenten som denna AccessibilityImplementation representerar.

Parametern childID kommer alltid att ha ett värde som inte är noll. Den här metoden tillämpas på ett underordnat element och inte på den övergripande komponenten. I Flash Player hanteras den övergripande komponenten.

Parametern selFlag är ett bit-fält som består av en eller flera urvalsflaggskonstanter som gör att en MSAA-klient kan visa hur objektet som refereras av childID ska markeras och sättas i fokus. Vad som följer är beskrivningar av urvalsflaggskonstanter och vad de visar vid hjälpmedelsimplementeringen. Av praktiska skäl kommer de flesta implementeringarna av den här metoden i hjälpmedelsimplementeringar, som ärver från Flex-klassen mx.accessibility.ListBaseAccImpl, att ignorera selFlag-konstanten och i stället förlita sig på komponentens tangentmarkeringsbeteende för att hantera flera markeringar.

Parametern selFlag behöver inte innehålla flaggan SELFLAG_TAKEFOCUS. Om den gör det ska du ange angivet childID som underordnat fokus och, såvida SELFLAG_EXTENDSELECTION också finns närvarande, göra det underordnade elementet till markeringsfästpunkt. I övriga fall ska underordnat fokus och markeringsfästpunkten lämnas som de är, trots att ytterligare flaggor som beskrivs nedan kan ändra markeringen.

Argumentet selFlag innehåller alltid en av följande fyra flaggor, som anger vilken markeringsförändring som är önskvärd:

• SELFLAG_TAKESELECTION: Tar bort eventuell markering och låter markeringen få värdet i angivet childID.

• SELFLAG_EXTENDSELECTION: Beräknar intervallet för underordnade element mellan och inklusive markeringsfästpunkt och angivet childID. Om SELFLAG_ADDSELECTION finns närvarande ska du lägga till alla dessa underordnade element till markeringen. Om SELFLAG_REMOVESELECTION finns närvarande ska du ta bort alla dessa underordnade element från markeringen. Om varken SELFLAG_ADDSELECTION eller SELFLAG_REMOVESELECTION finns närvarande, ska alla underordnade element anta markeringsfästpunktens markeringsstatus. Om markeringsfästpunkten är markerad ska du lägga till dessa underordnade element till markeringen eller i annat fall ta bort dem från markeringen.

• SELFLAG_ADDSELECTION (utan SELFLAG_EXTENDSELECTION): Lägg till angivet childID till markeringen.

• SELFLAG_REMOVESELECTION (utan SELFLAG_EXTENDSELECTION): Ta bort angivet childID från markeringen.

Observera att för en komponent som inte går att markera flera gånger, är de enda giltiga selFlag-parametervärdena SELFLAG_TAKEFOCUS och SELFLAG_TAKESELECTION. Du kan i teorin även välja att stödja SELFLAG_REMOVESELECTION för en komponent som inte går att markera flera gånger och som tillåter att användaren får göra en null-markering, men i praktiken fungerar de flesta komponenter som inte går att markera flera gånger inte på det här sättet och MSAA-klienter kanske inte kommer att genomföra den här typen av operation.

Om du upptäcker flaggor som verkar ogiltiga ska du ange att errno ska vara E_INVALIDARG.

Observera slutligen att när accSelect anropas, ser Flash Player till att den har värdfokus (fönsterfokus för dess behållarprogram) och att din komponent har fokus inom Flash Player.

Parametrar

Lär dig mer

Relaterade API-element

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

MSAA-metod för att returnera standardåtgärden för komponenten som denna AccessibilityImplementation representerar eller för ett av dess underordnade element.

Implementera denna metod endast om AccessibilityImplementation representerar ett gränssnittselement som har en standardåtgärd i MSAA-modellen. Se till att returnera strängen exakt så som den anges i MSAA-modellen. Till exempel är standardåtgärdssträngen för en Button-komponent "Press."

Om du endast implementerar get_accDefaultAction för själva AccessibilityImplementation eller för dess underordnade element, kommer du i vissa fall att behöva ange att det inte finns någon standardåtgärd för det speciella childID som skickades. Du gör detta genom att returnera null.

Parametrar

Lär dig mer

Relaterade API-element

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

MSAA-metod för att returnera eventuellt heltals-ID utan tecken för det underordnade elementet, som har underordnat fokus inom komponenten. Om ingen underordning har underordnat fokus kommer metoden att returnera noll.

Lär dig mer

Relaterade API-element

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

MSAA-metod för att returnera namnet på komponenten som denna AccessibilityImplementation representerar eller för ett av dess underordnade element.

För AccessibilityImplementation (childID == 0) gäller att om denna metod inte implementeras eller inte returnerar ett värde så kommer Flash Player att använda egenskapsvärdet AccessibilityProperties.name, om ett sådant finns närvarande.

För en AccessibilityImplementation som kan ha underordnade element, måste denna metod vara implementerad och den måste returnera ett strängvärde när childID inte är noll.

Beroende på vilken typ av användargränssnittselement det är kan namn i MSAA ha en av två möjliga betydelser. Det kan antingen vara ett utvecklartilldelat namn eller det faktiska textinnehållet i elementet. Vanligtvis kommer AccessibilityImplementation att tillhöra den tidigare kategorin. Dess name-egenskap är ett utvecklartilldelat namn. Underordnade element tillhör den andra kategorin. Namnen indikerar deras textinnehåll.

När egenskapen name för en AccessibilityImplementation har samma innebörd som ett utvecklartilldelat namn, finns det två sätt som komponenterna kan få namn från utvecklarna. Det första avser namn som redan finns i själva komponenten, till exempel en kryssrutekomponent kan innehålla en textetikett som kan användas som dess namn. Det andra, som är ett reservalternativ för det första, avser namn angivna i gränssnittet och som slutar med AccessibilityProperties.name. Det andra alternativet tillåter att användarna kan ange namn så som de kan göra för andra Sprite eller MovieClip.

Detta resulterar i tre möjligheter för själva AccessibilityImplementation (childID == noll):

• Utvecklartilldelat namn i komponent. Metoden get_accName ska vara implementerad och returnera ett strängvärde som innehåller namnet på AccessibilityImplementation när childID är noll. Om childID är noll men AccessibilityImplementation saknar namn, ska get_accName returnera en tom sträng för att förhindra att spelaren faller tillbaka till egenskapen AccessibilityProperties.name.

• Utvecklartilldelat namn från gränssnittet. Om AccessibilityImplementation kan innehålla underordnade element, ska metoden get_accName implementeras men den ska inte returnera ett värde när childID är noll. Om AccessibilityImplementation aldrig kommer att innehålla underordnade element, ska inte get_accName implementeras.

• Namn som anger innehåll. Metoden get_accName ska implementeras och returnera ett strängvärde när childID är noll. Om childId är noll men AccessibilityImplementation saknar innehåll, ska get_accName returnera en tom sträng för att förhindra att spelaren faller tillbaka till egenskapen AccessibilityProperties.name.

Observera att för underordnade element, om det kan finnas i AccessibilityImplementation, gäller alltid det tredje fallet. Metoden get_accName ska implementeras och returnera ett strängvärde när childID inte är noll.

Parametrar

Lär dig mer

Relaterade API-element

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

MSAA-metod för att returnera systemrollen för komponenten som denna AccessibilityImplementation representerar eller för ett av dess underordnade element. Systemroller är fördefinierade för alla komponenter i MSAA.

Parametrar

Lär dig mer

Relaterade API-element

MSAA-metod för att returnera en matris som innehåller ID:n för alla underordnade element som är markerade. Den returnerade matrisen innehåller noll, en eller flera ID:n, alla heltal utan tecken

Lär dig mer

Relaterade API-element

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

IAccessible-metod för att returnera det aktuella körningsläget för komponenten som denna AccessibilityImplementation representerar eller ett av dess underordnade element.

Denna metod måste returnera en kombination av noll, en eller flera fördefinierade objektlägeskonstanter för komponenter i MSAA. När fler än ett läge gäller ska lägeskonstanter kombineras med ett bit-fält där | används, den bitvisa OR-operatorn.

För att ange att ingen av lägeskonstanterna tillämpas för närvarande ska metoden returnera noll.

Du behöver inte spåra eller rapportera lägena STATE_SYSTEM_FOCUSABLE och STATE_SYSTEM_FOCUSED. Dessa lägen hanteras automatiskt i Flash Player.

Parametrar

Lär dig mer

Relaterade API-element

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

MSAA-metod för att returnera körtidsvärdet för komponenten som denna AccessibilityImplementation representerar eller för ett av dess underordnade element.

Implementera denna metod endast om AccessibilityImplementation representerar ett gränssnittselement som har ett värde i MSAA-modellen. Tänk på att vissa gränssnittselement som har ett "värde" kommer de facto att exponera detta värde på olika sätt, till exempel som get_accName (exempelvis text), get_accState (exempelvis kryssrutor) eller get_accSelection (exempelvis listrutor).

Om du endast implementerar get_accValue för själva AccessibilityImplementation eller för dess underordnade element, kommer du i vissa fall att behöva ange att det inte finns något värdekoncept för det speciella childID som skickades. Du gör detta genom att returnera null.

Parametrar

Lär dig mer

Relaterade API-element

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Returnerar en matris som innehåller heltals-ID:n utan tecken för alla underordnade element i AccessibilityImplementation.

Längden på matrisen kan vara noll. ID-värdena i matrisen ska visas i samma logiska ordning som de underordnade elementen som de representerar. Om AccessibilityImplementation kan innehålla underordnade element är den här metoden obligatorisk, i annat fall ska du inte implementera den.

När du tilldelar underordnade ID:n till underordnade element ska du använda ett schema som gör varje instans av din AccessibilityImplementation unik. Underordnade ID:n behöver inte vara löpande och ordningen behöver inte vara densamma som den logiska ordningen för de underordnade elementen. Du ska ordna dem så att inte underordnade ID:n återanvänds. Om ett underordnat element upptäcks ska dess ID inte användas igen så länge som AccessibilityImplementation-instansen finns. På grund av implementationsalternativen i Flash Player-koden ska du tänka på att oönskade beteenden kan uppträda om du använder underordnade ID:n som överstiger en miljon.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Returnerar true eller false för att ange om ett textobjekt som har en begränsningsram som anges med x, y, width och height, ska anses som en etikett för komponenten som denna AccessibilityImplementation representerar.

Koordinaterna x och y är relativa till det övre vänstra hörnet för komponenten som AccessibilityImplementation tillämpas på. Värdena kan vara negativa. Alla koordinater anges i scenpixlar.

Den här metoden gör att hjälpmedelskomponenter kan anpassas till Flash Player-sökningen efter automatiska etikettförhållanden, som medför att text utanför ett objekt kan ange objektets namn. Den här metoden finns eftersom det förväntas att villkoren för att identifiera etiketter varierar mellan olika komponenter. Om du implementerar den här metoden ska du rikta in dig på att använda geometriska villkor som påminner om de som används i spelarkoden för knappar och textfält. Dessa villkor är följande:

• För knappar gäller att all text som finns inom knappen tolkas som en etikett.
• För textfält gäller att all text som visas precis ovanför och vänsterjusterat eller precis till vänster tolkas som en etikett.

Om komponenten som representeras av AccessibilityImplementation aldrig ska omfattas av automatiska etikettförhållanden ska du inte implementera isLabeledBy. Detta motsvarar att alltid returnera false. Ett fall där isLabeledBy inte ska implementeras är när AccessibilityImplementation omfattas av exemplet med "utvecklartilldelat namn i komponent" som beskrivs ovan under get_accName.

Observera att denna metod inte baseras på någon IAccessible-metod. Den gäller speciellt för Flash.

Parametrar