TextBlock  - AS3

Anger att du vill förbättra skärmutseendet på bekostnad av WYSIWYG-utskriftsåtergivning. För plattformar och teckensnitt som inte har stöd för placering av delpixelsglyfer vid teckensnittsåtergivning på enheten, men som har stöd för icke-linjär skalning, kan du genom att ange den här egenskapen till true göra det möjligt att använda sådana mått på bekostnad av WYSIWYG-utskriftsåtergivning, i synnerhet för små punktstorlekar. Icke-linjär skalning fungerar så att du selektivt skalar bredden på enskilda glyfer så att du döljer fula luckor som orsakats av pixelfästning.

På plattformar där det finns stöd för placering av delpixelsglyfer ignoreras den här flaggan.

Den här flaggan har ingen effekt på återgivningen av inbäddade teckensnitt

Standardvärdet är true.

Teckensnittet som används för att bestämma baslinjen för alla rader som är brutna från blocket, oberoende av deras innehåll. Baslinjer är beroende av teckensnitt och teckenstorlek.

Standardvärdet är null. När baslinjeteckensnittet är null ignoreras dess storlek, och baslinjen för alla rader baseras på teckensnittet och storleken på radens största text. När du anger både baselineFontDescription och baselineFontSize avgör de baslinjerna för alla rader i textblocket, oberoende av deras innehåll. Den här kombinationen är användbar i t.ex. asiatisk typografi.

Relaterade API-element

Teckensnittet som används för att beräkna baslinjerna för rader som är skapade från blocket. Baslinjer är beroende av teckensnitt och teckenstorlek.

Standardvärdet är 12. När baslinjeteckensnittet är null ignoreras dess storlek, och baslinjen för alla rader baseras på teckensnittet och storleken på radens största text.

Relaterade API-element

Anger vilken baslinje som ska vara y=0 för rader som är skapade från detta block. Giltiga värden för denna egenskap kan hittas i medlemmarna i klassen TextBaseline.

Standardvärdet är TextBaseline.ROMAN.

Använd följande strängvärden när du ska ange värden för den här egenskapen:

Relaterade API-element

Anger styckeinbäddningsnivån för bidi-text i textblocket. I allmänhet bör du använda 0 för stycken med text som löper från vänster till höger (t.ex. engelska, japanska) och 1 för stycken med text som löper från höger till vänster (t.ex. arabiska, hebreiska). Användning av andra värden än 0 eller 1 är reserverad för specialfall. Läs mer i UAX#9, "Unicode Bidirectional Algorithm" (http://www.unicode.org/reports/tr9/).

Standardvärdet är 0.

Om du ändrar bidiLevel ändras giltigheten för alla tidigare brutna rader till TextLineValidity.INVALID. När bidiLevelhar ändrats är egenskapen firstInvalidLine lika med egenskapen firstLine, och du måste radbryta alla rader i TextBlock igen.

Relaterade API-element

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Innehåller textblockets innehåll. Eftersom ContentElement är en basklass ska du tilldela content en instans av en ContentElement-underklass: TextElement, GraphicElement eller GroupElement. Ett TextElement-objekt innehåller en String, ett GraphicElement-objekt innehåller ett DisplayObject och ett GroupElement innehåller ett Vektor-objekt som innehåller ett eller flera TextElement, GraphicElement eller andra GroupElement-objekt. Använd ett TextElement för ett stycke med homogen text, ett GraphicElement för en grafik och GroupElement för en kombination av text- och grafikelement eller flera instanser av dessa element eller andra GroupElement-objekt.

Standardvärdet är null.

Om du ändrar content-egenskapen ändras giltigheten för alla tidigare skapade rader till TextLineValidity.INVALID. När content har ändrats är egenskapen firstInvalidLine lika med egenskapen firstLine, och du måste radbryta alla rader i TextBlock igen.

Relaterade API-element

Identifierar den första raden i textblocket där TextLine.validity inte är lika med TextLineValidity.VALID.

Standardvärdet är null.

Relaterade API-element

Det första TextLine i TextBlock, om något.

Standardvärdet är null.

Relaterade API-element

Det sista TextLine i TextBlock, om något.

Standardvärdet är null.

Relaterade API-element

Roterar textraderna i textblocket som en enhet. Du måste anropa metoden createTextLine() efter att du har angett lineRotation för att den ska börja gälla. Standardvärdet är TextRotation.ROTATE_0.

