Sprite  - AS3

Spécifie le mode de bouton du sprite. Si la valeur true est renvoyée, ce sprite se comporte comme un bouton, ce qui signifie qu’il déclenche l’affichage du curseur en forme de main lorsque le pointeur le survole et qu’il peut recevoir un événement click si l’utilisateur appuie sur la touche Entrée ou la barre d’espacement lorsque le sprite dispose du focus. Pour remplacer le curseur en forme de main par le pointeur standard, réglez la propriété useHandCursor sur false.

Bien qu’il soit préférable d’utiliser la classe SimpleButton pour créer des boutons, la propriété buttonMode permet d’affecter à un sprite une fonctionnalité similaire à celle d’un bouton. Pour inclure un sprite dans l’ordre de tabulation, réglez la propriété tabEnabled (héritée de la classe InteractiveObject et réglée sur false par défaut) sur true. Demandez-vous en outre si les enfants de votre sprite doivent prendre en charge la saisie utilisateur. La plupart des boutons n’activent pas l’interactivité avec la saisie utilisateur pour leurs objets enfant, en raison de son impact sur le flux d’événements. Pour désactiver l’interactivité avec la saisie utilisateur pour tous les objets enfant, définissez la propriété mouseChildren (héritée de la classe DisplayObjectContainer) sur false.

Si vous utilisez la propriété buttonMode avec la classe MovieClip (une sous-classe de la classe Sprite), la fonctionnalité de votre bouton risque d’être enrichie. Si vous incluez les étiquettes d’images _up, _over et _down, Flash Player gère les changements d’état automatiques (fonctionnalité similaire à celle intégrée aux versions antérieures d’ActionScript pour les clips utilisés en tant que boutons). Ces changements d’état automatiques ne sont pas disponibles pour les sprites, qui ne disposent pas de scénario et donc, pas d’images à étiqueter.

Eléments de l’API associés

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Spécifie l’objet d’affichage sur lequel le sprite est glissé ou sur lequel il a été déposé.

Eléments de l’API associés

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Spécifie l’objet Graphics appartenant au sprite qui prend en charge les commandes de dessin vectoriel.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Désigne un autre sprite qui fera office de zone active d’un sprite. Si la propriété hitArea n’existe pas, ou si sa valeur est null ou undefined, le sprite fait office de zone active. La valeur de la propriété hitArea peut être une référence à un objet Sprite.

Vous pouvez modifier la propriété hitArea à tout moment ; le sprite modifié accepte immédiatement le nouveau comportement de la zone active. Il n’est pas nécessaire que le sprite désigné comme zone active soit visible ; bien qu’elle ne soit pas visible, sa forme graphique est encore détectée comme zone active.

Remarque : vous devez définir sur false la propriété mouseEnabled du sprite désigné comme zone active. Dans le cas contraire, votre bouton sprite risque de ne pas fonctionner, car c’est le sprite désigné comme zone active qui reçoit les événements de saisie utilisateur et non le bouton sprite.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Contrôle le son à l’intérieur du sprite.

Remarque : cette propriété n’affecte pas le contenu HTML d’un objet HTMLControl (dans Adobe AIR).

Eléments de l’API associés

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Valeur booléenne indiquant si le curseur en forme de main apparaît lorsque le pointeur survole un sprite dont la propriété buttonMode est définie sur true. La valeur par défaut de la propriété useHandCursor est true. Si la propriété useHandCursor est définie sur true, le curseur en forme de main utilisé pour les boutons s’affiche lorsque le pointeur survole un sprite. Si la propriété useHandCursor est définie sur false, le pointeur flèche est utilisé.

Vous pouvez modifier la propriété useHandCursor à tout moment ; le sprite modifié accepte immédiatement la nouvelle apparence du curseur.

Remarque : dans Flex ou Flash Builder, si votre sprite possède des sprites enfants, vous pouvez définir la propriété mouseChildren sur false. Par exemple, si vous souhaitez qu’un curseur en forme de main apparaisse sur une commande Flex <mx:Label>, réglez les propriétés useHandCursor et buttonMode sur true, et la propriété mouseChildren sur false.

