UIComponent  - AS3 Flash

Récupère ou définit une valeur indiquant si le composant peut accepter une interaction de l’utilisateur. La valeur true indique que le composant peut accepter une interaction de l’utilisateur ; la valeur false indique qu’il ne le peut pas.

Si vous définissez la propriété enabled sur false, la couleur du conteneur est grisée et la saisie de l’utilisateur est bloquée (sauf pour les composants Label et ProgressBar).

La valeur par défaut est true.

Récupère ou définit une valeur booléenne indiquant si le composant peut recevoir le focus après un clic de l’utilisateur sur son entrée. La valeur true indique qu'il peut recevoir le focus ; la valeur false indique qu'il ne le peut pas.

Si la valeur de cette propriété est false, le focus est transféré au premier parent dont la propriété mouseFocusEnabled est définie sur true.

La valeur par défaut est true.

Eléments de l’API associés

Récupère ou définit le FocusManager qui contrôle le focus pour ce composant et ses homologues. Chaque composant contextuel conserve sa propre boucle de focus et sa propre occurrence de FocusManager. Utilisez cette propriété pour accéder au FocusManager qui convient à ce composant.

Récupère ou définit la hauteur du composant, en pixels.

La définition de cette propriété entraîne la distribution d’un événement resize. Pour plus d'informations sur le moment où cet événement est distribué, reportez-vous à l'événement resize.

Si la propriété scaleY du composant n’a pas la valeur 1.0, la hauteur du composant qui est obtenue à partir de ses coordonnées internes ne correspondra pas à la valeur height des coordonnées du parent. Par exemple, si un composant présente une hauteur de 100 pixels et que sa propriété scaleY a pour valeur 2, le parent aura une valeur de 100 pixels, mais il stockera en interne une valeur indiquant que sa hauteur est de 50 pixels.

Récupère ou définit une valeur indiquant si le composant peut recevoir le focus après un clic de l’utilisateur sur son entrée. La valeur true indique qu'il peut recevoir le focus ; la valeur false indique qu'il ne le peut pas.

Si la valeur de cette propriété est false, le focus est transféré au premier parent dont la propriété mouseFocusEnabled est définie sur true.

La valeur par défaut est true.

Eléments de l’API associés

Multiplie la largeur actuelle du composant par un facteur de redimensionnement.

Eléments de l’API associés

Multiplie la hauteur actuelle du composant par un facteur de redimensionnement.

Eléments de l’API associés

Récupère ou définit une valeur indiquant si l’occurrence du composant actif est visible. La valeur true indique que le composant actif est visible ; la valeur false indique qu’il n’est l’est pas.

Lorsque cette propriété est définie sur true, l’objet diffuse un événement show. Lorsque cette propriété est définie sur false, l’objet diffuse un événement hide. Dans les deux cas, les enfants de l’objet ne génèrent pas d’événement show ou hide, sauf si l’objet écrit de façon explicite une telle implémentation.

La valeur par défaut est true.

Eléments de l’API associés

Récupère ou définit la largeur du composant, en pixels.

La définition de cette propriété entraîne la distribution d’un événement resize. Pour plus d'informations sur le moment où cet événement est distribué, reportez-vous à l'événement resize.

Si la propriété scaleX du composant n’a pas la valeur 1.0, la largeur du composant qui est obtenue à partir de ses coordonnées internes ne correspondra pas à la valeur width des coordonnées du parent. Par exemple, si un composant présente une largeur de 100 pixels et que sa propriété scaleX a pour valeur 2, le parent aura une valeur de 100 pixels, mais il stockera en interne une valeur indiquant que sa largeur est de 50 pixels.

Eléments de l’API associés

Récupère ou définit la coordonnée x représentant la position du composant le long de l’axe x au sein de son conteneur parent. Cette valeur est exprimée en pixels et est calculée en partant de la gauche.

La définition de cette propriété entraîne la distribution d’un événement ComponentEvent.MOVE.

La valeur par défaut est 0.

Eléments de l’API associés

Récupère ou définit la coordonnée y représentant la position du composant le long de l’axe y au sein de son conteneur parent. Cette valeur est exprimée en pixels et est calculée en partant du haut.

La définition de cette propriété entraîne la diffusion d’un événement move.

Eléments de l’API associés

Crée une nouvelle occurrence du composant UIComponent.

Définit une propriété de style depuis cette occurrence de composant.

La méthode getStyle() ne renvoie pas nécessairement la valeur undefined.

Paramètres

Eléments de l’API associés

Affiche ou masque l’indicateur de focus dans ce composant.

La classe UIComponent implémente cette méthode en créant et en positionnant une occurrence de la classe spécifiée par le style focusSkin.

Paramètres

Déclenche une opération de dessin immédiate, sans tout annuler comme le fait invalidateNow.

Récupère l’objet qui détient actuellement le focus.

Notez que cette méthode ne renvoie pas nécessairement le composant qui a le focus. Elle peut renvoyer le sous-composant interne du composant qui détient le focus. Pour obtenir le composant qui a le focus, utilisez la propriété focusManager.focus.

