| Paket | fl.managers |
| Klass | public class StyleManager |
| Arv | StyleManager  Object |
| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Publika egenskaper
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaperPublika metoder
| Metod | Definieras med | ||
|---|---|---|---|
Skapar ett nytt StyleManager-objekt. | StyleManager | ||
[statisk]
Hämtar ett format från den angivna komponenten. | StyleManager | ||
[statisk]
Tar bort ett globalt format från alla användargränssnittskomponenter i ett dokument. | StyleManager | ||
[statisk]
Hämtar ett format som finns i en viss komponent. | StyleManager | ||
[statisk]
Hämtar ett globalt format med hjälp av namnet. | StyleManager | ||
 |
Anger om det finns en egenskap angiven för ett objekt. | Object | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
[statisk]
Registrerar en komponentinstans med formathanteraren. | StyleManager | ||
[statisk]
Anger ett format i alla instanser för en komponenttyp, t.ex. i alla instanser av en Button-komponent, eller alla instanser av en ComboBox-komponent. | StyleManager | ||
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
[statisk]
Anger ett globalt format för alla användargränssnittskomponenter i ett dokument. | StyleManager | ||
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
|
Returnerar det angivna objektets strängbeteckning. | Object | |
|
Returnerar det angivna objektets primitiva värde. | Object | |
Konstruktordetaljer
StyleManager | () | Konstruktor |
public function StyleManager()| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Skapar ett nytt StyleManager-objekt.
Metoddetaljer
clearComponentStyle | () | metod |
public static function clearComponentStyle(component:Object, name:String):void| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Hämtar ett format från den angivna komponenten.
Parametrar
component:Object — Namnet på den komponent som det begärda formatet ska tas bort från.
| |
name:String — Namnet på det format som ska tas bort.
|
Relaterade API-element
clearStyle | () | metod |
public static function clearStyle(name:String):void| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Tar bort ett globalt format från alla användargränssnittskomponenter i ett dokument.
Parametrar
name:String — Namnet på det globala format som ska tas bort.
|
Relaterade API-element
getComponentStyle | () | metod |
public static function getComponentStyle(component:Object, name:String):Object| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Hämtar ett format som finns i en viss komponent.
Parametrar
component:Object — Namnet på komponentinstansen som det begärda formatet finns på.
| |
name:String — Namnet på det format som ska hämtas.
|
Object — Det begärda formatet för den angivna komponenten. Om det angivna formatet inte hittas returnerar funktionen värdet null.
|
Relaterade API-element
getStyle | () | metod |
public static function getStyle(name:String):Object| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Hämtar ett globalt format med hjälp av namnet.
Parametrar
name:String — Namnet på det format som ska hämtas.
|
Object — Värdet på det globala format som hämtades.
|
Relaterade API-element
registerInstance | () | metod |
public static function registerInstance(instance:UIComponent):void| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Registrerar en komponentinstans med formathanteraren. När en komponentinstans skapats kan den registreras med formathanteraren om ändringar i format ska meddelas. Komponentinstanser kan registrera så att de får besked om formatändringar som är komponentbaserade eller globala.
Parametrar
instance:UIComponent — Komponentinstansen ska registreras för formathantering.
|
setComponentStyle | () | metod |
public static function setComponentStyle(component:Object, name:String, style:Object):void| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger ett format i alla instanser för en komponenttyp, t.ex. i alla instanser av en Button-komponent, eller alla instanser av en ComboBox-komponent.
Parametrar
component:Object — Typen av komponent, t.ex. Button eller ComboBox. Den här parametern accepterar även en komponentinstans eller klass som kan användas för identifiering av alla instanser av en komponenttyp.
| |
name:String — Namnet på det format som ska anges.
| |
style:Object — Formatobjektet som beskriver det format som ska anges.
|
Relaterade API-element
setStyle | () | metod |
public static function setStyle(name:String, style:Object):void| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger ett globalt format för alla användargränssnittskomponenter i ett dokument.
Parametrar
name:String — Ett strängvärde som namnger det format som ska anges.
| |
style:Object — Formatobjektet som ska anges. Värdet för den här egenskapen beror på det format användaren anger. Om formatet t.ex. är angett till "textFormat" ska formategenskapen anges till ett TextFormat-objekt. Om formatnamnet inte matchar värdet på formategenskapen kan det leda till att komponenten inte uppför sig korrekt.
|
Relaterade API-element
Exempel Så här använder du exemplet
StyleManagerExample.as
I det här exemplet visas hur man dynamiskt skapar ett DataGrid och avlyssnar dess händelser.
Följ stegen nedan:
- Lägg till komponenterna DataGrid, Button, Label och TextArea i biblioteket.
- Spara koden som StyleManagerExample.as i samma katalog som din FLA-fil.
- Ställ in StyleManagerExample som DocumentClass i FLA-filen.
package
{
import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.Label;
import fl.controls.TextArea;
import fl.core.UIComponent;
import fl.managers.FocusManager;
import fl.managers.StyleManager;
import flash.display.InteractiveObject;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
public class StyleManagerExample extends Sprite
{
private var btn:Button;
private var ta1:TextArea;
private var ta2:TextArea;
private var ta3:TextArea;
private var ta4:TextArea;
private var description:Label;
private var dg:DataGrid;
private var formatForInstance:TextFormat;
private var formatForGlobal:TextFormat;
private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
public function StyleManagerExample() {
setupComponents();
setupUI();
setupStyles();
}
private function setupUI():void {
var setInstanceStyleBtn:Button = new Button();
var clearInstanceStyleBtn:Button = new Button();
var setClassStyleBtn:Button = new Button();
var clearClassStyleBtn:Button = new Button();
var setGlobalStyleBtn:Button = new Button();
var clearGlobalStyleBtn:Button = new Button();
setInstanceStyleBtn.label = "Set Instance Style";
clearInstanceStyleBtn.label = "Clear Instance Style";
setClassStyleBtn.label = "Set Class Style";
clearClassStyleBtn.label = "Clear Class Style";
setGlobalStyleBtn.label = "Set Global Style";
clearGlobalStyleBtn.label = "Clear Global Style";
setInstanceStyleBtn.focusEnabled = false;
clearInstanceStyleBtn.focusEnabled = false;
setClassStyleBtn.focusEnabled = false;
clearClassStyleBtn.focusEnabled = false;
setGlobalStyleBtn.focusEnabled = false;
clearGlobalStyleBtn.focusEnabled = false;
setInstanceStyleBtn.move(10,310);
clearInstanceStyleBtn.move(10,340);
setClassStyleBtn.move(140,310);
clearClassStyleBtn.move(140,340);
setGlobalStyleBtn.move(270,310);
clearGlobalStyleBtn.move(270,340);
setInstanceStyleBtn.setSize(120,24);
clearInstanceStyleBtn.setSize(120,24);
setClassStyleBtn.setSize(120,24);
clearClassStyleBtn.setSize(120,24);
setGlobalStyleBtn.setSize(120,24);
clearGlobalStyleBtn.setSize(120,24);
setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);
description = new Label();
description.move(10, 370);
description.autoSize = TextFieldAutoSize.LEFT;
description.text = "";
addChild(setInstanceStyleBtn);
addChild(clearInstanceStyleBtn);
addChild(setClassStyleBtn);
addChild(clearClassStyleBtn);
addChild(setGlobalStyleBtn);
addChild(clearGlobalStyleBtn);
addChild(description);
}
private function setupComponents():void {
dg = new DataGrid();
dg.addItem( { Name:"John Alpha", Number:"555-123-0101" } );
dg.addItem( { Name:"Mary Bravo", Number:"555-372-3322" } );
dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
dg.addItem( { Name:"Susan Delta", Number:"555-987-3434" } );
dg.move(10,10);
dg.setSize(200,290);
dg.columns = ["Name","Number"];
addChild(dg);
ta1 = new TextArea();
ta1.move(220,10);
ta1.setSize(150,140);
ta1.text = testString;
ta1.tabEnabled = true;
addChild(ta1);
ta2 = new TextArea();
ta2.move(380,10);
ta2.setSize(150,140);
ta2.text = testString;
ta2.tabEnabled = true;
addChild(ta2);
ta3 = new TextArea();
ta3.move(220,160);
ta3.setSize(150,140);
ta3.text = testString;
ta3.tabEnabled = true;
addChild(ta3);
ta4 = new TextArea();
ta4.move(380,160);
ta4.setSize(150,140);
ta4.text = testString;
ta4.tabEnabled = true;
addChild(ta4);
}
private function setupStyles():void {
formatForGlobal = new TextFormat();
formatForGlobal.font = "Georgia";
formatForGlobal.size = 10;
formatForInstance = new TextFormat();
formatForInstance.underline = true;
}
private function setInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.setStyle("textFormat",formatForInstance);
description.text = "The TextArea object with focus is now underlined.";
}
}
private function clearInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.clearStyle("textFormat");
description.text = "The TextArea object with focus is no longer underlined.";
}
}
private function setClassStyle(e:MouseEvent):void {
var c:Class = TextArea;
var styleName:String = "textPadding";
var value:Number = 10;
StyleManager.setComponentStyle(c,styleName,value);
description.text = "Padding for all TextArea instances is now 10.";
}
private function clearClassStyle(e:MouseEvent):void {
var styleName:String = "textPadding";
var c:Class = TextArea;
StyleManager.clearComponentStyle(c,styleName);
description.text = "TextArea padding has been reset to the default.";
}
private function setGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
var value:Object = formatForGlobal;
StyleManager.setStyle(styleName,value);
description.text = "All components now use font Georgia size 10.";
}
private function clearGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
StyleManager.clearStyle(styleName);
description.text = "Font style for all components has been cleared.";
}
}
}
Tue Jun 12 2018, 01:40 PM Z