UIComponent  - AS3 Flash

Hämtar eller ställer in värde som anger om komponenten kan ta emot användarinteraktion. Värdet true anger att komponenten kan ta emot användarinteraktion; värdet false anger att det inte kan det.

Om du ställer in egenskapen enabled till false blir färgen på behållaren dämpad och inmatning från användaren blockeras (med undantag för Label- och ProgressBar-komponenter).

Standardvärdet är true.

Hämtar eller ställer in booleskt värde som anger om komponenten kan ta emot fokus när användaren har klickat på den. Värdet true anger att komponenten kan ta emot fokus; värdet false anger att den inte kan det.

Om den här egenskapen är false flyttas fokus till den första överordnade som har egenskapen mouseFocusEnabled inställd på true.

Standardvärdet är true.

Relaterade API-element

Hämtar eller ställer in FocusManager som kontrollerar fokus för den här komponenten och dess jämlikar. Alla popup-komponenter behåller sina fokusslingor och FocusManager-instans. Använd den här egenskapen om du vill komma åt korrekt FocusManager för den här komponenten.

Hämtar eller ställer in komponenternas höjd, i pixlar.

När den här egenskapen ställs in skickas en resize-händelse. Se resize-händelsen för närmare information om när den skickas.

Om komponentens scaleY-egenskap inte är 1.0 kommer höjden på komponenten som hämtas från dess interna koordinater inte att matcha höjdvärdet från de överordnade koordinaterna. En komponent som t.ex. är 100 pixlar hög och har en scaleY av 2 som har ett värde på 100 pixlar i den överordnade, men internt lagrar ett värde som anger att det är 50 pixlar högt.

Hämtar eller ställer in ett värde som anger om komponenten kan ta emot fokus när användaren har klickat på den. Värdet true anger att komponenten kan ta emot fokus; värdet false anger att den inte kan det.

Om den här egenskapen är false flyttas fokus till den första överordnade som har egenskapen mouseFocusEnabled inställd på true.

Standardvärdet är true.

Relaterade API-element

Multiplicerar komponentens aktuella bredd med en skalfaktor.

Relaterade API-element

Multiplicerar komponentens aktuella höjd med en skalfaktor.

Relaterade API-element

Hämtar eller ställer in värde som anger om den aktuella komponentinstansen är synlig. Värdet true anger att den aktuella komponenten är synlig; värdet false anger att det inte är det.

När den här egenskapen är inställd på true skickar objektet en show-händelse. När den här egenskapen är inställd på false skickar objektet en hide-händelse. Oavsett kommer inte objektets underordnade att generera en show - eller hide-händelse om inte objektet specifikt skriver en implementering om att det ska göras.

Standardvärdet är true.

Relaterade API-element

Hämtar eller ställer in komponenternas bredd, i pixlar.

När den här egenskapen ställs in skickas en resize-händelse. Se resize-händelsen för närmare information om när den skickas.

Om komponentens scaleX-egenskap inte är 1.0 kommer bredden på komponenten som hämtas från dess interna koordinater inte att matcha breddvärdet från de överordnade koordinaterna. En komponent som t.ex. är 100 pixlar bred och har en scaleX av 2 som har ett värde på 100 pixlar i den överordnade, men internt lagrar ett värde som anger att det är 50 pixlar brett.

Relaterade API-element

Hämtar eller ställer in x-koordinaten som motsvarar komponentens position längs x-axeln inom dess överordnade behållare. Det här värdet beskrivs i pixlar och beräknas från vänster.

När den här egenskapen ställs in skickas en ComponentEvent.MOVE-händelse.

Standardvärdet är 0.

Relaterade API-element

Hämtar eller ställer in y-koordinaten som motsvarar komponentens position längs y-axeln inom dess överordnade behållare. Det här värdet beskrivs i pixlar och beräknas uppifrån.

När den här egenskapen ställs in skickas en move-händelse.

Relaterade API-element

Skapar en ny instans av komponenten UIComponent.

Tar bort en formategenskap från den här komponentinstansen.

Det här medför inte nödvändigtvis att getStyle()-metoden returnerar värdet undefined.

Parametrar

Relaterade API-element

Visar eller döljer fokusindikatorn på komponenten.

UIComponent-klassen implementerar den här metoden genom att skapa och positionera en instans av klassen som anges med formatet focusSkin.

Parametrar

Initierar omedelbar ritning utan att göra allt ogiltigt som invalidateNow gör.

Hämtar objektet som är i fokus.

Observera att den här metoden inte nödvändigtvis returnerar den komponent som är i fokus. Den kan returnera den interna underkomponenten för den komponent som är i fokus. Använd egenskapen focusManager.focus för att hämta komponenten som är i fokus.