Den slutliga rotationen för en glyf beror på värdena för ElementFormat.textRotation, ContentElement.textRotation och TextBlock.lineRotation.

TextBlock.lineRotation används i allmänhet för asiatisk text. Så här skapar du ett lodrätt stycke med japansk text:

1. Ange egenskapen TextBlock.lineRotation till TextRotation.ROTATE_90.
2. Låt egenskapen ElementFormat.textRotation för innehållet behålla standardvärdet, TextRotation.AUTO.

Använd följande konstanter (definieras i klassen TextRotation) när du anger värdet för den här egenskapen:

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Anger tabbstoppen för texten i textblocket i form av en vektor med TabStop-objekt.

Standardvärdet är null, vilket innebär att inga tabbstopp har angetts. När inga tabbstopp har angetts (eller insättningspunkten är bortom det sista angivna tabbstoppet) skapas som standard tabbstopp med en halv tums mellanrum.

När egenskapen tabStops ställs in, skapar TextBlock en kopia av Vector för intern användning. TextBlock påverkas inte av ändringar av ursprunglig Vector eller dess innehåll. När egenskapen tabStops efterfrågas, returneras en kopia av intern Vector. TextBlock påverkas inte heller här av ändringar av denna returnerade vektor.

Relaterade API-element

Anger den TextJustifier som ska användas när rader skapas.

Standardvärdet är ett konstruerat standard-TextJustifier-objekt.

När egenskapen textJustifier ställs in, skapar TextBlock en kopia av objektet för intern användning. TextBlock påverkas inte av ändringar av originalobjektet. När egenskapen textJustifier efterfrågas, returneras en kopia av det interna objektet. TextBlock påverkas inte heller här av ändringar av detta returnerade objekt.

Relaterade API-element

Anger resultatet av en createTextLine()-åtgärd. Om blockets innehåll ändras blir tidigare brutna rader ogiltiga och den här egenskapen återställs till null.

Standardvärdet är null.

Värdena för den här egenskapen finns i TextLineCreationResult.

Relaterade API-element

Medger att programmet kan koppla godtyckliga data till textblocket. Data kan vara information som hänvisar till innehållet, t.ex. ett revisionsdatum eller författarens namn, eller också kan det vara cachade data som du använder under bearbetningen.

Skapar ett TextBlock-objekt

Relaterade API-element

Instruerar textblocket att skapa en textrad från innehållet med början vid den punkt som anges av previousLine-parametern och brytningen vid punkten som anges width-parametern. Textraden är ett TextLine-objekt som du kan lägga till i visningslistan.

Att bryta rader över ett område i ett textblock som redan har brutits, kan förändra giltigheten hos raderna i och efter det område i vilket radbrytningen sker. Radstatusen kan ändras från VALID till INVALID eller POSSIBLY_INVALID. Om en nyligen bruten rad justerar perfekt mot en tidigare bruten rad som har en status POSSIBLY_INVALID, återställs status VALID för den föregående brutna raden och alla efterföljande POSSIBLY_INVALID-rader. Giltigheten för rader som har ställts in på värden som inte är medlemmar av TextLineValidity ändras inte till VALID, men kan ändras till INVALID. Kontrollera firstInvalidLine-egenskapen efter ändringar i textblock för att se var radbrytningen ska börja eller fortsätta.

Du kan skapa artificiella ordbrytningar genom att inkludera ett ZWSP-tecken (Unicode Zero Width Space) i texten. Detta kan vara användbart för språk som thai, som kräver ett lexikon för korrekt radbrytning. Flash-miljön innehåller inte ett sådant lexikon.

För att minska minnesbelastningen bör användaren anropa metoden releaseLineCreationData() så snart alla rader har skapats (om du inte förväntar dig att raderna behöver brytas om upprepade gånger till exempel på grund av att behållarens storlek ändras). Detta bör göras för att textblocket ska kunna släppa tillfälliga data som är kopplade till radbrytning.

Parametrar

Relaterade API-element

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Dumpar det underliggande innehållet i TextBlock som en XML-sträng. Detta kan vara användbart vid automatiserad testning och inkluderar text, formatering och layoutinformation.

Följande beskriver utdata:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Du hittar en beskrivning av utdata för alla rader i metoden TextLine.dump().

Obs! Innehållet i och formatet på utdata kan komma att ändras i framtiden. Adobe garanterar inte metodens bakåtkompatibilitet.

Relaterade API-element

