| Paket | flash.text.engine |
| Klass | public final class TextElement |
| Arv | TextElement  ContentElement Object |
| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
content-egenskapen i ett TextBlock-objekt för att skapa ett textblock. Tilldela det till ett GroupElement-objekt och kombinera det med andra textelement och annan grafik till en enhet. Använd klassen ElementFormat när du formaterar texten.
Relaterade API-element
Publika egenskaper
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaper| Egenskap | Definieras med | ||
|---|---|---|---|
 | constructor : Object
En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans. | Object | |
| elementFormat : ElementFormat
ElementFormat-objektet som används för elementet. | ContentElement | |
| eventMirror : EventDispatcher
EventDispatcher-objektet som tar emot kopior av varje händelse som skickas till giltiga textrader baserat på detta innehållselement. | ContentElement | |
| groupElement : GroupElement [skrivskyddad]
Det GroupElement som innehåller det här elementet, eller null om elementet inte ingår i någon grupp. | ContentElement | |
| rawText : String [skrivskyddad]
En kopia av texten i elementet, inklusive eventuella U+FDEF-tecken. | ContentElement | |
| text : String
Tar emot texten som utgör elementets innehåll. | TextElement | ||
| textBlock : flash.text.engine:TextBlock [skrivskyddad]
TextBlock som det här elementet tillhör. | ContentElement | |
| textBlockBeginIndex : int [skrivskyddad]
Indexplatsen i textblocket för det första tecknet i detta element. | ContentElement | |
| textRotation : String
Den rotation som ska användas på elementet som en enhet. | ContentElement | |
| userData : *
Medger att programmet kan koppla godtyckliga data till elementet. | ContentElement | |
Publika metoder
| Metod | Definieras med | ||
|---|---|---|---|
TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")
Skapar en ny TextElement-instans. | TextElement | ||
|
Anger om det finns en egenskap angiven för ett objekt. | Object | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
Ersätter teckenintervallet som anges av parametrarna beginIndex och endIndex med innehållet i parametern newText. | TextElement | ||
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
|
Returnerar det angivna objektets strängbeteckning. | Object | |
|
Returnerar det angivna objektets primitiva värde. | Object | |
Publika konstanter
Egenskapsdetaljer
text | egenskap |
Konstruktordetaljer
TextElement | () | Konstruktor |
public function TextElement(text:String = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Skapar en ny TextElement-instans.
Parametrartext:String (default = null)null.
| |
elementFormat:ElementFormat (default = null)null.
| |
eventMirror:EventDispatcher (default = null)EventDispatcher-objekt som tar emot kopior av alla händelser som skickas till textrader baserat på detta innehållselement. Standardvärdet är null.
| |
textRotation:String (default = "rotate0")TextRotation-konstanter för den här egenskapen. Standardvärdet är TextRotation.ROTATE_0.
|
Exempel ( Så här använder du exemplet )
Följande exempel skapar ett TextElement-objekt från en textsträng, formaterar det med teckenstorleken 12 och färgen röd (0xCC0000), och tilldelar det till
content-egenskapen för ett TextBlock. Det anropar funktionen createLines() för att bryta textblocket i rader om 150 pixlar vardera.
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.ElementFormat;
public class TextElementExample extends Sprite {
public function TextElementExample():void {
var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, " +
"sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut " +
"enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut " +
"aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit " +
"in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur " +
"sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt " +
"mollit anim id est laborum.";
var format:ElementFormat = new ElementFormat(null, 12, 0xCC0000);
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
createLines(textBlock);
}
private function createLines(textBlock:TextBlock):void {
var yPos = 20;
var textLine:TextLine = textBlock.createTextLine (null, 150);
while (textLine)
{
addChild(textLine);
textLine.x = 15;
yPos += textLine.textHeight+2;
textLine.y = yPos;
textLine = textBlock.createTextLine(textLine, 150);
}
}
}
}
Metoddetaljer
replaceText | () | metod |
public function replaceText(beginIndex:int, endIndex:int, newText:String):void| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ersätter teckenintervallet som anges av parametrarna beginIndex och endIndex med innehållet i parametern newText. beginIndex- och endIndex-värdena hänvisar till det aktuella innehållet i text.
Skicka null för newText om du vill ta bort text.
Om du vill infoga text skickar du samma värde för beginIndex och endIndex. Den nya texten infogas före det angivna indexet.
Om du vill lägga till text skickar du text.length för beginIndex och endIndex.
Om du vill ställa in all text skickar du 0 för beginIndex och text.length för endIndex.
Parametrar
beginIndex:int — Det nollbaserade indexvärdet för ersättningsintervallets startposition.
| |
endIndex:int — Det nollbaserade indexvärdet som följer slutpositionen för ersättningsintervallet.
| |
newText:String — Den text som ska användas för att ersätta det angivna teckenintervallet.
|
Utlöser
RangeError — beginIndex eller endIndex är utanför intervallet.
|
Exempel ( Så här använder du exemplet )
Det här exemplet anropar
replaceText() flera gånger för att göra följande:
- infoga en sträng i början av texten
- lägga till en sträng i slutet av texten
- infoga en sträng mitt i texten
- byta ut texten helt och hållet mot ny text.
package {
import flash.display.Sprite;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.TextElement;
import flash.text.engine.TextBlock;
import flash.text.engine.TextLine;
public class TextElement_replaceTextExample extends Sprite {
public function TextElement_replaceTextExample():void {
var str:String = "0123456";
var fontDescription:FontDescription = new FontDescription("Arial");
var format:ElementFormat = new ElementFormat(fontDescription);
format.fontSize = 14;
var textElement:TextElement = new TextElement(str, format);
var textBlock:TextBlock = new TextBlock();
textBlock.content = textElement;
textElement.replaceText(0, 0, "abc");
createLine(textBlock, 20); //"abc0123456"
textElement.replaceText(10, 10, "abc");
createLine(textBlock, 40); // "abc0123456abc"
textElement.replaceText(5, 8, "abc");
createLine(textBlock, 60); // "abc01abc56abc"
textElement.replaceText(0, 13, "abc");
createLine(textBlock, 80); // "abc"
textElement.replaceText(0, 3, "That's all she wrote!");
createLine(textBlock, 100); // "That's all she wrote" */
}
private function createLine(textBlock:TextBlock, y:Number):void {
var textLine:TextLine = textBlock.createTextLine(null, 150);
textLine.x = 10;
textLine.y = y;
addChild(textLine);
}
}
}
Tue Jun 12 2018, 01:40 PM Z