Label  - AS3 Flash

Lit ou définit une chaîne indiquant la manière dont une étiquette est dimensionnée et alignée pour s’adapter à la valeur de sa propriété text. Les valeurs suivantes sont prises en charge :

• TextFieldAutoSize.NONE : L’étiquette n’est pas redimensionnée ni alignée pour contenir le texte.
• TextFieldAutoSize.LEFT : Le bas et le côté droit de l’étiquette sont redimensionnés pour contenir le texte. Le haut et le côté gauche ne sont pas redimensionnés.
• TextFieldAutoSize.CENTER : Les côtés gauche et droit de l’étiquette sont redimensionnés pour contenir le texte. Le centre horizontal de l’étiquette reste ancré à sa position d’origine.
• TextFieldAutoSize.RIGHT : Le bas et le côté gauche de l’étiquette sont redimensionnés pour contenir le texte. Le haut et le côté droit ne sont pas redimensionnés.

La valeur par défaut est TextFieldAutoSize.NONE.

Eléments de l’API associés

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Récupère ou définit une valeur qui indique si des espaces blancs supplémentaires, tels que des espaces et des sauts de ligne, doivent être retirés d’un composant Label qui contient du texte HTML. La valeur true indique que l’espace blanc doit être supprimé, tandis que false indique qu’il doit être conservé.

La propriété condenseWhite n’affecte que le texte défini avec la propriété htmlText et non pas la propriété text. Lorsque vous définissez du texte avec la propriété text, la propriété condenseWhite est ignorée.

Si vous définissez la propriété condenseWhite sur true, vous devez utiliser les commandes HTML classiques, telles que <br> et <p>, pour placer des sauts de ligne dans le champ de texte.

La valeur par défaut est false.

Eléments de l’API associés

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Récupère ou définit la hauteur du composant, en pixels.

La définition de cette propriété entraîne la distribution d’un événement resize. Pour plus d'informations sur le moment où cet événement est distribué, reportez-vous à l'événement resize.

Si la propriété scaleY du composant n’a pas la valeur 1.0, la hauteur du composant qui est obtenue à partir de ses coordonnées internes ne correspondra pas à la valeur height des coordonnées du parent. Par exemple, si un composant présente une hauteur de 100 pixels et que sa propriété scaleY a pour valeur 2, le parent aura une valeur de 100 pixels, mais il stockera en interne une valeur indiquant que sa hauteur est de 50 pixels.

Eléments de l’API associés

Récupère ou définit le texte que le composant Label doit afficher, y compris le balisage HTML qui exprime les styles de ce texte. Vous pouvez spécifier du texte HTML dans cette propriété, vous pouvez utiliser le sous-ensemble de balises HTML pris en charge par l’objet TextField.

Si la valeur par défaut de la propriété text est modifiée dans l’inspecteur des propriétés, la nouvelle valeur est prioritaire sur toute valeur du champ de propriété htmlText dans l’inspecteur des propriétés. Pour utiliser la propriété htmlText dans l’inspecteur des propriétés, le champ de la propriété text doit contenir la valeur Label, comme illustré dans la figure. Lors du codage avec ActionScript, il est inutile de définir la valeur de la propriété text ; la valeur par défaut est Label.

La valeur par défaut est "".

Eléments de l’API associés

Lit ou définit une valeur qui indique si le texte peut être sélectionné. La valeur true indique qu’il peut être sélectionné, tandis que false indique le contraire.

Le texte sélectionnable peut être copié à partir du composant Label par l’utilisateur.

La valeur par défaut est false.

Lit ou définit le texte brut qui doit être affiché par le composant Label.

Tenez compte du fait que les caractères qui représentent le balisage HTML n’ont pas de signification spéciale dans la chaîne et s’affichent tels qu’ils ont été entrés.

Pour afficher un texte mis en forme à l’aide de balises HTML, utilisez la propriété htmlText. Si vous définissez la propriété htmlText, le code HTML remplace le texte défini à l’aide de cette propriété, et la propriété text renvoie une version en texte brut du texte HTML, dépouillée de toutes ses balises.

Si vous modifiez la valeur par défaut de la propriété text dans l’inspecteur des propriétés, cette dernière devient prioritaire par rapport à la propriété htmlText de l’inspecteur des propriétés.

La valeur par défaut est "Label".

Eléments de l’API associés

Une référence au champ de texte interne du composant Label.

Récupère ou définit la largeur du composant, en pixels.

La définition de cette propriété entraîne la distribution d’un événement resize. Pour plus d'informations sur le moment où cet événement est distribué, reportez-vous à l'événement resize.

Si la propriété scaleX du composant n’a pas la valeur 1.0, la largeur du composant qui est obtenue à partir de ses coordonnées internes ne correspondra pas à la valeur width des coordonnées du parent. Par exemple, si un composant présente une largeur de 100 pixels et que sa propriété scaleX a pour valeur 2, le parent aura une valeur de 100 pixels, mais il stockera en interne une valeur indiquant que sa largeur est de 50 pixels.

Eléments de l’API associés

Lit ou définit une valeur qui indique si le champ de texte prend en charge le retour à la ligne. La valeur true indique que c’est possible, tandis que false indique le contraire.

La valeur par défaut est false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Crée une nouvelle occurrence du composant Label.

Récupère la texture de style par défaut du composant actif. La texture de style contient le type adapté au composant, qui dépend du style utilisé par ce dernier. Par exemple, le style disabledTextFormat contient la valeur null ou un objet TextFormat. Vous pouvez utiliser ces styles et appeler setStyle() pour le composant actif. Le code suivant ignore le style par défaut disabledTextFormat dans le composant spécifié :

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Eléments de l’API associés

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Distribué en cas de modification de la largeur ou de la hauteur du composant.

Remarque : cet événement ne se produit pas si vous utilisez du code ActionScript pour modifier le texte de l’étiquette.

Les propriétés de cet événement sont les suivantes :

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Ajoutez les composants Label et Button dans votre bibliothèque.
2. Enregistrez ce code sous le nom LabelExample.as dans le même répertoire que votre fichier FLA.
3. Dans le fichier FLA, définissez DocumentClass sur LabelExample.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}