FontDescription  - AS3

Den typ av CFF-indikering som används för denna text. Använd CFFHinting-konstanter för den här egenskapen. Den här egenskapen gäller bara om egenskapen RenderingMode för texten är inställd på RenderingMode.CFF.

Den typ av CFF-utjämning (Compact Font Format) som används avgör om Flash-miljön tvingar in kraftiga vågräta linjer mot rutnätet under pixelnivå eller inte.

Gäller endast inbäddade teckensnitt.

Standardvärdet är CFFHinting.HORIZONTAL_STEM.

För egenskapen CFFHinting kan du använda följande konstanter från klassen CFFHinting:

Relaterade API-element

Anger hur teckensnittet ska slås upp.

Standardvärdet är FontLookup.DEVICE.

Använd följande strängvärden när du ska ange värden för den här egenskapen:

Relaterade API-element

Namnet på det teckensnitt som ska användas eller en kommaavgränsad lista med teckensnittsnamn. Miljön återger elementet med det första tillgängliga teckensnittet i listan. ”Arial, Helvetica, _sans” medför till exempel att spelaren söker efter Arial först, sedan efter Helvetica om Arial inte hittas och slutligen efter _sans, om ingendera hittas.

Flash-miljöer har stöd för tre allmänna enhetsteckensnittsnamn: _sans (för sans serif-teckensnitt), _serif (för serif-teckensnitt) och _typewriter (för teckensnitt med fast teckenbredd). Dessa mappas till särskilda enhetsteckensnitt beroende på plattformen.

Standardvärdet är "_serif".

Flash-miljöer har reservteckensnitt för specialtecken som inte hittas i det valda teckensnittet. Om specialtecknet inte hittas i teckensnittet försöker miljön återge det med ett annat enhetsteckensnitt som kan tänkas innehålla specialtecknet (oavsett om det teckensnitt som används är ett inbäddat teckensnitt eller ett enhetsteckensnitt).

Relaterade API-element

Anger teckensnittsläge.

Standardvärdet är FontPosture.NORMAL.

Ange värden för den här egenskapen med följande konstanter i klassen FontPosture:

Relaterade API-element

Anger teckensnittsstil.

Standardvärdet är FontWeight.NORMAL.

Ange värden för den här egenskapen med följande konstanter i klassen FontWeight:

Relaterade API-element

Anger om FontDescription är låst eller inte. Om true, går det inte att ändra FontDescription. Anropa FontDescription.clone() för att hämta en olåst kopia av FontDescription-objektet.

Det återgivningsläge som används för den här texten. Använd RenderingMode-konstanter för den här egenskapen.

Gäller endast inbäddade teckensnitt.

Standardvärdet är RenderingMode.CFF.

Ange värden för den här egenskapen med följande konstanter i klassen RenderingMode:

Relaterade API-element

Skapar ett FontDescription-objekt.

Skapar en olåst, klonad kopia av FontDescription.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescription_cloneExample extends Sprite {
        private var fd:FontDescription;
        private var fd2:FontDescription;
        
        public function FontDescription_cloneExample():void {
            fd = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            fd2 = (fd.locked) ? fd.clone() : fd;    
            fd2.fontWeight = flash.text.engine.FontWeight.NORMAL;
            var ef2:ElementFormat = new ElementFormat(fd2);

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

Returnerar true om ett användbart enhetsteckensnitt är tillgängligt med angivna fontName, fontWeight och fontPosture.

flash.text.engine-klasser kan bara använda OpenType- och TrueType-enhetsteckensnitt. Om ett teckensnitt som bygger på äldre teckensnittsteknik används ersätts det med kända, fungerande teckensnitt som tecken för tecken återger texten.

Parametrar

Relaterade API-element

Returnerar true om ett inbäddat teckensnitt är tillgängligt med angivet fontName, angiven fontWeight och angivet fontPosture, där Font.fontType är flash.text.FontType.EMBEDDED_CFF. Från och med Flash Player 10 kan två olika typer av inbäddade teckensnitt visas i programinnehåll. Normalt inbäddade teckensnitt används endast av TextField-objekt. CFF-inbäddade teckensnitt används endast av klasserna flash.text.enginge. De två typerna särskiljs med fontType-egenskapen för klassen Font, som de returneras av funktionen enumerateFonts().

flash.text.engine-klasserna kan inte använda ett teckensnitt av typen EMBEDDED. Om fontLookup är inställt på FontLookup.EMBEDDED_CFF, och det enda teckensnitt som är tillgängligt vid körning med det namn, den stil och det läge som anges är av typen EMBEDDED, används i stället enhetsteckensnitt på teckenbasis för att återge texten, som om inget inbäddat teckensnitt med angivet namn och format finns.

Om det finns både EMBEDDED- och EMBEDDED_CFF-teckensnitt med samma namn, stil och läge tillgängliga, väljs EMBEDDED_CFF-teckensnittet och texten återges med teckensnittet EMBEDDED_CFF.

Parametrar

Relaterade API-element

Det här exemplet skapar ett FontDescription-objekt, tilldelar det ett enhetsteckensnitt, anger olika egenskaper för teckensnitt och tilldelar det nya objektet till ett ElementFormat-objekt. Ytterligare teckensnittsformatering görs i ElementFormat. Ett nytt TextElement skapas med ElementFormat, och TextElement används som innehåll för ett TextBlock. En textrad skapas från TextBlock.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontDescriptionExample extends Sprite {
        
        public function FontDescriptionExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;
            fd.fontPosture = flash.text.engine.FontPosture.ITALIC;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
        }
    }    
}