AccessibilityImplementation  - AS3

Indique un code d’erreur. Les erreurs sont signalées hors bande, plutôt que dans les valeurs renvoyées. Pour indiquer une erreur, définissez la propriété errno sur l’un des codes d’erreur documentés dans l’annexe Constantes AccessibilityImplementation. La valeur renvoyée est alors ignorée. La propriété errno de la classe AccessibilityImplementation est toujours effacée (définie sur zéro) par le lecteur avant tout appel de la méthode AccessibilityImplementation.

Eléments de l’API associés

S’utilise pour créer un stub d’accessibilité de composant. Si un composant est publié sans une implémentation d’accessibilité ActionScript, Adobe vous recommande d’ajouter un stub d’accessibilité de composant. Pour des raisons d’accessibilité, ce stub entraîne le traitement par Flash Player du composant comme un simple graphique plutôt que l’exposition de la structure interne des boutons, des champs de texte, etc., dans le composant.

Pour créer un stub d’accessibilité de composant, créez une sous-classe de la classe AccImpl en remplaçant le stub de propriété par la valeur true.

Eléments de l’API associés

Constructeur statique. N’instanciez pas directement la classe AccessibilityImplementation en appelant son constructeur. Créez plutôt de nouvelles implémentations d’accessibilité par l’extension de la classe mx.accessibility.AccImpl pour chaque nouveau composant.

Eléments de l’API associés

Une méthode IAccessible qui exécute l’action par défaut associée au composant représenté par cette classe AccessibilityImplementation ou l’un de ses éléments enfant.

Implémentez cette méthode uniquement si la classe AccessibilityImplementation représente un élément d’interface utilisateur avec une action par défaut dans le modèle MSAA.

Si vous implémentez accDoDefaultAction() uniquement pour la classe AccessibilityImplementation ou uniquement pour ses éléments enfant, vous devrez dans certains cas indiquer qu’aucune action par défaut du paramètre childID n’a été transmise. Pour ce faire, définissez la propriété errno sur E_MEMBERNOTFOUND.

Paramètres

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

La méthode MSAA permettant de renvoyer un objet DisplayObject ou Rectangle spécifiant le cadre de sélection d’un élément enfant dans la classeAccessibilityImplementation.

Cette méthode n’est jamais appelée avec un childID dont la valeur est zéro. Si la classe AccessibilityImplementation ne contiendra jamais d’éléments enfant, vous ne devez pas implémenter cette méthode. Si la classe AccessibilityImplementation est susceptible de contenir des éléments enfant, cette méthode est obligatoire.

Vous pouvez généralement satisfaire aux exigences de cette méthode en renvoyant un objet représentant l’élément enfant lui-même. Cela est valable tant que l’élément enfant est un objet DisplayObject. Dans ce cas, il suffit de renvoyer l’objet DisplayObject qui correspond au nom de l’occurrence associée à l’objet visuel concerné dans la liste d’affichage.

Si un élément enfant ne remplit pas les conditions d’utilisation de la technique décrite ci-dessus, vous pouvez effectuer vous-même le calcul du cadre de sélection et renvoyer un Rectangle avec les propriétés suivantes : x, y, width et height. Les membres x et y spécifient le coin supérieur gauche du cadre de sélection, tandis que les membres width et heigth spécifient sa taille. La valeur des quatre membres doit être en unités de pixels de l’objet Stage, par rapport à l’origine du composant représenté par la classe AccessibilityImplementation. Les propriétés x et y peuvent posséder des valeurs négatives, étant donné que l’origine d’un objet DisplayObject n’est pas nécessairement dans le coin supérieur gauche.

Si l’élément enfant spécifié par childID n’est pas visible (dans le cas où, par exemple, get_accState pour cet enfant renvoie une valeur incluant STATE_SYSTEM_INVISIBLE), vous pouvez renvoyer null à partir de accLocation. Vous pouvez également renvoyer un objet Rectangle représentant les coordonnées de l’emplacement où l’élément enfant s’affiche s’il est visible.

Paramètres

Informations complémentaires

Eléments de l’API associés

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

La méthode IAccessible permettant de modifier la sélection dans le composant représenté par la classe AccessibilityImplementation.

La valeur du paramètre childID est toujours différente de zéro. Cette méthode s’applique toujours à un élément enfant plutôt qu’à l’ensemble du composant ; Flash Player gère la sélection de l’ensemble du composant lui-même.

