JointStyle - API-referens för Adobe ActionScript® 3 (AS3 )

Paket	flash.display
Klass	public final class JointStyle
Arv	JointStyle Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Klassen JointStyle är en uppräkning av konstanta värden som anger vilken ledstil som ska användas när linjer ritas. Dessa konstanter ska användas som värden i joints-parametern för flash.display.Graphics.lineStyle()-metoden. Metoden stöder tre typer av leder: spets, rund och avfasning, som framgår av detta exempel:

MITER, ROUND och BEVEL

Visa exemplen

Relaterade API-element

flash.display.Graphics.lineStyle()

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar det angivna objektets strängbeteckning.	Object
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object

Publika konstanter

	Konstant		Definieras med
		BEVEL : String = "bevel" [statisk] Anger avfasade fogar i parametern joints i metoden flash.display.Graphics.lineStyle().	JointStyle
		MITER : String = "miter" [statisk] Anger spetsiga fogar i parametern joints i metoden flash.display.Graphics.lineStyle().	JointStyle
		ROUND : String = "round" [statisk] Anger runda fogar i parametern joints i metoden flash.display.Graphics.lineStyle().	JointStyle

Konstantdetaljer

BEVEL

Konstant

public static const BEVEL:String = "bevel"

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger avfasade fogar i parametern joints i metoden flash.display.Graphics.lineStyle().

MITER

Konstant

public static const MITER:String = "miter"

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger spetsiga fogar i parametern joints i metoden flash.display.Graphics.lineStyle().

ROUND

Konstant

public static const ROUND:String = "round"

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9

Anger runda fogar i parametern joints i metoden flash.display.Graphics.lineStyle().

Exempel Så här använder du exemplet

JointStyleExample.as

I det exempel som följer används klass JointStyleExample för att visa resultatet av tre olika ledstilar tillämpade för tre uppsättningar förenade linjer. Detta genomförs med följande steg:

De olika linjernas egenskaper bestäms på följande sätt:
- Linjelängden sätts till 80 pixlar.
- Ramfärgen sätts till orange.
- Ramstorleken sätts till 30 pixlar.
- Markeringsfärgen sätts till grå.
- Markeringsstorleken sätts till noll pixlar.
- Alfavärdet sätts till 1, vilket gör den massiv.
- Pixelutjämningen sätts till false (linjer jämnas inte ut till hela pixlar).
- Linjeskalläget sätts till normalt, vilket skalar tjockleken.
- Kantändarna och foglängden har deklarerats men inte satts, varför standardvärdena används.
Klasskonstruktorn skapar tre uppsättningar med två anslutna linjesegment. Segmenten börjar i x = 0, y = 0 med att anropa doDrawCorner()-metoden tre gånger med tre ledstilar (spets, rund och avfasning). Vart och ett av de tre anropen till doDrawCorner() använder ledstilen och egenskaper som förtecknats tidigare för att rita två anslutna linjesegment och tillhörande linjemarkeringar. Det gör man genom att först skapa ett nytt Shape-objekt child och sedan använda Graphics-klassens metoder för att bestämma linjestilarna och rita linjerna och markeringarna. Varje instans av child läggs till i visningslistan och ritas omedelbart på scenen.
De anslutna linjesegmenten ritas sedan om med refreshLayout()-metoden vid y = 80 pixlar med början vid x = 80 pixlar, och med ett mellanrum på 25 pixlar mellan linjesegmenten.

package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.JointStyle;
    import flash.display.LineScaleMode;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class JointStyleExample extends Sprite {
        private var size:uint                  = 80;
        private var borderColor:uint           = 0xFFCC00;
        private var borderSize:uint            = 30;
        private var highlightColor:uint        = 0x666666;
        private var highlightSize:uint         = 0;
        private var gutter:uint                = 25;
        private var borderAlpha:uint           = 1;
        private var borderPixelHinting:Boolean = false;
        private var borderScaleMode:String     = LineScaleMode.NORMAL;
        private var borderCaps:String;
        private var borderMiterLimit:uint;

        public function JointStyleExample() {
            doDrawCorner(JointStyle.MITER);
            doDrawCorner(JointStyle.ROUND);
            doDrawCorner(JointStyle.BEVEL);
            refreshLayout();
        }

        private function doDrawCorner(jointStyle:String):void {
            var halfSize:uint = Math.round(size / 2);
            var child:Shape = new Shape();
            child.graphics.lineStyle(borderSize,
                                     borderColor,
                                     borderAlpha,
                                     borderPixelHinting,
                                     borderScaleMode,
                                     borderCaps,
                                     jointStyle,
                                     borderMiterLimit);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(size, 0);
            child.graphics.lineTo(halfSize, size);
            child.graphics.endFill();

            child.graphics.moveTo(0, 0);
            child.graphics.lineStyle(highlightSize, highlightColor);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(size, 0);
            child.graphics.lineTo(halfSize, size);

            addChild(child);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = size;
            lastChild.y = size;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = size;
                lastChild = child;
            }
        }
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

JointStyle - AS3

Klasser x

BEVEL

MITER

ROUND