Extrait une propriété de style définie dans la chaîne de recherche de style du composant.

Le type renvoyé par cette méthode varie en fonction de la propriété de style que cette même méthode renvoie. Il peut s’agir de l’un des types suivants : valeur booléenne ; alphanumérique ; numérique ; int ; objet uint, dans le cas d’une couleur RVB ; classe, dans le cas d’une enveloppe ; ou tout type d’objet.

Si vous appelez cette méthode dans le but d’extraire une propriété de style particulière, elle sera d’un type connu et vous pourrez la stocker dans une variable du même type. Il n’est pas nécessaire de recourir à une attribution de type. Une simple instruction d’affectation analogue à celle-ci suffit :

var backgroundColor:uint = getStyle("backgroundColor");

Si la propriété style n’est pas définie dans la chaîne de recherche de style, cette méthode renvoie la valeur undefined. Notez bien que undefined est une valeur spéciale qui ne correspond pas à false, "", NaN, 0 ou null. Aucune valeur de style valide n’est jamais undefined. Vous pouvez utiliser la méthode statique StyleManager.isValidStyleValue() pour vérifier si une valeur a été définie.

Paramètres

Eléments de l’API associés

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Récupère la texture de style par défaut du composant actif. La texture de style contient le type adapté au composant, qui dépend du style utilisé par ce dernier. Par exemple, le style disabledTextFormat contient la valeur null ou un objet TextFormat. Vous pouvez utiliser ces styles et appeler setStyle() pour le composant actif. Le code suivant ignore le style par défaut disabledTextFormat dans le composant spécifié :

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Eléments de l’API associés

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Renvoie le style spécifié pour un composant, en tenant compte de tous les styles définis au niveau global, au niveau du composant et au niveau de l’occurrence.

Par exemple, si le style d’un composant est défini au niveau global sur myStyle et que vous appelez getStyle("myStyle") sur une occurrence qui n’a pas de paramètre d’occurrence, null est renvoyé. Si vous appelez getStyleValue("myStyle"), "myStyle" est renvoyé, car il est actif au niveau global.

Paramètres

Marque une propriété comme non valide, puis redessine le composant dans la prochaine image, sauf spécification contraire.

Paramètres

Fusionne les styles de plusieurs classes en un seul objet. Si un style est défini dans plusieurs objets, la première occurrence trouvée est utilisée.

Paramètres

Déplace le composant à la position spécifiée dans son parent. Cela revient à modifier l’emplacement du composant en définissant ses propriétés x et y. L’appel à cette méthode entraîne la distribution de l’événement ComponentEvent.MOVE.

Pour annuler la méthode updateDisplayList() dans un composant personnalisé, appelez la méthode move() au lieu de définir les propriétés x et y. En effet, un appel à la méthode move() entraîne la distribution d’un objet d’événement move immédiatement après la fin de l’opération de mouvement. En revanche, lorsque vous modifiez l’emplacement d’un composant en définissant les propriétés x et y, l’objet d’événement est distribué lors de la prochaine actualisation de l’écran.

Paramètres

Eléments de l’API associés

Définit le focus sur ce composant. Le composant peut à son tour transmettre le focus à un sous-composant.

Remarque : seuls les composants TextInput et TextArea affichent un indicateur de focus lorsque cette méthode définit le focus. Tous les composants affichent un indicateur de focus lorsque l’utilisateur les atteint via la touche de tabulation.

Définit le composant en fonction de la largeur et de la hauteur spécifiées.

Paramètres

Définit une propriété de style pour cette occurrence de composant. Ce style peut remplacer un style défini globalement.

L’appel à cette méthode peut entraîner une baisse des performances. Utilisez-la uniquement lorsque cela est nécessaire.

Paramètres

Eléments de l’API associés

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Valide et met à jour les propriétés et la mise en forme de cet objet, puis le redessine si nécessaire.

Les propriétés qui nécessitent de nombreux calculs ne sont généralement pas traitées avant la fin de l’exécution du script. Cela s’explique par le fait que la définition d’une propriété peut nécessiter le traitement d’autres propriétés. Par exemple, la définition de la propriété width peut également nécessiter un nouveau calcul de la largeur des enfants ou des parents de l’objet. De plus, si le script recalcule plusieurs fois la largeur de l’objet, ces propriétés interdépendantes peuvent également nécessiter un nouveau calcul. Utilisez cette méthode pour neutraliser manuellement ce comportement.

Distribué après que la visibilité du composant soit passée de visible à invisible.

Les propriétés de cet événement sont les suivantes :

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Eléments de l’API associés

Distribué à la suite du déplacement du composant.

Les propriétés de cet événement sont les suivantes :

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Distribué à la suite du redimensionnement du composant.

Les propriétés de cet événement sont les suivantes :

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Distribué après que la visibilité du composant soit passée de invisible à visible.

Les propriétés de cet événement sont les suivantes :

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Eléments de l’API associés

Numéro de version des composants.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);