| Paket | flash.text.engine |
| Klass | public final class GroupElement |
| Arv | GroupElement  ContentElement Object |
| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
content-egenskapen i ett TextBlock-objekt. Ett GroupElement-objekt kan också dela formateringen i ett annat GroupElement-objekt.
När ett GroupElement innehåller ett annat GroupElement behåller det inre GroupElement sin egen formatering (ElementFormat-inställningar). Det ärver inte formateringen från det yttre GroupElement.
I ett GroupElement har de flesta formategenskaper ingen påverkan. Av detta skäl är det godkänt att skapa en textrad för ett GroupElement-objekt som har en elementFormat-parameter som är null. En del formategenskaper som kerning och ligature påverkar formateringen där överlappande områden uppstår mellan medlemmar i en grupp. Om gruppen har ett null-format avgör formatet på det föregående elementet formateringen där överlappande områden uppstår mellan medlemmar i en grupp.
Relaterade API-element
Publika egenskaper
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaper| Egenskap | Definieras med | ||
|---|---|---|---|
 | constructor : Object
En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans. | Object | |
| elementCount : int [skrivskyddad]
Antalet element i gruppen. | GroupElement | ||
| elementFormat : ElementFormat
ElementFormat-objektet som används för elementet. | ContentElement | |
| eventMirror : EventDispatcher
EventDispatcher-objektet som tar emot kopior av varje händelse som skickas till giltiga textrader baserat på detta innehållselement. | ContentElement | |
| groupElement : GroupElement [skrivskyddad]
Det GroupElement som innehåller det här elementet, eller null om elementet inte ingår i någon grupp. | ContentElement | |
| rawText : String [skrivskyddad]
En kopia av texten i elementet, inklusive eventuella U+FDEF-tecken. | ContentElement | |
| text : String [skrivskyddad]
En kopia av texten i elementet, förutom eventuella U+FDEF-tecken, som representerar grafiska element i strängen. | ContentElement | |
| textBlock : flash.text.engine:TextBlock [skrivskyddad]
TextBlock som det här elementet tillhör. | ContentElement | |
| textBlockBeginIndex : int [skrivskyddad]
Indexplatsen i textblocket för det första tecknet i detta element. | ContentElement | |
| textRotation : String
Den rotation som ska användas på elementet som en enhet. | ContentElement | |
| userData : *
Medger att programmet kan koppla godtyckliga data till elementet. | ContentElement | |
Publika metoder
| Metod | Definieras med | ||
|---|---|---|---|
GroupElement(elements:Vector.<ContentElement> = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")
Skapar en ny GroupElement-instans. | GroupElement | ||
Hämtar ett element inom gruppen. | GroupElement | ||
Returnerar elementet som innehåller det tecken som anges av parametern charIndex. | GroupElement | ||
Returnerar indexet för det element som anges av parametern element. | GroupElement | ||
Ersätter elementintervallet som anges av parametrarna beginIndex och endIndex med ett nytt GroupElement som innehåller dessa element. | GroupElement | ||
|
Anger om det finns en egenskap angiven för ett objekt. | Object | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
Sammanfogar texten från elementintervallet som anges av parametrarna beginIndex och endIndex i ett element som anges av beginIndex utan att det påverkar det elementets format. | GroupElement | ||
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
replaceElements(beginIndex:int, endIndex:int, newElements:Vector.<ContentElement>):Vector.<ContentElement>
Ersätter elementintervallet som anges av parametrarna beginIndex och endIndex med innehållet i parametern newElements. | GroupElement | ||
Anger elementen i gruppen till innehållet i Vektor. | GroupElement | ||
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
Delar ett TextElement i två delar och skapar ett nytt TextElement vid den angivna positionen. | GroupElement | ||
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
|
Returnerar det angivna objektets strängbeteckning. | Object | |
Delar upp elementen i ett kapslat GroupElement som groupIndex anger i ett yttre GroupElement-objekt. | GroupElement | ||
|
Returnerar det angivna objektets primitiva värde. | Object | |
Publika konstanter
Egenskapsdetaljer
elementCount | egenskap |
Konstruktordetaljer
GroupElement | () | Konstruktor |
public function GroupElement(elements:Vector.<ContentElement> = null, elementFormat:ElementFormat = null, eventMirror:EventDispatcher = null, textRotation:String = "rotate0")| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Skapar en ny GroupElement-instans.
Parametrarelements:Vector.<ContentElement> (default = null)null.
| |
elementFormat:ElementFormat (default = null)null. Formatet gäller de överlappande områdena mellan elementen i gruppen. Elementen ärver inte formatet.
| |
eventMirror:EventDispatcher (default = null)EventDispatcher-objekt som tar emot kopior av alla händelser som skickas till textrader, som har skapats baserat på detta innehållselement. Standardvärdet är null.
| |
textRotation:String (default = "rotate0")TextRotation-konstanter för den här egenskapen. Standardvärdet är TextRotation.ROTATE_0.
|
Utlöser
ArgumentError — Angiven element innehåller null-element.
| |
ArgumentError — Angivet element innehåller ett element som inte är en känd underklass till ContentElement.
| |
ArgumentError — Angivet element innehåller element som har angetts som content för ett TextBlock.
| |
ArgumentError — Angivet element innehåller element som redan är medlemmar i en grupp eller som förekommer fler än en gång i elements.
|
Relaterade API-element
Metoddetaljer
getElementAt | () | metod |
public function getElementAt(index:int):ContentElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Hämtar ett element inom gruppen.
Parametrar
index:int — Indexvärdet för det element som ska hämtas.
|
ContentElement |
Utlöser
RangeError — Om index är utanför intervallet.
|
getElementAtCharIndex | () | metod |
public function getElementAtCharIndex(charIndex:int):ContentElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Returnerar elementet som innehåller det tecken som anges av parametern charIndex.
Parametrar
charIndex:int — Det nollbaserade indexvärdet för det tecken vars element du vill hitta. Ett värde på 0 stämmer överens med det första tecknet i gruppen, inte det första tecknet i TextBlock.
|
ContentElement — Det element som innehåller tecknet vid charIndex.
|
Utlöser
RangeError — Om charIndex inte ligger i intervallet 0 - rawText.length.
|
getElementIndex | () | metod |
public function getElementIndex(element:ContentElement):int| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Returnerar indexet för det element som anges av parametern element.
Parametrar
element:ContentElement — Elementet i gruppen vars index du vill hämta.
|
int — Indexvärdet för det element som anges av element eller -1, om elementet inte finns i gruppen.
|
groupElements | () | metod |
public function groupElements(beginIndex:int, endIndex:int):GroupElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ersätter elementintervallet som anges av parametrarna beginIndex och endIndex med ett nytt GroupElement som innehåller dessa element. Elementen från beginIndex till endIndex-1 ersätts.
Parametrar
beginIndex:int — Det nollbaserade indexvärdet för startpositionen för det område som ska grupperas.
| |
endIndex:int — Det nollbaserade indexvärdet som följer slutpositionen för det område som ska grupperas.
|
GroupElement — Den nya gruppen.
|
Utlöser
RangeError — Om angivet beginIndex eller endIndex är utanför intervallet.
|
mergeTextElements | () | metod |
public function mergeTextElements(beginIndex:int, endIndex:int):flash.text.engine:TextElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Sammanfogar texten från elementintervallet som anges av parametrarna beginIndex och endIndex i ett element som anges av beginIndex utan att det påverkar det elementets format. Texten från elementen från beginIndex till endIndex-1 sammanfogas. När texten har sammanfogats tas elementen från beginIndex+1 till endIndex-1 bort från gruppen och blir utan överordnade med värdet null för group-egenskaperna.
Parametrar
beginIndex:int — Det nollbaserade indexvärdet för startpositionen för det område som ska sammanfogas.
| |
endIndex:int — Det nollbaserade indexvärdet som följer slutpositionen för det område som ska sammanfogas.
|
flash.text.engine:TextElement — Det första textelementet i området, som nu innehåller all text i området.
|
Utlöser
RangeError — Om angivet beginIndex eller endIndex är utanför intervallet.
| |
ArgumentError — Om några av elementen i det angivna området inte är TextElement.
|
Relaterade API-element
replaceElements | () | metod |
public function replaceElements(beginIndex:int, endIndex:int, newElements:Vector.<ContentElement>):Vector.<ContentElement>| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Ersätter elementintervallet som anges av parametrarna beginIndex och endIndex med innehållet i parametern newElements. Elementen från beginIndex till endIndex-1 ersätts.
Skicka null för newElements om du vill ta bort elementen. Om du vill infoga ett element skickar du samma värde för beginIndex och endIndex. Det nya elementet infogas före det angivna indexet. Om du vill lägga till ett element skickar du elementCount för beginIndex och endIndex.
Efter åtgärden blir de ersatta elementen utan överordnade element, får värdet null för group-egenskaperna och returneras.
Parametrar
beginIndex:int — Det nollbaserade indexvärdet för ersättningsintervallets startposition.
| |
endIndex:int — Det nollbaserade indexvärdet som följer slutpositionen för ersättningsintervallet.
| |
newElements:Vector.<ContentElement> — Elementen som ska användas för att ersätta det angivna elementintervallet.
|
Vector.<ContentElement> — En Vektor som innehåller de element som ersattes.
|
Utlöser
RangeError — beginIndex eller endIndex är utanför intervallet.
| |
ArgumentError — Angiven newElements innehåller null-element.
| |
ArgumentError — Angiven newElements innehåller this-element.
| |
ArgumentError — Angiven newElements innehåller element som inte är en känd underklass till ContentElement.
| |
ArgumentError — Angiven newElements innehåller element som har angetts som content för ett TextBlock.
| |
ArgumentError — Angiven newElements innehåller element som redan är medlemmar i en grupp eller som förekommer fler än en gång i elements.
| |
ArgumentError — Om åtgärden skulle innebära kapslade rotationer i GroupElement.
|
setElements | () | metod |
public function setElements(value:Vector.<ContentElement>):void| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Anger elementen i gruppen till innehållet i Vektor.
Parametrar
value:Vector.<ContentElement> |
Utlöser
ArgumentError — Angiven value innehåller null-element.
| |
ArgumentError — Angiven value innehåller this-element.
| |
ArgumentError — Angivet value innehåller element som inte är en känd underklass till ContentElement.
| |
ArgumentError — Angivet value innehåller element som har angetts som content för ett TextBlock.
| |
ArgumentError — Angivet value innehåller element som redan är medlemmar i en grupp eller som förekommer fler än en gång i value.
| |
ArgumentError — Om åtgärden skulle innebära kapslade rotationer i GroupElement.
|
splitTextElement | () | metod |
public function splitTextElement(elementIndex:int, splitIndex:int):flash.text.engine:TextElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Delar ett TextElement i två delar och skapar ett nytt TextElement vid den angivna positionen.
Parametrar
elementIndex:int — Det nollbaserade indexvärdet för elementets position i gruppen.
| |
splitIndex:int — Det nollbaserade indexvärdet för tecknet i TextElement där uppdelningen ska ske. Det angivna tecknet blir det första tecknet i det nya TextElement.
|
flash.text.engine:TextElement — Det nya textelementet som innehåller den senare delen av det ursprungliga textelementet.
|
Utlöser
RangeError — Om angivet elementIndex eller charIndex är utanför intervallet.
| |
ArgumentError — Om elementet vid elementIndex inte är ett TextElement.
|
Relaterade API-element
ungroupElements | () | metod |
public function ungroupElements(groupIndex:int):void| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5, Flash Lite 4 |
Delar upp elementen i ett kapslat GroupElement som groupIndex anger i ett yttre GroupElement-objekt. När åtgärden har slutförts ersätter de uppdelade elementen det kapslade GroupElement, vilket blir utan överordnade och får värdet null för group-egenskapen.
Parametrar
groupIndex:int — Det nollbaserade indexvärdet för positionen för den grupp som ska delas upp.
|
Utlöser
RangeError — Om groupIndex är utanför intervallet.
| |
ArgumentError — Om elementet vid groupIndex inte är ett GroupElement.
|
Exempel Så här använder du exemplet
GroupElementExample.as
Det här exemplet skapar en röd ruta som ett GraphicElement-objekt och kombinerar det med två TextElement-objekt för att skapa ett GroupElement-objekt. Det tilldelar GroupElement-objektet till
content-egenskapen för ett TextBlock, som det skapar tre rader från.
package {
import flash.display.Sprite;
import flash.display.MovieClip;
import flash.text.engine.ContentElement;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.GraphicElement;
import flash.text.engine.GroupElement;
import flash.text.engine.TextLine;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontDescription;
public class GroupElementExample extends Sprite {
public function GroupElementExample():void {
var redBox:MovieClip = new MovieClip();
redBox.graphics.beginFill(0xCC0000, 1.0);
redBox.graphics.drawRect(0, 0, 20, 20);
redBox.graphics.endFill();
var format:ElementFormat = new ElementFormat();
var fontDescription:FontDescription = new FontDescription("Arial");
format.fontSize = 16;
format.fontDescription = fontDescription;
var str1:String = "This red box is a GraphicElement ";
var str2:String = " in the middle of two TextElements, " +
" which together make " +
"up a GroupElement in a TextBlock that is broken into three lines.";
var textElement1:TextElement = new TextElement(str1,format);
var graphicElement:GraphicElement = new GraphicElement(redBox,redBox.width,redBox.height, format);
var textElement2:TextElement = new TextElement(str2, format);
var groupVector:Vector.<ContentElement> = new Vector.<ContentElement>();
groupVector.push(textElement1, graphicElement, textElement2);
var groupElement = new GroupElement(groupVector);
var textBlock:TextBlock = new TextBlock();
textBlock.content = groupElement;
createTextLines(textBlock);
}
private function createTextLines(textBlock:TextBlock):void
{
var yPos = 20;
var line_length:Number = 450;
var textLine:TextLine = textBlock.createTextLine (null, line_length);
while (textLine)
{
addChild(textLine);
textLine.x = 15;
yPos += textLine.height+8;
textLine.y = yPos;
textLine = textBlock.createTextLine(textLine, line_length);
}
}
}
}
Tue Jun 12 2018, 01:40 PM Z