Le paramètre selFlag est un champ de bits composé d’une ou de plusieurs constantes d’indicateur de sélection qui permet à un client MSAA d’indiquer la manière dont l’élément référencé par le paramètre childID doit être sélectionné ou prendre le focus. Ce qui suit sont des descriptions des constantes d’indicateur de sélection et des éléments qu’ils communiquent à l’implémentation d’accessibilité. Dans la pratique, la plupart des implémentations de cette méthode dans les implémentations d’accessibilité qui héritent de la classe Flex mx.accessibility.ListBaseAccImpl ignorent la constante selFlag et s’appuient sur le comportement de sélection de clavier du composant pour gérer la multi-sélection.

Le paramètre selFlag peut contenir ou non l’indicateur SELFLAG_TAKEFOCUS. Si tel est le cas, vous devez également définir le focus enfant sur le childID spécifié, puis, à moins que SELFLAG_EXTENDSELECTION soit également présent, transformer cet élément enfant en ancrage de sélection. Dans le cas contraire, le focus enfant et l’ancrage de sélection ne doivent pas être modifiés, en dépit du fait que d’autres indicateurs décrits ci-dessous puissent modifier la sélection.

L’argument selFlag contient toujours l’un des quatre indicateurs suivants, qui représentent le type de modification de sélection souhaité :

• SELFLAG_TAKESELECTION : effacez toute sélection existante, puis définissez la sélection en fonction du paramètre childID.

• SELFLAG_EXTENDSELECTION : calculez la plage d’éléments enfant entre l’ancrage de sélection et le paramètre childID spécifié, incluant ces derniers. Si SELFLAG_ADDSELECTION est présent, ajoutez l’ensemble de ces éléments enfant à la sélection. Si SELFLAG_REMOVESELECTION est présent, supprimez tous ces éléments enfant de la sélection. En l’absence de SELFLAG_ADDSELECTION et SELFLAG_REMOVESELECTION, tous ces éléments enfant doivent prendre l’état de sélection de l’ancrage de sélection : si l’ancrage de sélection est sélectionné, ajoutez ces éléments enfant à la sélection ; sinon supprimez-les.

• SELFLAG_ADDSELECTION (sans SELFLAG_EXTENDSELECTION) : ajoutez l’élément childID à la sélection.

• SELFLAG_REMOVESELECTION (sans SELFLAG_EXTENDSELECTION) : supprimez l’élément childID de la sélection.

Notez que pour un composant non multi-sélectionnable, les seules valeurs valides pour le paramètre selFlag sont SELFLAG_TAKEFOCUS et SELFLAG_TAKESELECTION. Vous pouvez également, en théorie, choisir de prendre en charge SELFLAG_REMOVESELECTION pour un composant non multi-sélectionnable ayant autorisé l’utilisateur à forcer une sélection null mais, en pratique, la plupart des composants non multi-sélectionnables ne fonctionnent pas de cette façon et les clients MSAA ne doivent pas effectuer ce type d’opération.

Si des indicateurs vous semblent non valides, définissez errno sur E_INVALIDARG.

Enfin, notez que lorsque la méthode accSelect est appelée, Flash Player s’assure qu’elle possède le focus hôte (la fenêtre de focus de son application conteneur) et que votre composant a le focus dans Flash Player.

Paramètres

Informations complémentaires

Eléments de l’API associés

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

La méthode MSAA permettant de renvoyer l’action par défaut du composant représenté par cette classe AccessibilityImplementation ou de l’un de ses éléments enfant.

Implémentez cette méthode uniquement si la classe AccessibilityImplementation représente un élément d’interface utilisateur exécutant une action par défaut dans le modèle MSAA. Pensez à renvoyer la chaîne exacte spécifiée par le modèle MSAA. Par exemple, la chaîne d’action par défaut d’un composant Button est « Press ».

Si vous implémentez get_accDefaultAction uniquement pour la classe AccessibilityImplementation ou ses éléments enfant, vous aurez besoin dans certains cas d’indiquer qu’il n’existe aucune action par défaut pour l’identifiant childID qui a été transmis. Pour ce faire, il suffit de renvoyer la valeur null.

Paramètres

Informations complémentaires

Eléments de l’API associés

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

