TextLine  - AS3

Anger antalet pixlar från baslinjen till överkanten av de högsta tecknen på raden. För en TextLine som innehåller endast ett grafikelement är ascent inställt på 0.

Antalet atomer på raden, det vill säga antalet odelbara element, inklusive blanksteg och grafikelement.

Anger antalet pixlar från baslinjen till nederkanten av de tecken som är längst ned på raden. För en TextLine som innehåller endast ett grafikelement är descent inställt på 0.

Anger om textraden innehåller grafikelement.

Relaterade API-element

Anger om textraden innehåller tabbar.

Vektorn som innehåller de TextLineMirrorRegion-objekt som är associerade med raden, eller null om det inte finns några objekt.

Relaterade API-element

Nästa TextLine i TextBlock eller null, om detta är den sista raden i blocket eller om radens giltighet är TextLineValidity.STATIC.

Relaterade API-element

Föregående TextLine i TextBlock eller null, om detta är den första raden i blocket eller om radens giltighet är TextLineValidity.STATIC.

Relaterade API-element

Längden på raw-text för textblocket som blev raden, inklusive de U+FDEF-tecken som representerar grafikelement och eventuella efterföljande blanksteg som är del av raden men som inte visas.

Relaterade API-element

Bredden som angavs till metoden TextBlock.createTextLine() när den skapade raden. Det här värdet är användbart när du ska bestämma om raden behöver anpassas efter en ändring.

Relaterade API-element

Det TextBlock som innehåller den här textraden eller null om radens giltighet är TextLineValidity.STATIC, vilket innebär att kopplingen mellan raden och TextBlock har brutits.

Relaterade API-element

Indexet för det första tecknet på raden i textblockets raw-text.

Relaterade API-element

Textradens logiska höjd, vilken är lika med ascent + descent. Använd den ärvda height-egenskapen om du vill få fram bläckhöjden.

Värdet beräknas baserat på skillnaden mellan baslinjerna som utgör gränser för raden, antingen ideo top/bottom eller ascent/descent beroende på om TextBlock.baselineZero är ideo eller inte. Grafikelement tas inte med i beräkningen av dessa baslinjer.

Relaterade API-element

Den logiska bredden på textraden som är den bredd som textmotorn använder för att lägga ut raden. Du kan komma åt den ärvda width-egenskapen för att hämta den faktiska bredden på begränsningsramen på alla ritade pixlar.

Relaterade API-element

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Anger antalet pixlar från baslinjen till överkanten av de högsta tecknen eller bilderna på raden.

Anger antalet pixlar från baslinjen till nederkanten av de tecken eller bilder som är längst ned på raden.

Den totala logiska höjden på textraden, som är lika med totalAscent + totalDescent.

Bredden på raden om den inte hade justerats. För ojusterad text är detta värde samma som textWidth. För justerad text är detta värde vad length skulle ha varit utan justering och textWidth representerar den faktiska radbredden. Ett exempel: när följande String justeras och skickas till TextBlock.createTextLine() med en bredd på 500, har den en faktisk bredd på 500 men en ojusterad bredd på 268,9921875.

Relaterade API-element

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Medger att programmet kan koppla godtyckliga data till textraden.

Anger den aktuella giltigheten för textraden. Värden för den här egenskapen finns i medlemmarna i klassen TextLineValidity. Reglerna för att ställa in den här egenskapen är följande:

En rad betraktas som USER_INVALID om giltigheten har angetts till en sträng som inte är medlem i TextLineValidity. USER_INVALID är en abstraktion som används här för att representera sådana värden.

När innehållet i TextBlock ändras markerar Flash-miljön påverkade textrader, den föregående raden och alla efterföljande rader som INVALID. Den föregående raden måste markeras som ogiltig om en ändring tillåter den föregående raden att absorbera en del av innehållet som ursprungligen fanns på den första påverkade raden.

Nyligen brutna rader är alltid VALID. Flash-miljön kan ändra efterföljande rader från VALID till POSSIBLY_INVALID eller INVALID. Den kan ändra rader från POSSIBLY_INVALID till VALID om radbrytningarna passar eller till INVALID om de inte passar.

Med programkoden kan rader som är VALID markeras som INVALID eller USER_INVALID, och rader som är USER_INVALID kan markeras som VALID. Rader kan inte markeras som POSSIBLY_INVALID med programkod.