Hittar indexet för nästa atomgräns från det angivna teckenindexet, exklusive tecknet vid det angivna indexet. Tecknen mellan atomgränserna kombineras så att de bildar en atom i en TextLine, t.ex. ett ”e” och en akut accent.

Parametrar

Relaterade API-element

Hittar indexet för nästa ordgräns från det angivna teckenindexet, exklusive tecknet vid det angivna indexet. Ordgränserna bestäms utifrån tecknens Unicode-egenskaper.

Parametrar

Hittar indexet för föregående atomgräns till det angivna teckenindexet, exklusive tecknet vid det angivna indexet. Tecknen mellan atomgränserna kombineras så att de bildar en atom i en TextLine, t.ex. ett ”e” och en akut accent.

Parametrar

Relaterade API-element

Hittar indexet för föregående ordgräns till det angivna teckenindexet, exklusive tecknet vid det angivna indexet. Ordgränserna bestäms utifrån tecknens Unicode-egenskaper.

Parametrar

Returnerar TextLine som innehåller det tecken som anges av parametern charIndex.

Parametrar

Instruerar textblocket att återanvända en befintlig textrad för att skapa en textrad från innehållet, med början vid den punkt som anges av previousLine-parametern och med radbrytningen vid den punkt som anges av width-parametern. Textraden är ett TextLine-objekt som du kan lägga till i visningslistan. Tack vare att en befintlig textrad återanvänds förbättras prestandan eftersom färre objekt behöver skapas.

Om den textLine som återskapas finns i ett textblock frigörs den från textblocket. Dessutom återställs alla egenskaper, inklusive ärvda egenskaper från DisplayObjectContainer, InteractiveObject och DisplayObject, till standardvärdena. Slutligen tas alla underordnade för raden bort, inklusive grafikelement och andra dekorationer, och alla händelseavlyssnare för raden tas bort. Det enda undantaget i denna fullständiga återställning är att själva raden inte tas bort från dess överordnade vilket förbättrar prestandan.

Att bryta rader över ett område i ett textblock som redan har brutits, kan förändra giltigheten hos raderna i och efter det område i vilket radbrytningen sker. Radstatusen kan ändras från VALID till INVALID eller POSSIBLY_INVALID. Om en nyligen bruten rad justerar perfekt mot en tidigare bruten rad som har en status POSSIBLY_INVALID, återställs status VALID för den föregående brutna raden och alla efterföljande POSSIBLY_INVALID-rader. Giltigheten för rader som har ställts in på värden som inte är medlemmar av TextLineValidity ändras inte till VALID, men kan ändras till INVALID. Kontrollera firstInvalidLine-egenskapen efter ändringar i textblock för att se var radbrytningen ska börja eller fortsätta.

Du kan skapa artificiella ordbrytningar genom att inkludera ett ZWSP-tecken (Unicode Zero Width Space) i texten. Detta kan vara användbart för språk som thai, som kräver ett lexikon för korrekt radbrytning. Flash-miljön innehåller inte ett sådant lexikon.

För att minska minnesbelastningen bör användaren anropa metoden releaseLineCreationData() så snart alla rader har skapats (om du inte förväntar dig att raderna behöver brytas om upprepade gånger till exempel på grund av att behållarens storlek ändras). Detta bör göras för att textblocket ska kunna släppa tillfälliga data som är kopplade till radbrytning.

Parametrar

Relaterade API-element

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Instruerar textblocket att släppa alla tillfälliga data som är kopplade till att skapa textrader. Om du vill minimera programmets minnesanvändning bör du anropa metoden releaseLineCreationData() när du har skapat alla textrader från ett textblock. Om du däremot vill maximera prestanda för att radbryta raderna på nytt (till exempel när behållarens storlek ändras) bör du inte anropa metoden releaseLineCreationData(). Programmet avgör hur minnesanvändning och prestanda används.

Rekommenderat arbetssätt för text som inte väntas förändras är: initiera ett textblock, anropa metoden createTextLine() efter behov för att skapa önskade utdata och anropa sedan metoden releaseLineCreationData().

Relaterade API-element

Tar bort ett textradsintervall från radlistan som underhålls av TextBlock. Detta gör att raderna kan skräpsamlas om det inte finns några andra referenser.

Anger värdet för medlemmarna textBlock, nextLine och previousLine i den borttagna raden som null. Anger värdet validity för de borttagna raderna och alla rader som kommer efter dem i TextBlock som TextLineValidity.INVALID.

Parametrar

Relaterade API-element