La méthode MSAA permettant de renvoyer, le cas échéant, l’ID d’entier non signé de l’élément enfant possédant le focus au sein du composant. Si aucun enfant ne possède de focus enfant, la méthode renvoie zéro.

Informations complémentaires

Eléments de l’API associés

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

La méthode MSAA permettant de renvoyer le nom du composant représenté par cette classe AccessibilityImplementation ou de l’un de ses éléments enfant.

Dans le cas de la classe AccessibilityImplementation (childID == 0), si cette méthode n’est pas implémentée ou ne renvoie pas de valeur, Flash Player utilise la valeur de la propriété AccessibilityProperties.name, si elle existe.

Pour les classes AccessibilityImplementation pouvant avoir des éléments enfant, cette méthode doit être implémentée et doit renvoyer une valeur de chaîne lorsque childID n’est pas égal à zéro.

Selon le type d’élément d’interface utilisateur, les noms peuvent représenter deux choses différentes dans MSAA : un nom attribué par l’auteur ou le contenu textuel réel de l’élément. Généralement, la classe AccessibilityImplementation appartient à la première catégorie. Sa propriété name est un nom attribué par l’auteur. Les éléments enfant appartiennent toujours à la deuxième catégorie. Leurs noms indiquent leur contenu de texte.

Lorsque la propriété name d’une classe AccessibilityImplementation représente le nom attribué par l’auteur, les composants peuvent acquérir des noms provenant des auteurs de deux façons. La première implique des noms présents dans le composant. Par exemple, un composant Checkbox peut inclure une étiquette de texte qui lui fait office de nom. La deuxième, une option de secours à la première, implique des noms spécifiés dans l’interface utilisateur et aboutissant dans AccessibilityProperties.name. Cette option de secours autorise les utilisateurs à spécifier des noms tout comme ils le feraient pour n’importe quelle autre classe Sprite ou MovieClip.

Il en découle trois possibilités pour la classe AccessibilityImplementation (childID == zéro) :

• Nom attribué par l’auteur au sein du composant. La méthode get_accName doit être implémentée et doit renvoyer une valeur de chaîne contenant le nom de la classe AccessibilityImplementation lorsque la valeur de childID est zéro. Si la valeur de childID est zéro mais la classe AccessibilityImplementation n’a pas de nom, get_accName doit renvoyer une chaîne vide pour empêcher le lecteur de retourner à la propriété AccessibilityProperties.name.

• Nom attribué par l’auteur provenant de l’interface utilisateur. Si la classe AccessibilityImplementation peut avoir des éléments enfant, la méthode get_accName doit être implémentée, mais ne doit pas renvoyer de valeur lorsque childID est égal à zéro. Si la classe AccessibilityImplementation ne possédera jamais d’éléments enfant, get_accName ne doit pas être implémentée.

• Le nom indiquant le contenu. La méthode get_accName doit être implémentée et doit renvoyer une valeur de chaîne appropriée lorsque la valeur de childID est zéro. Si la valeur de childId est zéro mais la classe AccessibilityImplementation ne possède pas de contenu, get_accName doit renvoyer une chaîne vide pour empêcher le lecteur de retourner à la propriété AccessibilityProperties.name.

Notez que pour les éléments enfant (si la classe AccessibilityImplementation peut en posséder), le troisième cas s’applique toujours. La méthode get_accName doit être implémentée et doit renvoyer une valeur de chaîne appropriée lorsque la valeur de childID n’est pas zéro.

Paramètres

Informations complémentaires

Eléments de l’API associés

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

La méthode MSAA permettant de renvoyer le rôle système du composant représenté par cette classe AccessibilityImplementation ou de l’un de ses éléments enfant. Les rôles système sont prédéfinis pour tous les composants de MSAA.

Paramètres

Informations complémentaires

Eléments de l’API associés

La méthode MSAA permettant de renvoyer un tableau contenant les ID de tous les éléments enfant sélectionnés. Le tableau renvoyé peut contenir aucun, un ou plusieurs ID, tous des entiers non signés.

Informations complémentaires

Eléments de l’API associés

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

La méthode IAccessible permettant de renvoyer l’état d’exécution actuel du composant représenté par cette classe AccessibilityImplementation ou de l’un de ses éléments enfant.

