MovieClip  - AS3

Spécifie le numéro de l’image où réside la tête de lecture dans le scénario de l’occurrence de MovieClip. Si le clip contient plusieurs séquences, cette valeur correspond au numéro de l’image dans la séquence en cours.

mc1.gotoAndStop(mc1.currentFrame + 5);

Etiquette de l’image actuelle dans le scénario de l’occurrence MovieClip. Si l’image actuelle ne possède aucune étiquette, currentLabel est null.

Etiquette où réside actuellement la tête de lecture dans le scénario de l’occurrence de MovieClip. Si l’image suivante ne dispose pas d’étiquette, currentLabel est défini en fonction du nom de la première image ayant inclus une étiquette. Si l’image actuelle et les images précédentes n’incluent pas d’étiquette, currentLabel renvoie null.

trace(mc1.currentLabel);

Renvoie un tableau des objets FrameLabel extraits de la séquence en cours. Si l’occurrence de MovieClip n’utilise pas de séquence, le tableau comprend toutes les étiquettes d’image extraites de la totalité de l’occurrence de MovieClip.

Eléments de l’API associés

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

Séquence où réside actuellement la tête de lecture dans le scénario de l’occurrence de MovieClip.

Eléments de l’API associés

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Valeur booléenne indiquant si un clip est activé. La valeur par défaut de enabled est true. Si enabled est défini sur false, les images Dessus, Abaissé et Haut du clip sont désactivées. Le clip continue à recevoir des événements (par exemple, mouseDown, mouseUp, keyDown et keyUp).

La propriété enabled gère uniquement les propriétés spécifiques aux boutons d’un clip. Vous pouvez modifier la propriété enabled à tout moment ; le clip modifié est immédiatement activé ou désactivé. Si la propriété enabled est définie sur false, l’objet n’est pas inclus dans l’ordre de tabulation automatique.

mc1.enabled = false;

Nombre d’images à charger à partir d’un fichier SWF en diffusion continue. Vous pouvez utiliser la propriété framesLoaded pour déterminer si le contenu d’une image spécifique, ainsi que l’ensemble des images chargées précédemment sont disponibles de façon locale dans le navigateur. Vous pouvez également l’utiliser pour superviser le téléchargement de fichiers SWF volumineux. Par exemple, si désiré, affichez un message aux utilisateurs leur indiquant que le chargement du fichier SWF ne commencera pas tant que le chargement d’une image spécifiée dans le fichier SWF ne sera pas terminé.

Si le clip contient plusieurs séquences, la propriété framesLoaded renvoie le nombre d’images chargées pour toutes les séquences.

Eléments de l’API associés

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Valeur booléenne indiquant si un clip est en cours de lecture.

Tableau des objets Scene, chacun d’eux indiquant le nom, le nombre d’images et les étiquettes d’image d’une séquence dans l’occurrence de MovieClip.

Eléments de l’API associés

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

Nombre total d’images dans l’occurrence de MovieClip.

Si le clip contient plusieurs images, la propriété totalFrames renvoie le nombre total d’images dans all les séquences.

 trace(mc1.totalFrames);

Indique si d’autres objets d’affichage de type SimpleButton ou MovieClip peuvent recevoir des événements de relâchement de souris ou d’autres types d’événements de relâchement. La propriété trackAsMenu permet de créer des menus. Vous pouvez définir la propriété trackAsMenu sur n’importe quel objet SimpleButton ou MovieClip. La valeur par défaut de la propriété trackAsMenu est false.

Vous pouvez modifier la propriété trackAsMenu à tout moment ; le clip modifié accepte immédiatement le nouveau comportement.

 mc1.trackAsMenu = true;

Crée une occurrence de MovieClip. Après avoir créé l’objet MovieClip, appelle la méthode addChild() ou addChildAt() d’un objet conteneur d’affichage qui est sur la scène.

Commence la lecture du fichier SWF sur l’image spécifiée. Cette opération se produit lorsque l’exécution de toutes les autres actions de l’image est terminée. Pour spécifier une séquence et une image, affectez une valeur au paramètre scene.

Paramètres

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Place la tête de lecture au niveau de l’image spécifiée du clip et l’arrête à cet endroit. Cette opération se produit lorsque l’exécution de toutes les autres actions de l’image est terminée. Pour spécifier une séquence en plus d’une image, utilisez un paramètre scene.

Paramètres

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Place la tête de lecture sur l’image suivante et l’arrête. Cette opération se produit lorsque l’exécution de toutes les autres actions de l’image est terminée.

Eléments de l’API associés

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Place la tête de lecture sur la séquence suivante de l’occurrence de MovieClip. Cette opération se produit lorsque l’exécution de toutes les autres actions de l’image est terminée.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Déplace la tête de lecture dans le scénario du clip.

Eléments de l’API associés

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Place la tête de lecture sur l’image précédente et l’arrête. Cette opération se produit lorsque l’exécution de toutes les autres actions de l’image est terminée.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Place la tête de lecture sur la séquence précédente de l’occurrence de MovieClip. Cette opération se produit lorsque l’exécution de toutes les autres actions de l’image est terminée.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Arrête la tête de lecture dans le clip.

1. La fonction constructeur définit un champ de texte, qui permet d’afficher les valeurs des propriétés de l’objet MovieClipExample (qui étend MovieClip).
2. La valeur renvoyée par la méthode getPropertiesString() est utilisée en tant que texte pour le champ de texte outputText. La méthode getPropertiesString() renvoie une chaîne qui est remplie avec des valeurs provenant des propriétés suivantes du clip : currentFrame, currentLabel, currentScene, framesLoaded, totalFrames et trackAsMenu.
3. Deux des lignes de code de la fonction constructeur règlent les propriétés width et height du champ de texte outputText.
4. La dernière ligne de la fonction constructeur ajoute le champ de texte outputText à la liste d’affichage.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}