Matrix  - AS3

Värdet som påverkar positioneringen på pixlarna utefter x-axeln vid skalning eller rotering av en bild.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

Värdet som påverkar positioneringen på pixlarna utefter y-axeln vid rotering eller skevning av en bild.

import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

Värdet som påverkar positioneringen på pixlarna utefter x-axeln vid rotering eller skevning av en bild.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

Värdet som påverkar positioneringen på pixlarna utefter y-axeln vid skalning eller rotering av en bild.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

Avståndet som varje punkt ska översättas med på x-axeln.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

Avståndet som varje punkt ska översättas med på y-axeln.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50

Skapar ett nytt Matrix-objekt med de angivna parametrarna. I matrisnotation ordnas egenskaperna så här:

Om du inte anger några parametrar för konstruktorn new Matrix() skapas en identitetsmatris med följande värden:

a = 1

b = 0

c = 0

d = 1

tx = 0

ty = 0

I matrisnotation ser identitetsmatrisen ut så här:

import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)

Returnerar ett nytt Matrix-objekt som är en klon av den här matrisen med en exakt kopia av objektet i den.

Sammanfogar en matris med den aktuella matrisen så att de två matrisernas geometriska effekter kombineras. I matematiska termer är det samma sak att sammanfoga två matriser och att kombinera dem med matrismultiplikation.

Om matrisen m1 exempelvis skalar ett objekt med faktorn fyra och matrisen m2 roterar ett objekt med 1,5707963267949 radianer (Math.PI/2), omvandlarm1.concat(m2) m1 till en matris som skalar ett objekt med faktorn fyra och roterar objektet med Math.PI/2 radianer.

Den här metoden ersätter källmatrisen med den sammanfogade matrisen. Om du vill sammanfoga de två matriserna utan att ändra någon av källmatriserna kan du först kopiera källmatrisen med metoden clone(), vilket visas i avsnittet Klassexempel.

Parametrar

Kopierar ett Vector3D-objekt till en specifik kolumn för anropande Matrix3D-objekt.

Parametrar

Kopierar en specifik kolumn i anropande Matrix-objekt till Vector3D-objektet. Elementet w för Vector3D-objektet kommer inte att ändras.

Parametrar

Kopierar alla matrisdata från källans Point-objekt till anropande Matrix-objekt.

Parametrar

Kopierar ett Vector3D-objekt till en specifik rad för anropande Matrix-objekt.

Parametrar

Kopierar en specifik rad i anropande Matrix-objekt till Vector3D-objektet. Elementet w för Vector3D-objektet kommer inte att ändras.

Parametrar

Inkluderar parametrar för skalning, rotation och translation. När metoden tillämpas på en matris ställs matrisens värden in utifrån dessa parametrar.

Med createBox()-metoden kan du få samma matris som om du använde metoderna identity(), rotate(), scale(), och translate() i följd. Till exempel får mat1.createBox(2,2, Math.PI/4, 100, 100) samma effekt som följande:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Parametrar

Relaterade API-element

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Skapar det angivna matrisformatet som förväntas av metoderna beginGradientFill() och lineGradientStyle()i klassen Graphics. Bredd och höjd skalas till ett scaleX / scaleY-par och värdena tx / ty förskjuts med halva bredden och höjden.

Ta till exempel en övertoning med följande egenskaper:

• GradientType.LINEAR
• Två färger, grönt och blått, med proportionsarrayen inställd på [0, 255]
• SpreadMethod.PAD
• InterpolationMethod.LINEAR_RGB

I följande bilder visas övertoningar där matrisen definierats med hjälp av metoden createGradientBox() med olika parameterinställningar:

createGradientBox()-inställningar	Resulterande övertoning
width = 25; height = 25; rotation = 0; tx = 0; ty = 0;
width = 25; height = 25; rotation = 0; tx = 25; ty = 0;
width = 50; height = 50; rotation = 0; tx = 0; ty = 0;
width = 50; height = 50; rotation = Math.PI / 4; // 45 degrees tx = 0; ty = 0;

Parametrar

Relaterade API-element

package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

Returnerar koordinaterna för en given punkt i koordinatrymden före omformning, efter att omformningen sker. Till skillnad från standardomformningen som används med metoden transformPoint() tar inte deltaTransformPoint()-metodens omformning hänsyn till översättningsparametrarna tx och ty.

Parametrar

Ställer in varje matrisegenskap på ett värde som orsakar en null-omformning. Ett objekt som har omvandlats genom att en identitetsmatris används är identiskt med originalet.

När metoden identity() har anropats har den resulterande matrisen följande egenskaper: a =1, b =0, c =0, d =1, tx =0, ty =0.

I matrisnotation ser identitetsmatrisen ut så här:

Utför motsatt omformning av den ursprungliga matrisen. Du kan tillämpa en omvänd matris på ett objekt för att ångra omformning som gjorts med den ursprungliga matrisen.

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Tillämpar rotationsomformning på Matrix-objektet.

Metoden rotate() ändrar a, b, c och d-egenskaperna i Matrix-objektet. I matrisnotationen är detta samma sak som att sammanfoga den aktuella matrisen med följande:

Parametrar

Tillämpar skalningsomformning på Matrix-objektet. x-axeln multipliceras med sx och y-axeln multipliceras med sy.

Metoden scale() ändrar Matrix-objektets a- ochd-egenskaper. I matrisnotationen är detta samma sak som att sammanfoga den aktuella matrisen med följande matris:

Parametrar

Tilldelar matrismedlemmarna det angivna värdet

Parametrar

Returnerar ett textvärde som listar egenskaperna för det här Matrix-objektet.

Returnerar resultatet från tillämpning av den geometriska omformningen som representeras av Matrix-objektet vid den angivna punkten.

Parametrar

Matrisen omvandlas längs x- och y-axlarna enligt dx- och dy-parametrarna.

Parametrar

1. Programmet skapar först ett nytt Matrix-objektmyMatrix. Sedan används metoden trace() för att skicka standardegenskapsvärden för myMatrix-objektet.
2. Programmet anropar createGradientBox() med parametrarna width och height inställda på 200 pixlar, ingen rotation, och avståndet att omvandla längs x- och y-axlarna inställt på 50 pixlar.
3. Programmet skriver ut myMatrix-objektet igen för att visa ändringen efter anropet till createGradientBox().
4. Programmet ställer in tre variabler som styr hur övertoningsrutan fylls.
   • colors: Anger att övertoningsfärgerna varierar från heltäckande rött och heltäckande blått.
   • alphas: Ställer in opaciteten till heltäckande.
   • ratios: Ställer in likvärdig fördelning av färgerna för både rött och blått.
5. Programmet anropar Graphics-metoden beginGradientFill() som verkar på myMatrix-objektet och anropar metoden lineTo(), vilket resulterar i en övertoningsfylld ruta.

package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}