Label  - AS3 Flash

Hämtar eller ställer in en sträng som anger hur en etiketts storlek och justering ställs in för att passa värdet för dess text-egenskap. Dessa värden är giltiga:

• TextFieldAutoSize.NONE: Etiketten ändrar inte storlek eller justeras för att anpassas efter texten.
• TextFieldAutoSize.LEFT: Storleken ändras på de högra sidorna och sidorna längst ned på etiketten för att anpassas efter texten. Storleken ändras inte på de vänstra sidorna och sidorna längst upp.
• TextFieldAutoSize.CENTER: Storleken ändras på de vänstra och högra sidorna på etiketten för att anpassas efter texten. Den vågräta centreringen av etiketten förblir förankrad vid dess ursprungliga vågräta mittposition.
• TextFieldAutoSize.RIGHT: Storleken ändras på de vänstra sidorna och sidorna längst ned på etiketten för att passa texten. Storleken ändras inte på de översta sidorna och de högra sidorna.

Standardvärdet är TextFieldAutoSize.NONE.

Relaterade API-element

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Hämtar eller ställer in ett värde som anger om extra tomrum, t.ex. mellanslag och radbrytningar, ska tas bort från en Label-komponent med HTML-text. Värdet true anger att tomrum ska tas bort. Värdet false anger att det får vara kvar.

Egenskapen condenseWhite påverkar bara text som angetts med egenskapen htmlText, inte text-egenskapen. Om du använder text-egenskapen för att ange text ignoreras condenseWhite.

Om du ställer in condenseWhite-egenskapen på true måste du använda HTML-standardkommandon som t.ex. <br> och <p> för att placera radbrytningar i textfältet.

Standardvärdet är false.

Relaterade API-element

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Hämtar eller ställer in komponenternas höjd, i pixlar.

När den här egenskapen ställs in skickas en resize-händelse. Se resize-händelsen för närmare information om när den skickas.

Om komponentens scaleY-egenskap inte är 1.0 kommer höjden på komponenten som hämtas från dess interna koordinater inte att matcha höjdvärdet från de överordnade koordinaterna. En komponent som t.ex. är 100 pixlar hög och har en scaleY av 2 som har ett värde på 100 pixlar i den överordnade, men internt lagrar ett värde som anger att det är 50 pixlar högt.

Relaterade API-element

Hämtar eller ställer in den text som visas av Label-komponenten, inklusive HTML-kod som uttrycker textens format. Du kan ange HTML-text i den här egenskapen genom att använda den delmängd HTML-taggar som stöds av TextField-objektet.

Om standardvärdet för text-egenskapen ändras i egenskapsinspektören har den företräde framför värden i htmlText-egenskapen i egenskapsinspektören. För att htmlText-egenskapen i egenskapsinspektören ska kunna användas måste text-egenskapsfältet innehålla värdet Label, precis som det visas. När du kodar med ActionScript behöver du inte ställa in värdet för text-egenskapen. Standardvärdet är Label.

Standardvärdet är "".

Relaterade API-element

Hämtar eller ställer in ett värde som anger om texten kan markeras. Värdet true anger att den går att markera. Värdet false anger att den inte går att markera.

Text som kan markeras kan inte kopieras från Label-komponenten av användaren.

Standardvärdet är false.

Hämtar eller ställer in den text som ska visas av Label-komponenten.

Observera att tecknen som representerar HTML-kod har ingen speciell betydelse i strängen och kommer att visas precis som de angavs.

Om du vill visa text som innehåller HTML-taggar använder du egenskapen htmlText. HTML ersätter all text som du anger med hjälp av egenskapen htmlText, och text-egenskapen returnerar en oformaterad version av HTML-texten, där alla HTML-taggar är borttagna.

Om standardvärdet för text-egenskapen ändras i egenskapsinspektören har den företräde framför htmlText-egenskapen i egenskapsinspektören.

Standardvärdet är "Label".

Relaterade API-element

En referens till det interna textfältet för Label-komponenten.

Hämtar eller ställer in komponenternas bredd, i pixlar.

När den här egenskapen ställs in skickas en resize-händelse. Se resize-händelsen för närmare information om när den skickas.

Om komponentens scaleX-egenskap inte är 1.0 kommer bredden på komponenten som hämtas från dess interna koordinater inte att matcha breddvärdet från de överordnade koordinaterna. En komponent som t.ex. är 100 pixlar bred och har en scaleX av 2 som har ett värde på 100 pixlar i den överordnade, men internt lagrar ett värde som anger att det är 50 pixlar brett.

Relaterade API-element

Hämtar eller ställer in ett värde som anger om textfältet har stöd för automatisk radbrytning. Värdet true anger att det har det. Värdet false anger att det inte har det.

Standardvärdet är false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Skapar en ny instans av komponenten Label.

Hämtar standardformatförskjutningen för den aktuella komponenten. Formatförskjutningen innehåller den type som är lämplig för komponenten, beroende på det format komponenten använder. Till exempel innehåller formatet disabledTextFormat värdet null eller ett TextFormat-objekt. Du kan använda dessa format och anropa setStyle() på den aktuella komponenten. Följande kod åsidosätter standardformatet för disabledTextFormat för den angivna komponenten:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Relaterade API-element

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Skickas när en ändring av bredden och höjden på komponenten har gjorts.

Obs! Den här händelsen inträffar inte om du använder ActionScript-koden för att ändra etikettexten.

Den här händelsen har följande egenskaper:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Lägg till Label- och Button-komponenterna i ditt bibliotek.
2. Spara koden som LabelExample.as i samma katalog som din FLA-fil.
3. Ställ in LabelExample som DocumentClass i FLA-filen.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}