Eléments de l’API associés

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Crée une occurrence de Sprite. Une fois l’occurrence de Sprite créée, appelez la méthode DisplayObjectContainer.addChild() ou DisplayObjectContainer.addChildAt() pour ajouter le sprite à une occurrence de l’objet DisplayObjectContainer parent.

Permet à l’utilisateur de faire glisser le sprite spécifié. Il reste possible de faire glisser le sprite jusqu’à l’arrêt explicite de cette action par un appel à la méthode Sprite.stopDrag() ou lorsqu’un autre sprite est rendu déplaçable. Vous ne pouvez déplacer qu’un seul sprite à la fois.

Les objets d’affichage tridimensionnels suivent le pointeur et la méthode Sprite.startDrag() déplace l’objet dans le plan tridimensionnel défini par l’objet d’affichage. Si l’objet d’affichage est un objet bidimensionnel et l’enfant d’un objet tridimensionnel, l’objet bidimensionnel se déplace dans le plan tridimensionnel défini par l’objet parent tridimensionnel.

Paramètres

Eléments de l’API associés

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Permet à l’utilisateur de faire glisser le sprite spécifié sur un périphérique tactile. Il est possible de faire glisser le sprite jusqu’à l’arrêt explicite de cette action par un appel à la méthode Sprite.stopTouchDrag() ou lorsqu’un autre sprite est rendu déplaçable. Vous ne pouvez déplacer qu’un seul sprite à la fois.

Les objets d’affichage tridimensionnels suivent le pointeur et la méthode Sprite.startTouchDrag() déplace l’objet dans le plan tridimensionnel défini par l’objet d’affichage. Si l’objet d’affichage est un objet bidimensionnel et l’enfant d’un objet tridimensionnel, l’objet bidimensionnel se déplace dans le plan tridimensionnel défini par l’objet parent tridimensionnel.

Paramètres

Eléments de l’API associés

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Met fin à la méthode startDrag(). Un sprite qu’il est possible de déplacer grâce à la méthode startDrag() reste déplaçable jusqu’à ce qu’une autre méthode stopDrag() soit ajoutée, ou jusqu’à ce qu’un autre sprite devienne déplaçable. Vous ne pouvez déplacer qu’un seul sprite à la fois.

Eléments de l’API associés

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Met fin à la méthode startTouchDrag() en vue d’utiliser des périphériques tactiles. Un sprite qu’il est possible de déplacer grâce à la méthode startTouchDrag() reste déplaçable jusqu’à ce qu’une autre méthode stopTouchDrag() soit ajoutée, ou jusqu’à ce qu’un autre sprite devienne déplaçable. Vous ne pouvez déplacer qu’un seul sprite à la fois.

Paramètres

Eléments de l’API associés

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. Déclarez la propriété size (100 x 100 pixels) et la couleur de fond (orange) pour une exploitation ultérieure lors du dessin du carré.
2. Le constructeur crée ensuite un nouvel objet Sprite child et l’utilise pour ajouter deux écouteurs d’événement et leurs méthodes associées : mouseDownHandler() et mouseUpHandler().
3. L’objet Sprite child est ensuite transmis à la méthode draw(), qui dessine le carré orange.
4. L’enfant est ensuite placé dans la liste d’affichage grâce à un appel à la méthode addChild().
5. Les écouteurs d’événements fonctionnent de la façon suivante :
   • mouseDownHandler() : lorsque l’utilisateur clique sur l’objet Sprite, cette méthode ajoute un écouteur d’événements mouseMove, la méthode mouseMoveHandler(), qui traite les mouvements de la souris. La méthode startDrag() est ensuite appelée et permet de faire glisser l’objet Sprite.
   • mouseUpHandler() : lorsque le bouton de la souris est relâché, l’écouteur d’événements mouseMove est supprimé et la méthode stopDrag() est appelée, ce qui fige le carré orange.
   • mouseMoveHandler : tant que le bouton gauche de la souris reste enfoncé, cette méthode demande au lecteur de redessiner en continu le carré orange.

Remarque : chacune des méthodes de l’écouteur d’événements déclare une variable sprite locale, qui se voit affecter la propriété target de l’événement.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}