Cette méthode doit renvoyer une combinaison de zéro, une ou plusieurs constantes d’état d’objet prédéfinies pour les composants de MSAA. Lorsque plusieurs états s’appliquent, les constantes d’état doivent être combinées en un champ de bits à l’aide de |, l’opérateur OR au niveau du bit.

Pour indiquer qu’aucune des constantes d’état n’est en cours d’application, cette méthode doit renvoyer zéro.

Vous ne devez pas suivre ou signaler les états STATE_SYSTEM_FOCUSABLE ou STATE_SYSTEM_FOCUSED. Flash Player gère automatiquement ces états.

Paramètres

Informations complémentaires

Eléments de l’API associés

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

La méthode MSAA permettant de renvoyer la valeur d’exécution du composant représenté par cette classe AccessibilityImplementation ou de l’un de ses éléments enfant.

Implémentez cette méthode uniquement si la classe AccessibilityImplementation représente un élément d’interface utilisateur ayant une valeur dans le modèle MSAA. N’oubliez pas que certains éléments d’interface utilisateur possédant une valeur apparente exposent en fait cette valeur de différentes manières, notamment get_accName (texte, par exemple), get_accState (case à cocher, par exemple) ou get_accSelection (zones de liste, par exemple).

Si vous implémentez get_accValue uniquement pour la classe AccessibilityImplementation ou pour ses éléments enfant, vous aurez besoin dans certains cas d’indiquer qu’il n’existe aucun concept de valeur pour l’identifiant childID qui a été transmis. Pour ce faire, il suffit de renvoyer la valeur null.

Paramètres

Informations complémentaires

Eléments de l’API associés

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Renvoie un tableau contenant les ID d’entiers non signés de l’ensemble des éléments enfant de la classe AccessibilityImplementation.

La longueur du tableau peut être égale à zero. Les ID du tableau doivent apparaître dans le même ordre logique que les éléments enfant qu’ils représentent. Si votre classe AccessibilityImplementation peut contenir des éléments enfant, cette méthode est obligatoire ; sinon, ne l’implémentez pas.

Lors de l’affectation d’ID enfant à vos éléments enfant, utilisez un modèle qui conserve l’unicité de chaque occurrence de la classe AccessibilityImplementation. Les ID enfant ne doivent pas être contigus et leur ordre ne doit pas correspondre à l’ordre logique des éléments enfant. Vous devez organiser les ID enfant de manière à ne pas les réutiliser ; si un élément enfant est supprimé, son ID ne doit jamais être réutilisé pendant la durée d’utilisation de cette occurrence AccessibilityImplementation. N’oubliez pas que les choix d’implémentation du code Flash Player peuvent entraîner un comportement indésirable si vous utilisez des ID enfant dépassant le million.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Renvoie true ou false pour indiquer si un objet de texte dont le cadre de sélection est spécifié par x, y, width et height doit être considéré comme une étiquette pour le composant que représente cette classe AccessibilityImplementation.

Les coordonnées x et y sont relatives à l’angle supérieur gauche du composant auquel la classe AccessibilityImplementation s’applique et peuvent être négatives. Toutes les coordonnées sont en unités de scène pixels.

Cette méthode permet d’inclure les composants accessibles dans la recherche de relations d’étiquetage automatique de Flash Player ; ces relations permettent au texte externe à un objet de fournir le nom de l’objet. Cette méthode est fournie, car il est fort probable que les critères de reconnaissance des étiquettes diffèrent d’un composant à l’autre. Si vous implémentez cette méthode, vous devez utiliser des critères géométriques similaires à ceux utilisés dans le code du lecteur pour les boutons et les champs de texte. Ces critères sont les suivants :

• Pour les boutons, tout texte faisant partie intégrale du bouton est considéré comme une étiquette.
• Pour les champs de texte, tout texte qui apparaît juste au-dessus et aligné à gauche ou qui apparaît à gauche est considéré comme une étiquette.

Si le composant que cette classe AccessibilityImplementation représente ne doit jamais participer à des relations d’étiquetage automatique, n’implémentez pas la méthode isLabeledBy. Cela équivaut à toujours renvoyer false. Par exemple, la méthode isLabeledBy ne doit pas être implémentée lorsque la classe AccessibilityImplementation tombe dans le cas « Nom attribué par l’auteur au sein du composant » décrit dans la méthode get_accName ci-dessus.

Notez que cette méthode n’est basée sur aucune méthode IAccessible, mais qu’elle est propre à Flash.

Paramètres