| Paket | flash.text.engine |
| Klass | public final class ElementFormat |
| Arv | ElementFormat  Object |
| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ett ElementFormat-objekt som används på ett ContentElement i ett TextBlock medför inte att TextBlock blir ogiltigt. När ett ElementFormat-objekt har använts på ett ContentElement ställs dess locked-egenskap in på true. Egenskaperna för ett låst ElementFormat-objekt kan inte ändras. Använd i stället metoden clone() för att skapa en olåst kopia av objeket som kan ändras och tilldelas till ContentElement.
Relaterade API-element
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaper| Egenskap | Definieras med | ||
|---|---|---|---|
| alignmentBaseline : String
Anger den typ av baslinje i behållarelementet efter vilken dominanta baslinjer i element med det här formatet ska justeras. | ElementFormat | ||
| alpha : Number
Anger genomskinlighet för de radelement som påverkas av det här objektet. | ElementFormat | ||
| baselineShift : Number
Anger baslinjeförflyttning för elementet i pixlar. | ElementFormat | ||
| breakOpportunity : String
Radbrytningsmöjligheten som används i denna text. | ElementFormat | ||
| color : uint
Anger textens färg. | ElementFormat | ||
 | constructor : Object
En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans. | Object | |
| digitCase : String
Det skiftläge för siffror som används för den här texten. | ElementFormat | ||
| digitWidth : String
Den sifferbredd som används för den här texten. | ElementFormat | ||
| dominantBaseline : String
Anger den typ av baslinje som ska användas som dominant baslinje. | ElementFormat | ||
| fontDescription : FontDescription
Ett objekt vars egenskaper beskriver ett teckensnitt. | ElementFormat | ||
| fontSize : Number
Textstorleken i pixlar. | ElementFormat | ||
| kerning : String
Kerning justerar pixlarna mellan vissa teckenpar för att öka läsbarheten. | ElementFormat | ||
| ligatureLevel : String
Den ligaturnivå som används för den här texten. | ElementFormat | ||
| locale : String
Textens språkinställning. | ElementFormat | ||
| locked : Boolean
Anger om ElementFormat är låst. | ElementFormat | ||
| textRotation : String
Ställer in rotationen som används för enskilda glyfer. | ElementFormat | ||
| trackingLeft : Number
Den spårning eller manuella kerning som används till vänster om varje glyf i pixlar. | ElementFormat | ||
| trackingRight : Number
Den spårning eller manuella kerning som används till höger om varje glyf i pixlar. | ElementFormat | ||
| typographicCase : String
Den skiftlägestypografi som används för den här texten. | ElementFormat | ||
| Metod | Definieras med | ||
|---|---|---|---|
ElementFormat(fontDescription:FontDescription = null, fontSize:Number = 12.0, color:uint = 0x000000, alpha:Number = 1.0, textRotation:String = "auto", dominantBaseline:String = "roman", alignmentBaseline:String = "useDominantBaseline", baselineShift:Number = 0.0, kerning:String = "on", trackingRight:Number = 0.0, trackingLeft:Number = 0.0, locale:String = "en", breakOpportunity:String = "auto", digitCase:String = "default", digitWidth:String = "default", ligatureLevel:String = "common", typographicCase:String = "default")
Skapar ett ElementFormat-objekt. | ElementFormat | ||
Skapar en olåst, klonad kopia av ElementFormat. | ElementFormat | ||
Returnerar ett FontMetrics-objekt med egenskaper som beskriver emBox, genomstrykningsposition, genomstrykningstjocklek, understrykningsposition och understrykningstjocklek för det teckensnitt som anges av fontDescription och fontSize.
| ElementFormat | ||
|
Anger om det finns en egenskap angiven för ett objekt. | Object | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
|
Returnerar det angivna objektets strängbeteckning. | Object | |
|
Returnerar det angivna objektets primitiva värde. | Object | |
alignmentBaseline | egenskap |
alignmentBaseline:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Anger den typ av baslinje i behållarelementet efter vilken dominanta baslinjer i element med det här formatet ska justeras. Använd TextBaseline-konstanter för den här egenskapen.
Baslinjejusteringen avgörs av radens största lodräta elementet, om inte TextBlock.baselineFontDescription och TextBlock.baselineFontSize har ställts in så att de åsidosätter detta.
Standardvärdet är TextBaseline.USE_DOMINANT_BASELINE.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
TextBaseline.ROMAN | dominantBaseline justeras mot radens latinska baslinje. |
TextBaseline.ASCENT | dominantBaseline justeras mot radens stigande baslinje. |
TextBaseline.DESCENT | dominantBaseline justeras mot radens sjunkande baslinje. |
TextBaseline.IDEOGRAPHIC_TOP | dominantBaseline justeras mot radens ideografiska övre baslinje. |
TextBaseline.IDEOGRAPHIC_CENTER | dominantBaseline justeras mot radens ideografiska centrala baslinje. |
TextBaseline.IDEOGRAPHIC_BOTTOM | dominantBaseline justeras mot radens ideografiska nedre baslinje. |
TextBaseline.USE_DOMINANT_BASELINE | dominantBaseline justeras mot samma baslinje för raden. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Anger radens justeringsbaslinje som grafikelementets dominantBaseline justeras mot. |
GroupElement | Har ingen effekt. |
TextElement | Anger radens justeringsbaslinje som textelementets dominantBaseline justeras mot. |
Implementering
public function get alignmentBaseline():String public function set alignmentBaseline(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av TextBaseline.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
alpha | egenskap |
alpha:Number| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Anger genomskinlighet för de radelement som påverkas av det här objektet. Giltiga värden är från 0 (helt genomskinlig) till 1 (helt ogenomskinlig). Visningsobjekt med alpha inställt på 0 är aktiva trots att de är osynliga.
Standardvärdet är 1.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Tillämpar angiven alfa på grafikelementet. Kombinerar multiplikativt med angiven alfa på det grafiska DisplayObject eller på TextLine. |
GroupElement | Har ingen effekt. |
TextElement | Tillämpar angiven alfa på textelementet. Kombinerar multiplikativt med angiven alfa på TextLine. |
Implementering
public function get alpha():Number public function set alpha(value:Number):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
baselineShift | egenskap |
baselineShift:Number| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Anger baslinjeförflyttning för elementet i pixlar.
Så här mycket flyttas elementet från dominantBaseline. Förskjutningen adderas till y-positionen för medlemmarna av elementet. I text som inte roteras innebär en positiv baslinjeförflyttning att elementet flyttas nedåt och en negativ baslinjeförflyttning att elementet flyttas uppåt.
Standardvärdet är 0.0, vilket anger att ingen förflyttning görs.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Flyttar grafiken bort från baslinjen. |
GroupElement | Har ingen effekt. |
TextElement | Flyttar texten bort från baslinjen. |
Implementering
public function get baselineShift():Number public function set baselineShift(value:Number):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
breakOpportunity | egenskap |
breakOpportunity:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Radbrytningsmöjligheten som används i denna text. Denna egenskap avgör vilka tecken som kan användas för radbrytning när text bryts ned till flera rader. Använd BreakOpportunity-konstanter för den här egenskapen.
Standardvärdet är BreakOpportunity.AUTO.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
BreakOpportunity.AUTO | Radbrytningsmöjligheterna baseras på standard-Unicode-teckenegenskaper, t.ex. brytningar mellan ord och avstavningar. |
BreakOpportunity.ANY | Varje tecken i ContentElement-objektet hanteras som en radbrytningsmöjlighet. Det här värdet används vanligtvis då latinsk text är inbäddad i asiatisk text och det är önskvärt med brytningar mitt i orden. |
BreakOpportunity.NONE | Inga tecken i området hanteras som radbrytningsmöjligheter. |
BreakOpportunity.ALL | Alla tecken i intervallet behandlas som radbrytningsmöjligheter, vilket innebär att en radbrytning infogas efter varje tecken. Praktiskt när du skapar effekter som text på en bana. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Bestämmer brytningsmöjligheten mellan angränsande textelement i gruppen. Om gruppens elementFormat är null används formatet för det första av de angränsande elementen. |
TextElement | Bestämmer brytningsmöjligheten mellan tecknen i textelementet. |
Implementering
public function get breakOpportunity():String public function set breakOpportunity(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av BreakOpportunity.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
color | egenskap |
color:uint| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Anger textens färg. Ett heltal som innehåller tre 8-bitars RGB-komponenter. 0xFF0000 är t.ex. rött och 0x00FF00 är grönt.
Standardvärdet är 0x000000, vilket är svart.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Anger textens färg. |
Implementering
public function get color():uint public function set color(value:uint):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
digitCase | egenskap |
digitCase:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Det skiftläge för siffror som används för den här texten. Skiftläge för siffror påverkar format och positionering på grupper av numeriska tecken. Använd DigitCase-konstanter för den här egenskapen.
Standardvärdet är DigitCase.DEFAULT.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
DigitCase.DEFAULT | Använder standardskiftläget för siffror i texten. |
DigitCase.LINING | Använder skiftläget för Lining-siffror i texten. |
DigitCase.OLD_STYLE | Använder skiftläget för siffror i gammal stil i texten. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer vilket skiftläge för siffror som används för texten i elementet. |
Implementering
public function get digitCase():String public function set digitCase(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av DigitCase.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
digitWidth | egenskap |
digitWidth:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Den sifferbredd som används för den här texten. Använd DigitWidth-konstanter för den här egenskapen.
Standardvärdet är DigitWidth.DEFAULT.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
DigitWidth.DEFAULT | Tillämpar standardsifferbredd i texten. |
DigitWidth.PROPORTIONAL | Tillämpar proportionell sifferbredd i texten. |
DigitWidth.TABULAR | Tillämpar tabulär sifferbredd i texten. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer vilken sifferbredd som används för texten i elementet. |
Implementering
public function get digitWidth():String public function set digitWidth(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av DigitWidth.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
dominantBaseline | egenskap |
dominantBaseline:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Anger den typ av baslinje som ska användas som dominant baslinje. Den dominanta baslinjen justeras efter justeringsbaslinjen för att avgöra elementets lodräta position på raden. Använd TextBaseline-konstanter för den här egenskapen.
Innehållet i elementet avgör baslinjerna. För TextElement avgörs baslinjerna av teckensnittet och punktstorleken. För GraphicElement avgörs baslinjerna av elementets höjd.
Standardvärdet är TextBaseline.ROMAN.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
TextBaseline.ROMAN | Elementets latinska baslinje justeras mot alignmentBaseline. |
TextBaseline.ASCENT | Elementets stigande baslinje justeras mot alignmentBaseline. |
TextBaseline.DESCENT | Elementets sjunkande baslinje justeras mot alignmentBaseline. |
TextBaseline.IDEOGRAPHIC_TOP | Elementets ideografiska övre baslinje justeras mot alignmentBaseline. |
TextBaseline.IDEOGRAPHIC_CENTER | Elementets ideografiska centrala baslinje justeras mot alignmentBaseline. |
TextBaseline.IDEOGRAPHIC_BOTTOM | Elementets ideografiska nedre baslinje justeras mot alignmentBaseline. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Bestämmer vilken av baslinjerna för grafikelementet som justeras mot alignmentBaseline. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer vilken av baslinjerna för textelementet som justeras mot alignmentBaseline. |
Implementering
public function get dominantBaseline():String public function set dominantBaseline(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av TextBaseline.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
fontDescription | egenskap |
fontDescription:FontDescription| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ett objekt vars egenskaper beskriver ett teckensnitt.
Standardvärdet är ett standardkonstruerat FontDescription-objekt.
När egenskapen fontDescription anges låses det angivna FontDescription-objektet: dess locked-egenskap får värdet true. En låst FontDescription går inte att ändra.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer vilket teckensnitt som används för texten i elementet. |
Implementering
public function get fontDescription():FontDescription public function set fontDescription(value:FontDescription):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
fontSize | egenskap |
fontSize:Number| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Textstorleken i pixlar.
Standardvärdet är 12.0.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer vilken storlek i pixlar som används för texten i elementet. |
Implementering
public function get fontSize():Number public function set fontSize(value:Number):voidUtlöser
ArgumentError — Om det angivna värdet är mindre än noll.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
kerning | egenskap |
kerning:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Kerning justerar pixlarna mellan vissa teckenpar för att öka läsbarheten. Kerning stöds för alla teckensnitt som har kerningtabeller.
Standardvärdet är Kerning.ON.
Ange värden för den här egenskapen med följande konstanter i klassen Kerning:
| Strängvärde | Beskrivning |
|---|---|
Kerning.ON | Kerning är aktiverad. |
Kerning.OFF | Kerning är inaktiverad. |
Kerning.AUTO | Kerning är aktiverat, utom i de fall det inte lämpar sig för asiatiskt text. Kerning tillämpas mellan två tecken, om inget av dem är Kanji, Hiragana eller Katakana. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Bestämmer om kerning ska tillämpas mellan angränsande textelement i gruppen. Om gruppens elementFormat är null används formatet för det första av de angränsande elementen. |
TextElement | Bestämmer om kerning ska tillämpas mellan tecknen i textelementet. |
Implementering
public function get kerning():String public function set kerning(value:String):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
ligatureLevel | egenskap |
ligatureLevel:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Den ligaturnivå som används för den här texten. En ligatur inträffar där två eller flera bokstavsformer sammanfogas som en enda glyf. Ligaturer ersätter vanligtvis konsekutiva tecken som delar gemensamma komponenter, till exempel bokstavspar 'fi', 'fl' eller 'ae'. De används med både latinska och icke-latinska teckenuppsättningar. Använd LigatureLevel-konstanter för den här egenskapen.
Standardvärdet är LigatureLevel.COMMON.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
LigatureLevel.NONE | Inga ligaturer skapas. |
LigatureLevel.MINIMUM | Minimala ligaturer skapas. |
LigatureLevel.COMMON | Vanliga ligaturer skapas. |
LigatureLevel.UNCOMMON | Ovanliga ligaturer skapas. |
LigatureLevel.EXOTIC | Exotiska ligaturer skapas. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Bestämmer ligaturnivån mellan angränsande textelement i gruppen. Om gruppens elementFormat är null används formatet för det första av de angränsande elementen. |
TextElement | Bestämmer ligaturnivån mellan tecknen i textelementet. |
Implementering
public function get ligatureLevel():String public function set ligatureLevel(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av LigatureLevel.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
locale | egenskap |
locale:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Textens språkinställning. Styr skiftlägesomvandlingar och -formning. Standardidentifierare för språk används. Till exempel används "en", "en_US" och "en-US" för engelska och "ja" för japanska. Den här iso639-2-kodlistan innehåller en lista över språkkoder.
Standardvärdet är "en".
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer omvandlingar och formning för texten i elementet. |
Implementering
public function get locale():String public function set locale(value:String):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
locked | egenskap |
locked:Boolean| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5., Flash Lite 4 |
Anger om ElementFormat är låst. Om true, går det inte att ändra ElementFormat. Anropa ElementFormat.clone() för att hämta en olåst kopia av ElementFormat-objektet.
Implementering
public function get locked():Boolean public function set locked(value:Boolean):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
textRotation | egenskap |
textRotation:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ställer in rotationen som används för enskilda glyfer. Använd konstanter som definieras i klassen TextRotation för den här egenskapen.
Standardvärdet är TextRotation.AUTO.
Den slutliga rotationen för en glyf är summan av ElementFormat.textRotation, ContentElement.textRotation och TextBlock.lineRotation.
Den här egenskapen används vanligtvis för asiatisk text, där tecknen måste roteras för att visas korrekt i en lodrät layout. Använd TextRotation.AUTO i kombination med TextBlock.lineRotation = TextRotation.ROTATE_90 för att uppnå detta.
Om den här egenskapen anges för teckensnitt som inte innehåller lodrät layoutinformation kan det ge oönskade resultat. Teckensnitt som innehåller en vmtx- eller VORG-tabell, t.ex. det japanska teckensnittet MS Mincho, fungerar korrekt eftersom tabellerna anger de data som layoutmotorn kräver för korrekt layout. Teckensnitt, t.ex. Verdana, som inte innehåller den nödvändiga informationen gör inte det.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
TextRotation.ROTATE_0 | Glyferna roteras inte. |
TextRotation.ROTATE_90 | Glyferna roteras 90 grader medurs. |
TextRotation.ROTATE_180 | Glyferna roteras 180 grader. |
TextRotation.ROTATE_270 | Glyferna roteras 270 grader medurs. |
TextRotation.AUTO | Anger 90 graders rotation moturs enbart för de hela och breda glyfer som anges i glyfens Unicode-egenskaper. Detta värde används typiskt med asiatisk text för att rotera enbart de glyfer som kräver rotation. Denna rotation används bara på vertikal text för att returnera full bredd och breda tecken på en vertikal orientering utan att påverka andra tecken. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer rotationen för glyferna i textelementet. |
Implementering
public function get textRotation():String public function set textRotation(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av TextRotation.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
trackingLeft | egenskap |
trackingLeft:Number| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5., Flash Lite 4 |
Den spårning eller manuella kerning som används till vänster om varje glyf i pixlar. Om kerning är aktiverad läggs trackingLeft-värdet till bland värdena i kerningtabellen för teckensnittet. Om kerning är inaktiverad används trackingLeft-värdet som ett manuellt kerningvärde. Stöder både positiva och negativa värden.
Det önskade spårningsvärdet delas vanligtvis mellan trackingRight och trackingLeft. Annars är spårningen i text med blandad riktning dubbelt så stor som spårning vid en bidi-gräns och ingen vid den andra.
Standardvärdet är 0.0.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Avgör spårningen som används i bildens vänstra sida. |
GroupElement | Har ingen effekt. |
TextElement | Avgör spårningen som används på tecken i textelementets vänstra sida. |
Exempel:
//positive tracking added to kerning
var ef1:ElementFormat = new ElementFormat();
ef1.kerning = flash.text.engine.Kerning.ON;
ef1.trackingLeft = 0.5;
//negative manual kerning
var ef2:ElementFormat = new ElementFormat();
ef2.kerning = flash.text.engine.Kerning.OFF;
ef2.trackingLeft = -1.0;
Implementering
public function get trackingLeft():Number public function set trackingLeft(value:Number):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
trackingRight | egenskap |
trackingRight:Number| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5., Flash Lite 4 |
Den spårning eller manuella kerning som används till höger om varje glyf i pixlar. Om kerning är aktiverad läggs trackingRight-värdet till bland värdena i kerningtabellen för teckensnittet. Om kerning är inaktiverad används trackingRight-värdet som ett manuellt kerningvärde. Stöder både positiva och negativa värden.
Det önskade spårningsvärdet delas vanligtvis mellan trackingRight och trackingLeft. Annars är spårningen i text med blandad riktning dubbelt så stor som spårning vid en bidi-gräns och ingen vid den andra.
Standardvärdet är 0.0.
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Avgör spårningen som används i bildens högra sida. |
GroupElement | Har ingen effekt. |
TextElement | Avgör spårningen som används på tecken i textelementets högra sida. |
Exempel:
//positive tracking added to kerning
var ef1:ElementFormat = new ElementFormat();
ef1.kerning = flash.text.engine.Kerning.ON;
ef1.trackingRight = 0.5;
//negative manual kerning
var ef2:ElementFormat = new ElementFormat();
ef2.kerning = flash.text.engine.Kerning.OFF;
ef2.trackingRight = -1.0;
Implementering
public function get trackingRight():Number public function set trackingRight(value:Number):voidUtlöser
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
typographicCase | egenskap |
typographicCase:String| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Den skiftlägestypografi som används för den här texten. Använd konstanter som definieras i klassen TypographicCase för den här egenskapen.
Standardvärdet är TypographicCase.DEFAULT.
Använd följande strängvärden när du ska ange värden för den här egenskapen:
| Strängvärde | Beskrivning |
|---|---|
TypographicCase.DEFAULT | Anger att normal bokstavstyp används för alla tecken. |
TypographicCase.TITLE | Anger att rubrikglyfer används för versaler i utdata. |
TypographicCase.CAPS | Anger att teckenavståndet justeras för versaler i utdata. |
TypographicCase.SMALL_CAPS | Anger att gemena glyfer används för versaler i utdata. |
TypographicCase.UPPERCASE | Anger att versala glyfer används för alla tecken i utdata. |
TypographicCase.LOWERCASE | Anger att gemena glyfer används för alla tecken i utdata. |
TypographicCase.CAPS_AND_SMALL_CAPS | Anger att gemena glyfer används för alla gemener i utdata. |
| Underklass | Effekten av att ställa in egenskapen |
|---|---|
GraphicElement | Har ingen effekt. |
GroupElement | Har ingen effekt. |
TextElement | Bestämmer vilken skiftlägestypografi som används för texten i elementet. |
Implementering
public function get typographicCase():String public function set typographicCase(value:String):voidUtlöser
ArgumentError — Om den anges till ett värde som inte är medlem av TypographicCase.
| |
IllegalOperationError — Om det anges efter att ElementFormat-objektet har låsts (locked är true).
|
Relaterade API-element
ElementFormat | () | Konstruktor |
public function ElementFormat(fontDescription:FontDescription = null, fontSize:Number = 12.0, color:uint = 0x000000, alpha:Number = 1.0, textRotation:String = "auto", dominantBaseline:String = "roman", alignmentBaseline:String = "useDominantBaseline", baselineShift:Number = 0.0, kerning:String = "on", trackingRight:Number = 0.0, trackingLeft:Number = 0.0, locale:String = "en", breakOpportunity:String = "auto", digitCase:String = "default", digitWidth:String = "default", ligatureLevel:String = "common", typographicCase:String = "default")| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Skapar ett ElementFormat-objekt.
ParametrarfontDescription:FontDescription (default = null)null. Om ingen teckensnittsbeskrivning ges konstrueras en standardteckensnittsbeskrivning.
| |
fontSize:Number (default = 12.0) | |
color:uint (default = 0x000000) | |
alpha:Number (default = 1.0)alpha-egenskapen som används på alla radatomer baserat på elementformatet.
| |
textRotation:String (default = "auto") | |
dominantBaseline:String (default = "roman") | |
alignmentBaseline:String (default = "useDominantBaseline") | |
baselineShift:Number (default = 0.0) | |
kerning:String (default = "on") | |
trackingRight:Number (default = 0.0) | |
trackingLeft:Number (default = 0.0) | |
locale:String (default = "en") | |
breakOpportunity:String (default = "auto") | |
digitCase:String (default = "default") | |
digitWidth:String (default = "default") | |
ligatureLevel:String (default = "common") | |
typographicCase:String (default = "default") |
Utlöser
ArgumentError — Angiven fontSize är mindre än 0.
| |
ArgumentError — Angiven textRotation är inte medlem av TextRotation.
| |
ArgumentError — Angiven dominantBaseline är inte medlem av TextBaseline.
| |
ArgumentError — Angiven alignmentBaseline är inte medlem av TextBaseline.
| |
ArgumentError — Angiven kerning är inte medlem av Kerning.
| |
ArgumentError — Angiven breakOpportunity är inte medlem av BreakOpportunity.
| |
ArgumentError — Angivet digitCase är inte medlem av DigitCase.
| |
ArgumentError — Angiven digitWidth är inte medlem av DigitWidth.
| |
ArgumentError — Angiven ligatureLevel är inte medlem av LigatureLevel.
| |
ArgumentError — Angivet typographicCase är inte medlem av TypographicCase.
|
clone | () | metod |
public function clone():ElementFormat| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Skapar en olåst, klonad kopia av ElementFormat.
ReturnerarElementFormat — En olåst kopia av ElementFormat-objektet.
|
Exempel ( Så här använder du exemplet )
Detta exempel skapar ett ElementFormat-objekt och ställer in en FontSize. Ett nytt TextElement skapas med ElementFormat (och blir därmed låst), och TextElement används som innehåll för ett TextBlock. En textrad skapas från TextBlock.
Om du vill ändra ElementFormat-objektet kontrollerar du först dess locked-egenskap. Om värdet är true använder du metoden clone() för att skapa en olåst kopia av ElementFormat, ändra dess egenskaper och sedan länka om det nya ElementFormat till TextBlock. När raderna bryts på nytt får de nya raderna de nya teckensnittsinställningarna.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class ElementFormat_cloneExample extends Sprite {
private var ef1:ElementFormat;
private var ef2:ElementFormat;
public function ElementFormat_cloneExample():void {
var fd:FontDescription = new FontDescription();
fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
fd.fontName = "Palatino";
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize=20;
var str:String = "This is flash text 0123456789";
var tb:TextBlock = new TextBlock();
var te1:TextElement = new TextElement(str, ef1);
tb.content = te1;
var line1:TextLine = tb.createTextLine(null, 600);
addChild(line1);
ef2 = (ef1.locked) ? ef1.clone() : ef1;
ef2.fontSize = 32;
tb.content.elementFormat=ef2;
var line2:TextLine = tb.createTextLine(null, 600);
addChild(line2);
}
}
}
getFontMetrics | () | metod |
public function getFontMetrics():FontMetrics| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Returnerar ett FontMetrics-objekt med egenskaper som beskriver emBox, genomstrykningsposition, genomstrykningstjocklek, understrykningsposition och understrykningstjocklek för det teckensnitt som anges av fontDescription och fontSize.
FontMetrics — Ett FontMetrics-objekt som beskriver egenskaperna för det teckensnitt som anges av fontDescription.
|
Relaterade API-element
Exempel ( Så här använder du exemplet )
ElementFormat-objekt med en tilldelad FontDescription, och metoden getFontMetrics används för att visa måtten för det valda teckensnittet vid 24 punkter.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class FontMetricsExample extends Sprite {
public function FontMetricsExample():void {
var fd:FontDescription = new FontDescription();
fd.fontName = "Garamond";
fd.fontWeight = flash.text.engine.FontWeight.BOLD;
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize = 24;
var fm1:FontMetrics = ef1.getFontMetrics();
trace(fm1.emBox);
trace(fm1.strikethroughOffset);
trace(fm1.strikethroughThickness);
trace(fm1.subscriptScale);
trace(fm1.subscriptOffset);
trace(fm1.superscriptScale);
trace(fm1.superscriptOffset);
trace(fm1.underlineOffset);
trace(fm1.underlineThickness);
}
}
}
Det här exemplet skapar två ElementFormat-objekt och ställer in flera av deras egenskaper. Exemplet tilldelar sedan de nya ElementFormats till ett TextElement-objekt, som har tilldelats som innehåll för ett TextBlock. Observera att om du ändrar ElementFormat för ett TextElement påverkas inte TextLines som tidigare har skapats av överordnat TextBlock.
package {
import flash.display.Sprite;
import flash.text.engine.*;
public class ElementFormatExample extends Sprite {
public function ElementFormatExample():void {
var fd:FontDescription = new FontDescription();
fd.fontName = "Garamond";
fd.fontWeight = flash.text.engine.FontWeight.BOLD;
var ef1:ElementFormat = new ElementFormat(fd);
ef1.fontSize = 30;
ef1.color = 0xFF0000;
ef1.alpha = 100;
ef1.kerning = flash.text.engine.Kerning.ON;
ef1.trackingRight = 2;
ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
var ef2:ElementFormat = new ElementFormat(fd);
ef2.fontSize = 30;
ef2.color = 0xFF0000;
ef2.alpha = 0.3;
ef2.kerning = flash.text.engine.Kerning.OFF;
ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
var str:String = "This is flash text 0123456789";
var tb:TextBlock = new TextBlock();
var te1:TextElement = new TextElement(str, ef1);
tb.content = te1;
var line1:TextLine = tb.createTextLine(null, 600);
addChild(line1);
line1.x = 15;
line1.y = 30;
tb.content.elementFormat = ef2;
var line2:TextLine = tb.createTextLine(null, 600);
addChild(line2);
line2.x = 15;
line2.y = 60;
}
}
}
Tue Jun 12 2018, 01:40 PM Z