Rader kan markeras som STATIC med programkod. Det medför i så fall att block-medlemmen blir null. Grafikelement i en STATIC-textrad tas bort och får nya överordnade element, om de är en del av en ny textrad som har brutits av från det textblock som STATIC-textraden ursprungligen kom från.

Relaterade API-element

Dumpar det underliggande innehållet i TextLine som en XML-sträng. Detta kan vara användbart vid automatiserad testning och inkluderar text, formatering och layoutinformation.

Följande beskriver utdata:

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Obs! Innehållet i och formatet på utdata kan komma att ändras i framtiden. Adobe garanterar inte metodens bakåtkompatibilitet.

Relaterade API-element

Den här metoden är föråldrad och har ingen effekt. Atomdata komprimeras och påverkar inte minneshanteringen.

Relaterade API-element

Hämtar bidi-nivån för atomen vid det angivna indexet. Avgörs av en kombination av TextBlock.bidiLevel och de dubbelriktade Unicode-egenskaperna på de tecken som utgör raden.

Om du till exempel startar ett textblock med lite hebreisk text ställer du in TextBlock.bidiLevel till 1 vilket gör att standard är höger till vänster. Om du inom texten har ett citat på engelska (vänster till höger) har den texten AtomBidiLevel på 2. Om du inom den engelska texten har ett citat på arabiska (höger till vänster) har den texten AtomBidiLevel på 3. Om du inom den arabiska texten har ett nummer (vänster till höger) har den texten AtomBidiLevel på 4. Det spelar ingen roll på vilken rad atomerna hamnar. Hebreiska atomer är AtomBidiLevel 1, engelska atomer är AtomBidiLevel 2, arabiska atomer är AtomBidiLevel 3 och nummeratomer är AtomBidiLevel 4.

Parametrar

Relaterade API-element

Hämtar begränsningar för atomen vid det angivna indexet i förhållande till textraden. Gränserna för den angivna atomen består av atomens vågräta position (x) på raden, dess lodräta position på raden (y), dess bredd (w) och dess höjd (h). Alla värden är i pixlar.

Parametrar

Hämtar centrum på atomen som detta mäts längs baslinjen vid det angivna indexet.

Parametrar

Hämtar grafiken för atomen vid det angivna indexet, eller null om atomen är ett tecken.

Parametrar

Returnerar index på den atom som innehåller det tecken som anges av charIndex-parametern, eller -1 om tecknet inte bidrar till någon atom på den raden. charIndex är relativ till det fullständiga innehållet i det textblock som innehåller raden.

Parametrar

Returnerar index på atomen vid den punkt som anges av x- och y-parametrarna, eller -1 om det inte finns någon atom vid den punkten.

Den här metoden använder globala koordinater, och du kan därför enkelt använda den med egenskaperna MouseEvent.stageX och MouseEvent.stageY.

Parametrar

Hämtar textblockets startindex för atomen vid det angivna indexet.

Parametrar

Hämtar textblockets slutindex för atomen vid det angivna indexet.

Parametrar

Hämtar rotationen på atomen vid det angivna indexet. TextRotation-konstanter används för den här egenskapen. Atomens rotation motsvarar de kumulativa rotationerna för elementet och raden. Dess huvudsakliga användning är att ställa in textinmatningspositionens (markörens) orientering vid interaktion med en TextLine.

Parametrar

Relaterade API-element

Anger om en ordgräns förekommer till vänster om atomen vid angivet index. Ordgränserna bestäms baserat på Unicode-egenskaperna för de tecken som bidragit till raden.

Parametrar

Hämtar den angivna baslinjens position i förhållande till TextBlock.baselineZero.

Parametrar

Relaterade API-element

Returnerar den första TextLineMirrorRegion på raden vars mirror-egenskaper matchar den som anges av mirror-parametern, eller null om det inte finns någon matchning.

Observera att ett enda TextElement kan ge flera TextLineMirrorRegion-objekt på en eller flera rader, beroende på dubbelriktningen och radbrytningen. Egenskaperna nextRegion och previousRegion länkar alla spegelregioner som har skapats från ett textelement.

Parametrar

Relaterade API-element

Maximal begärd bredd för en textrad, i pixlar. Metoden TextBlock.createTextLine() använder denna konstant som standardvärde för width-parametern om du inte anger ett värde.

Relaterade API-element

1. Lägg till NumericStepper-komponenten i biblioteket.
2. Spara koden som TextLineExample.as i samma katalog som din FLA-fil.
3. Ställ in Class i Properties-fönstret i FLA till TextLineExample.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}