Hämtar en formategenskap som är inställd i komponentens sökkedja.

Den type som den här metoden returnerar varierar beroende på den formategenskap som metoden hämtar. Intervallet av möjliga types inkluderar Boolean; String; Number; int; uint för en RGB-färg; en Class för ett skal; eller valfritt objekt.

Om du anropar den här metoden för att hämta en viss formategenskap kommer det att vara av en känd typ som du kan lagra i en variabel av samma typ. Datatypsbyte behövs inte. Istället räcker det med en enkel uppdragssats som den här:

var backgroundColor:uint = getStyle("backgroundColor");

Om formategenskapen inte har ställts in någonstans i formatsökkedjan returnerar den här metoden värdetundefined. Observera att undefined är ett eget värde som inte är detsamma som false, "", NaN, 0, eller null. Giltiga formatvärden är aldrig undefined. Det går att använda den statiska metoden StyleManager.isValidStyleValue() om du vill testa om ett värde har ställts in.

Parametrar

Relaterade API-element

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Hämtar standardformatförskjutningen för den aktuella komponenten. Formatförskjutningen innehåller den type som är lämplig för komponenten, beroende på det format komponenten använder. Till exempel innehåller formatet disabledTextFormat värdet null eller ett TextFormat-objekt. Du kan använda dessa format och anropa setStyle() på den aktuella komponenten. Följande kod åsidosätter standardformatet för disabledTextFormat för den angivna komponenten:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Relaterade API-element

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Returnerar det angivna formatet för en komponent, givet alla format som har angetts på global nivå, komponentnivå och instansnivå.

Om en komponent till exempel har ett format angivet på global nivå till myStyle och du anropar getStyle("myStyle") på en instans som inte har en instansinställning, returnerar den null. Om du anropar getStyleValue("myStyle") returnerar den ”myStyle” eftersom den är aktiv på global nivå.

Parametrar

Markerar en egenskap som ogiltig och ritar om komponenten i nästa bildruta om inte annat anges.

Parametrar

Sammanfogar format från flera klasser till ett objekt. Om ett format definieras i flera objekt används den första förekomsten som hittas.

Parametrar

Flyttar komponenten till den angivna positionen inom dess överordnade. Det har samma effekt som att ändra komponentens plats genom att ställa in x- och y-egenskaper. När du anropar den här metoden skickas ComponentEvent.MOVE-händelsen.

Om du vill åsidosätta updateDisplayList()-metoden i en anpassad komponent bör du använda move()-metoden istället för att ställa in x- och y-egenskaperna. Det beror på att ett anrop till move()-metoden orsakar att move-händelseobjektet skickas omedelbart när flyttningen genomförts. Om du istället skulle ändra komponentens plats genom att ställa in x- och y-egenskaper skickas händelseobjektet när skärmen uppdateras nästa gång.

Parametrar

Relaterade API-element

Ställer in fokus på den här komponenten. Komponenten kan i sin tur ge fokus till en underkomponent.

Obs! Det är bara komponenterna TextInput och TextArea som visar en fokusindikator när fokus ställs in med den här metoden. Alla komponenter visar en fokusindikator när användaren tabbar till komponenten.

Ställer in komponenten på angiven bredd och höjd.

Parametrar

Ställer in en formategenskap för en komponentinstans. Detta format kan åsidosätta ett format som ställts in globalt.

Om du anropar den här metoden kan det medföra sänkt prestanda. Använd det endast när det är nödvändigt.

Parametrar

Relaterade API-element

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Validerar och uppdaterar egenskaper och layout för det här objektet och ritar om det vid behov.

Egenskaper som kräver betydande databehandling bearbetas normalt inte förrän skriptet har körts. Det beror på att om en egenskap ställs in kan andra egenskaper behöva bearbetas. Inställning av egenskapen width kan exempelvis kräva omräkning av bredden på objektets underordnade eller överordnade. Och om skriptet räknar om bredden på objektet mer än en gång kan de egenskaper som är beroende av varandra också behöva räknas om. Använd den här metoden om du manuellt vill åsidosätta detta.

Skickas när komponenten ändrar synlighet från synlig till osynlig.

Den här händelsen har följande egenskaper:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Relaterade API-element

Skickas när komponenten har flyttats.

Den här händelsen har följande egenskaper:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Skickas när komponentens storlek ändrats.

Den här händelsen har följande egenskaper:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Skickas när komponenten ändrar synlighet från osynlig till synlig.

Den här händelsen har följande egenskaper:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Relaterade API-element

Versionsnummer för komponenterna.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);