TextFormat  - AS3

Anger styckets justering. Giltiga värden är TextFormatAlign-konstanter.

Standardvärdet är TextFormatAlign.LEFT.

Relaterade API-element

Anger blockindrag i pixlar. Blockindrag används på ett helt textblock, på alla rader i texten. Normalt indrag (TextFormat.indent) påverkar bara den första raden i varje stycke. Om egenskapen är null anger inte TextFormat-objektet något blockindrag (blockindraget är 0).

Anger om texten är fetstilt. Standardvärdet är null vilket anger att ingen fetstil används. Om värdet är true är texten fetstilt.

Anger att texten är del av en punktlista. I en punktlista är varje textstycke indraget. Till vänster om den första raden i varje stycke visas en punktsymbol. Standardvärdet är null vilket anger att ingen punktlista används.

Anger textens färg. Ett tal som innehåller tre 8-bitars RGB-komponenter, till exempel är 0xFF0000 rött och 0x00FF00 grönt. Standardvärdet är null vilket innebär att Flash Player använder svart färg (0x000000).

Namnet på teckensnittet för texten i detta textformat, som en sträng. Standardvärdet är null vilket innebär att Flash Player använder teckensnittet Times New Roman i texten.

Anger indraget från den vänstra marginalen till det första tecknet i stycket. Standardvärdet är null vilket innebär att inget indrag används.

Relaterade API-element

Anger om texten i textformatet är kursiv. Standardvärdet är null vilket innebär att ingen kursivering används.

Ett booleskt värde som anger om kerning används (true) eller inte (false). Med kerning justeras pixlarna mellan vissa teckenpar för att underlätta läsbarheten. Det bör bara användas när det är nödvändigt, till exempel i rubriker med stora teckensnitt. Kerning kan endast användas med inbäddade teckensnitt.

Vissa teckensnitt, till exempel Verdana och teckensnitt med fast teckenbredd som Courier New, stöder inte kerning.

Standardvärdet är null vilket innebär att kerning inte är aktiverat.

Ett heltal som representerar lodrätt utrymme i pixlar (radavstånd) mellan raderna. Standardvärdet är null vilket innebär att radavståndet är 0.

Styckets vänstra marginal i pixlar. Standardvärdet är null vilket innebär att vänstermarginalen är 0 pixlar.

Ett tal som representerar mängden utrymme som är jämnt fördelat mellan alla tecken. Värdet anger antalet pixlar som läggs till framflyttningen efter varje tecken. Standardvärdet är null vilket innebär att teckenavståndet är 0 pixlar. Du kan använda decimaltal, till exempel 1.75.

Styckets högra marginal i pixlar. Standardvärdet är null vilket innebär att högermarginalen är 0 pixlar.

Pixelstorleken för text i det här textformatet. Standardvärdet är null, vilket innebär att storleken är 12.

Anger anpassade tabbstopp som en array med positiva heltal. Alla tabbstopp anges i pixlar. Om anpassade tabbstopp inte anges (null) är standardtabbstoppet 4 (genomsnittlig teckenbredd).

Visar målfönstret där hyperlänken visas. Om målfönstret är en tom sträng visas texten i standardmålfönstret _self. Du kan välja ett anpassat namn eller ett av följande fyra namn: Med alternativet _self anges den aktuella bildrutan i aktuellt fönster. _blank anger ett nytt fönster, _parent anger den aktuella bildrutans överordnade bildruta och _top anger bildrutan på översta nivån i aktuellt fönster. Om TextFormat.url-egenskapen är en tom sträng eller null kan du hämta eller ställa in egenskapen, men den kommer inte att ha någon effekt.

Relaterade API-element

Anger om texten med detta textformat är understruken (true) eller inte (false). Den här understrykningen liknar den som skapas av <U>-taggen, men den senare är ingen riktig understrykning, eftersom den inte hoppar över nedstaplar på rätt sätt. Standardvärdet är null vilket innebär att inget understrykning används.

Anger mål-URL:en för texten i textformatet. Om egenskapen url är en tom sträng har texten ingen hyperlänk. Standardvärdet är null vilket innebär att texten inte har någon hyperlänk.

Obs! Texten med det tilldelade textformatet måste anges med egenskapen htmlText för att hyperlänken ska fungera.

Relaterade API-element

Skapar ett TextFormat-objekt med angivna egenskaper. Du kan sedan ändra egenskaperna för TextFormat-objektet för att ändra textfältens formatering.

Alla parametrar kan ställas in på null för att visa att de inte är definierade. Alla parametrar är valfria och alla parametrar som uteslutits behandlas som null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. En label-egenskap av typen TextField skapas.
2. Klasskonstruktorn anropar funktionen configureLabel().
3. Metoden configureLabel() skapar först ett nytt TextField-objekt och kopplar det till egenskapen label och ställer sedan in sina parametrar på
   • Vänsterjustera textfältet
   • Aktivera bakgrundsfyllningen
   • Aktivera kantlinjen.
4. Metoden configureLabel() skapar den lokala variabeln format och kopplar den till en ny TextFormat-instans med parametrarna inställda på:
   • Font type = Verdana
   • Font Color = solid red
   • Font size = 10
   • Font underline = true.
5. Egenskapen defaultTextFormat ställs in på format och label-instansen läggs till i visningslistan som först visar ett textfält utan text (som en liten ruta med vit bakgrund) på scenen.
6. Slutligen (tillbaka i konstruktorn) anges etikettexten till "Hello World and welcome to the show", vid koordinaterna x = 0, y = 0 genom anrop till setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}