MovieClip  - AS3

Anger det bildrutenummer som spelhuvudet är på i MovieClip-instansens tidslinje. Om filmklippet innehåller flera scener är detta värde bildrutenumret i den aktuella scenen.

mc1.gotoAndStop(mc1.currentFrame + 5);

Etiketten på den aktuella bildrutan i tidslinjen för MovieClip-instansen. Om den aktuella bildrutan saknar etikett är currentLabel null.

Den aktuella etiketten som spelhuvudet är på i MovieClip-instansens tidslinje. Om den aktuella bildrutan inte har någon etikett sätts currentLabel till namnet på den tidigare bildruta som har en etikett. Om vare sig den aktuella bildrutan eller någon tidigare bildruta har någon etikett returnerar currentLabel null.

trace(mc1.currentLabel);

Returnerar en array med FrameLabel-objekt från den aktuella scenen. Om MovieClip-instansen inte använder scener inkluderar arrayen alla bildruteetiketter från hela MovieClip-instansen.

Relaterade API-element

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

Den aktuella scenen som spelhuvudet är på i MovieClip-instansens tidslinje.

Relaterade API-element

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Ett booleskt värde som anger om ett filmklipp är aktiverat. Standardvärdet för enabled är true. Om enabled sätts till false inaktiveras filmklippets bildrutor Over, Down och Up. Filmklippet fortsätter att ta emot händelser (exempelvis mouseDown, mouseUp, keyDown och keyUp).

Egenskapen enabled styr bara de knappliknande egenskaperna för ett filmklipp. Du kan ändra egenskapen enabled när som helst. Det ändrade filmklippet aktiveras eller inaktiveras omedelbart. Om enabled sätts till false inkluderas objektet inte i automatisk tabbordning.

mc1.enabled = false;

Antalet bildrutor som läses in från en direktuppspelad SWF-fil. Du kan använda egenskapen framesLoaded för att avgöra om innehållet i en viss bildruta, och alla bildrutor före den, är inlästa och tillgängliga lokalt i webbläsaren. Du kan också använda den för att övervaka nedladdningen av stora SWF-filer. Du kanske till exempel vill visa ett meddelande för användaren som säger att SWF-filen läses in tills en viss bildruta i SWF-filen har lästs in.

Om filmklippet innehåller flera scener returnerar egenskapen framesLoaded det antal bildrutor som lästs in för samtliga scener i filmklippet.

Relaterade API-element

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Ett booleskt värde som anger om ett filmklipp spelas för närvarande.

En array med Scene-objekt som listar namn, antal bildrutor och bildruteetiketter för en scen i MovieClip-instansen.

Relaterade API-element

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

Det totala antalet bildrutor i MovieClip-instansen.

Om filmklippet innehåller flera scener returnerar egenskapen totalFrames det antal bildrutor som lästs in för samtliga scener i filmklippet.

 trace(mc1.totalFrames);

Anger om andra visningsobjekt som är SimpleButton-objekt eller MovieClip-objekt kan ta emot släppningshändelser från musen eller andra användarindataenheter. Med egenskapen trackAsMenu kan du skapa menyer. Du kan sätta egenskapen trackAsMenu på valfritt SimpleButton- eller MovieClip-objekt. Standardvärdet för trackAsMenu-egenskapen är false.

Du kan ändra egenskapen trackAsMenu när som helst. Det ändrade filmklippet får det nya beteendet direkt.

 mc1.trackAsMenu = true;

Skapar en ny MovieClip-instans. Efter MovieClip-skapandet anropar du metoden addChild() eller addChildAt() för en visningsobjektbehållare som befinner sig på scenen.

Börjar spela upp SWF-filen vid den angivna bildrutan. Detta händer när alla återstående åtgärder i bildrutan är avslutade. För att ange både en scen och en bildruta anger du ett värde för parametern scene.

Parametrar

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Flyttar spelhuvudet till den angivna bildrutan i filmklippet och stannar det där. Detta händer när alla återstående åtgärder i bildrutan är avslutade. Om du vill ange en scen utöver en bildruta så anger du en scene-parameter.

Parametrar

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Flyttar spelhuvudet till nästa bildruta och stannar det där. Detta händer när alla återstående åtgärder i bildrutan är avslutade.

Relaterade API-element

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Flyttar spelhuvudet till nästa scen i MovieClip-instansen. Detta händer när alla återstående åtgärder i bildrutan är avslutade.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Flyttar spelhuvudet i filmklippets tidslinje.

Relaterade API-element

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Flyttar spelhuvudet till föregående bildruta och stannar det där. Detta händer när alla återstående åtgärder i bildrutan är avslutade.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Flyttar spelhuvudet till föregående scen i MovieClip-instansen. Detta händer när alla återstående åtgärder i bildrutan är avslutade.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Stoppar spelhuvudet i filmklippet.

1. Konstruktorfunktionen definierar ett textfält som används för att visa värden för egenskaper för MovieClipExample-objektet (som utökar MovieClip).
2. Returvärdet för getPropertiesString()-metoden används text för textfältet outputText. getPropertiesString()-metoden returnerar en sträng som innehåller värden för följande egenskaper för filmklippet: currentFrame, currentLabel, currentScene, framesLoaded, totalFrames och trackAsMenu.
3. Två kodrader i konstruktorfunktionen ändrar egenskaperna width och height textfält outputText.
4. Den sista raden i konstruktorfunktionen lägger till textfält outputText till visningslistan.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}